R_AllocationCycleTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Allocation Cycle'
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API }
@ObjectModel.usageType: { dataClass: #CUSTOMIZING,
                          serviceQuality: #C,
                          sizeCategory: #M
            }
@AccessControl.privilegedAssociations:  [ '_Ledger' ]
@ObjectModel.sapObjectNodeType.name: 'AllocationPostingType'
define root view entity R_AllocationCycleTP
  as select from I_AllocationCycle

  association [0..1] to R_CycleRunGroupTP            as _CycleRunGroup    on  $projection.AllocationType              = _CycleRunGroup.AllocationType
                                                                          and $projection.Ledger                      = _CycleRunGroup.Ledger
                                                                          and $projection.AllocationCycleRunGroup     = _CycleRunGroup.AllocationCycleRunGroup
                                                                          and $projection.AllocationPostingType       = _CycleRunGroup.AllocationPostingType
                                                                          and $projection.AllocationActualPlanVariant = _CycleRunGroup.AllocationActualPlanVariant
  association [0..1] to I_AllocationPostingType      as _AllocPostingType on  $projection.AllocationPostingType = _AllocPostingType.AllocationPostingType
  association [0..1] to I_AllocCycleAssignmentStatus as _AssignmentStatus on  $projection.AllocCycleAssignmentStatus = _AssignmentStatus.AllocCycleAssignmentStatus
  association [0..1] to I_Ledger                     as _Ledger           on  $projection.Ledger = _Ledger.Ledger
{
  key AllocationType,
  key AllocationCycle,
      @Semantics.businessDate.from: true
  key AllocationCycleStartDate,
      AllocationCycleRunGroup,
      AllocationPostingType,
      AllocationActualPlanVariant,
      @Semantics.businessDate.at: true
      AllocationLastExecutedDate,
      Ledger,
      LastChangeDate,
      LastChangedByUser,
      @Semantics.text: true
      _Text.AllocationCycleNameText,
      AllocationCycleName,
      cast(
        case AllocationCycleRunGroup
          when '0000' then '1'
          when ''     then '1'
          else '2'
        end
      as fco_alloc_cycle_assgmt_status) as AllocCycleAssignmentStatus,

      cast(
        case AllocationCycleRunGroup
          when '0000' then '3'
          when ''     then '3'
          else '2'
        end
      as eve_tv_criticality)            as StatusCriticality,

      /* Associations */
      _ActualPlanText,
      _Context,
      _CycleRunGroup,
      _AssignmentStatus,
      _Ledger,
      _AllocPostingType
}
where
  AllocationCycleStartDate <> '00000000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ALLOCASSMTDISTRLONGTEXT",
"I_ALLOCATIONCYCLE"
],
"ASSOCIATED":
[
"I_ALLOCACTUALPLANVARIANTTEXT",
"I_ALLOCATIONCONTEXTTYPE",
"I_ALLOCATIONPOSTINGTYPE",
"I_ALLOCCYCLEASSIGNMENTSTATUS",
"I_LEDGER",
"R_CYCLERUNGROUPTP"
],
"BASE":
[
"I_ALLOCATIONCYCLE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/