R_WBSElementMilestoneTP

DDL: R_WBSELEMENTMILESTONETP Type: view_entity TRANSACTIONAL

TP View for I_ProjectMilestoneData

R_WBSElementMilestoneTP is a Transactional CDS View that provides data about "TP View for I_ProjectMilestoneData" in SAP S/4HANA. It reads from 1 data source (I_ProjectMilestoneData) and exposes 30 fields with key fields ProjectMilestone, ProjectMilestoneInternalID. It has 2 associations to related views.

1 data source(s) 30 fields

Data Sources (1)

SourceAliasJoin Type
I_ProjectMilestoneData _ProjectMilestoneData from

Associations (2)

CardinalityTargetAliasCondition
[0..1] R_ProjectTP_2 _Project $projection.ProjectInternalID = _Project.ProjectInternalID
[1..1] E_ProjectMilestone _Extension $projection.ProjectMilestone = _Extension.ProjectMilestone

Annotations (9)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label TP View for I_ProjectMilestoneData view
Metadata.ignorePropagatedAnnotations true view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
VDM.viewType #TRANSACTIONAL view
ObjectModel.sapObjectNodeType.name WBSElementMilestone view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view

Fields (30)

KeyFieldSource TableSource FieldDescription
KEY ProjectMilestone ProjectMilestone
KEY ProjectMilestoneInternalID ProjectMilestoneInternalID
WBSElementInternalID WBSElementInternalID
WBSElementExternalID _WBSElement WBSElementExternalID
ProjectInternalID _WBSElement ProjectInternalID
ProjectExternalID
MlstnLangBsdDescription _MilestoneShortText LanguageBasedShortText
MilestoneDescription
UsageCode UsageCode
MlstnIsRelevantForPrgrsAnlys MlstnIsRelevantForPrgrsAnlys
MlstnIsRelevantForDteInSlsDoc MlstnIsRelevantForDteInSlsDoc
MlstnIsRelevantForTrendAnlys MlstnIsRelevantForTrendAnlys
CompletionRateInPercent CompletionRateInPercent
ProjCostToBeInvoicedPercent ProjCostToBeInvoicedPercent
FixedBasicDate FixedBasicDate
ScheduledBasicDate ScheduledBasicDate
ActualEndDate ActualEndDate
DateIsOffsetToParentEndDate DateIsOffsetToParentEndDate
SetOfDatesForOffsets
MlstnDateOffsetDuration MlstnDateOffsetDuration
MlstnDateOffsetDurationUnit MlstnDateOffsetDurationUnit
MlstnDateOffsetPercent MlstnDateOffsetPercent
AuthorizationGroup AuthorizationGroup
CreatedByUser CreatedByUser
CreationDate CreationDate
LastChangeDate LastChangeDate
LastChangedByUser LastChangedByUser
IsMarkedForDeletion IsDeleted
_WBSElement _WBSElement
_Project _Project 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'TP View for I_ProjectMilestoneData'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.sapObjectNodeType.name:'WBSElementMilestone'
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
define view entity R_WBSElementMilestoneTP
  as select from I_ProjectMilestoneData as _ProjectMilestoneData
  association        to parent R_WBSElementTP_2 as _WBSElement on $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [0..1] to R_ProjectTP_2           as _Project    on $projection.ProjectInternalID = _Project.ProjectInternalID
  association [1..1] to E_ProjectMilestone      as _Extension  on $projection.ProjectMilestone = _Extension.ProjectMilestone

{
  key ProjectMilestone,
  key ProjectMilestoneInternalID,
      WBSElementInternalID,
      _WBSElement.WBSElementExternalID                                                 as WBSElementExternalID,
      _WBSElement.ProjectInternalID                                                    as ProjectInternalID,
      _WBSElement._Project[inner].ProjectExternalID                                    as ProjectExternalID,
      @Semantics.text: true
      _MilestoneShortText.LanguageBasedShortText                                       as MlstnLangBsdDescription,
      //1                                                                                as MlstnLangBsdDescription,

      @Semantics.text: true
      _Text[left outer where Language = $session.system_language].MilestoneDescription as MilestoneDescription,
      UsageCode,

      MlstnIsRelevantForPrgrsAnlys,
      MlstnIsRelevantForDteInSlsDoc,
      MlstnIsRelevantForTrendAnlys,
      CompletionRateInPercent,
      ProjCostToBeInvoicedPercent,
      FixedBasicDate,
      ScheduledBasicDate,
      ForecastedFixedDate,
      ScheduledForecastedDate,
      ActualEndDate,
      DateIsOffsetToParentEndDate,
      //new variable to maintain scheduling for different sets of dates in case of updating offset

      cast ( '' as char1 )                      as SetOfDatesForOffsets,
      @Semantics.quantity.unitOfMeasure: 'MlstnDateOffsetDurationUnit'
      MlstnDateOffsetDuration,
      MlstnDateOffsetDurationUnit,
      MlstnDateOffsetPercent,
      AuthorizationGroup,

      CreatedByUser,
      CreationDate,
      LastChangeDate,
      LastChangedByUser,
      IsDeleted                                                                        as IsMarkedForDeletion,

      _WBSElement,
      _Project
}
where
      _ProjectMilestoneData.ProjectNetworkInternalID  is initial
  and _ProjectMilestoneData.NetworkActivityInternalID is initial

Learn More