R_SourcingProjectQuotation

@ClientHandling.algorithm: #SESSION_VARIABLE

@AbapCatalog: { sqlViewName: 'RSRCGPROJQTN',
                compiler.compareFilter: true,
                preserveKey: true
}

@AccessControl.authorizationCheck: #MANDATORY

@ObjectModel:{
               representativeKey: 'SourcingProjectQuotationUUID',
               semanticKey: ['SrcgProjQuotationVersion', 'SourcingProjectQuotation'],

               usageType: {
                 dataClass: #TRANSACTIONAL,
//               Service Quality A/B needed

                 serviceQuality: #A,
                 sizeCategory: #M
              }
}

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Quotation for Sourcing Project'
define view R_SourcingProjectQuotation
  as select from mmsrcgprojqtn

  association [0..1] to R_SourcingProject            as _SourcingProject            on $projection.SourcingProjectUUID = _SourcingProject.SourcingProjectUUID

  association [1..*] to R_SrcgProjQtnItem            as _SrcgProjQtnItem            on $projection.SourcingProjectQuotationUUID = _SrcgProjQtnItem.SourcingProjectQuotationUUID

  association [0..*] to R_SrcgProjQtnSupplierContact as _SrcgProjQtnSupplierContact on $projection.SourcingProjectQuotationUUID = _SrcgProjQtnSupplierContact.SourcingProjectQuotationUUID

  //foreign key associations

  association [0..1] to I_Currency                   as _SrcgProjQtnOfferCurrency   on $projection.SrcgProjQtnOfferCurrency = _SrcgProjQtnOfferCurrency.Currency
  association [0..1] to I_CompanyCode                as _CompanyCode                on $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_PurchasingGroup            as _PurchasingGroup            on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..1] to I_PurchasingOrganization     as _PurchasingOrganization     on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
  association [0..1] to I_SrcgProjQtnLifecycleSts    as _SrcgProjQtnLifecycleSts    on $projection.SrcgProjQtnLifecycleStatus = _SrcgProjQtnLifecycleSts.SrcgProjQtnLifecycleStatus
  association [0..1] to I_BusinessPartner            as _BusinessPartner            on $projection.Bidder = _BusinessPartner.BusinessPartner

  //tbd

  association [0..1] to I_UserContactCard            as _CreatedByUser              on $projection.CreatedByUser = _CreatedByUser.ContactCardID
  association [0..1] to I_UserContactCard            as _ChangedByUser              on $projection.LastChangedByUser = _ChangedByUser.ContactCardID
  association [0..1] to I_MaterialGroup              as _MaterialGroup              on $projection.MaterialGroup = _MaterialGroup.MaterialGroup
  association [0..1] to I_UnitOfMeasure              as _DeviationPercentUnit       on _DeviationPercentUnit.UnitOfMeasure = '%'
  association [0..1] to R_SourcingProjectQuotation   as _SourceSrcgProjQuotation    on $projection.SourceSrcgProjQuotationUUID = _SourceSrcgProjQuotation.SourcingProjectQuotationUUID
{
  key sourcingprojectquotationuuid   as SourcingProjectQuotationUUID,
      sourcingprojectquotation       as SourcingProjectQuotation,
      srcgprojquotationversion       as SrcgProjQuotationVersion,
      sourcingprojectquotationtype   as SourcingProjectQuotationType,
      sourcingprojectquotationname   as SourcingProjectQuotationName,
      srcgprojquotationissimulated   as SrcgProjQuotationIsSimulated,
      bidder                         as Bidder,
      companycode                    as CompanyCode,
      purchasinggroup                as PurchasingGroup,
      purchasingorganization         as PurchasingOrganization,
      @Semantics.currencyCode: true
      srcgprojqtnoffercurrency       as SrcgProjQtnOfferCurrency,
      @Semantics.amount.currencyCode: 'SrcgProjQtnOfferCurrency'
      @DefaultAggregation: #NONE
      srcgprojqtntotnetamt           as SrcgProjQtnTotNetAmt,

      srcgprojqtnlifecyclestatus     as SrcgProjQtnLifecycleStatus,
      srcgprojqtnrevisionsts         as SrcgProjQtnRevisionSts,
      srcgprojqtnactvtnsts           as SrcgProjQtnActvtnSts,
      srcgprojqtnsubmsnsts           as SrcgProjQtnSubmsnSts,
      srcgprojqtnawardingstatus      as SrcgProjQtnAwardingStatus,

      sourcingprojectuuid            as SourcingProjectUUID,
      sourcingprojectnegotiationuuid as SourcingProjectNegotiationUUID,

      pricingprocedure               as PricingProcedure,

      @Semantics.user.lastChangedBy: true
      lastchangedbyuser              as LastChangedByUser,
      @Semantics.user.createdBy: true
      createdbyuser                  as CreatedByUser,

      @Semantics.systemDateTime.lastChangedAt: true
      lastchangedatetime             as LastChangeDateTime,

      @Semantics.systemDateTime.createdAt: true
      creationdatetime               as CreationDateTime,

      srcgprojattchsareforbidden     as SrcgProjAttchsAreForbidden,
      srcgprojnotesareforbidden      as SrcgProjNotesAreForbidden,

      sourcingorigin                 as SourcingOrigin,
      externalsourcingprojectqtnref  as ExternalSourcingProjectQtnRef,
      qtnlatestsubmissiondatetime    as QtnLatestSubmissionDateTime,
      logicalsystem                  as LogicalSystem,
      sourcesrcgprojquotationuuid    as SourceSrcgProjQuotationUUID,
      @Semantics.booleanIndicator: true
      iseopblocked                   as IsEndOfPurposeBlocked,
      cashdiscount1days              as CashDiscount1Days,
      cashdiscount2days              as CashDiscount2Days,
      cashdiscount1percent           as CashDiscount1Percent,
      cashdiscount2percent           as CashDiscount2Percent,
      netpaymentdays                 as NetPaymentDays,
      materialgroup                  as MaterialGroup,
      sourcingawardingdate           as SourcingAwardingDate,
      srcgprojqtnsuitability         as SrcgProjQtnSuitability,

      /* Associations */
      _SourcingProject,
      _SrcgProjQtnItem,
      _SrcgProjQtnSupplierContact,
      //foreign key associations

      _CompanyCode,
      _PurchasingGroup,
      _PurchasingOrganization,
      _SrcgProjQtnOfferCurrency,
      _SrcgProjQtnLifecycleSts,
      _BusinessPartner,
      _DeviationPercentUnit,
      //tbd

      _CreatedByUser,
      _ChangedByUser,
      _MaterialGroup,
      _SourceSrcgProjQuotation
}