@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Order TP'
@VDM.viewType: #COMPOSITE
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@ObjectModel.sapObjectNodeType.name: 'MaintenanceOrder'
@AbapCatalog.extensibility: {
extensible: true,
dataSources: ['_MaintenanceOrderExtension'],
elementSuffix: 'ORI',
quota: {
maximumFields: 250,
maximumBytes: 5000
}
}
define root view entity R_MaintenanceOrderTP
as select from I_MaintenanceOrder
composition [0..*] of R_MaintenanceOrderOperationTP as _MaintenanceOrderOperation
composition [0..*] of R_MaintOrdObjectListItemTP as _MaintOrderObjectListItem
composition [0..*] of R_MaintOrderSettlmtDistrRuleTP as _MaintOrderSettlmtDistrRule
composition [0..*] of R_MaintOrderPhaseControlTP as _MaintenanceOrderPhaseControl
composition [0..*] of R_MaintenanceOrderPartnerTP as _MaintenanceOrderPartner
composition [0..*] of R_MaintenanceOrderLongTextTP as _MaintenanceOrderLongText
composition [0..*] of R_MaintOrdSettlmtDistrRuleTP_2 as _MaintOrderSettlmtDistrRule_2
association [0..1] to I_FunctionalLocationLabel as _FunctionalLocationLabel on _FunctionalLocationLabel.FunctionalLocation = $projection.FunctionalLocation
association [0..1] to E_MaintenanceOrder as _MaintenanceOrderExtension on _MaintenanceOrderExtension.MaintenanceOrder = $projection.MaintenanceOrder
association [0..1] to I_WBSElementBasicData as _WBSElement on $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
association [0..1] to I_WBSElementBasicData as _LocAcctAssgmtWBSElement on $projection.LocAcctAssgmtWBSElmntIntID = _LocAcctAssgmtWBSElement.WBSElementInternalID
association [0..1] to I_ProjectBasicData as _ProjectBasicData on $projection.ProjectInternalID = _ProjectBasicData.ProjectInternalID
association [0..1] to I_PersonWorkAgreement_1 as _PersonResponsible on $projection.MaintOrdPersonResponsible = _PersonResponsible.PersonWorkAgreement
association of one to many R_MaintOrderOpComponentTP_2 as _OrderComponent on $projection.MaintenanceOrder = _OrderComponent.MaintenanceOrder
and ( _OrderComponent.ProductTypeCode <> '2' )
association of one to many R_MaintOrderOpComponentTP_2 as _OrderService on $projection.MaintenanceOrder = _OrderService.MaintenanceOrder
and _OrderService.ProductTypeCode = '2'
association of one to many R_MaintOrderOpProdnRsceToolTP as _OrderPrtTool on $projection.MaintenanceOrder = _OrderPrtTool.MaintenanceOrder
//TEXTs
association [0..*] to I_EAMProcessPhaseText as _EAMProcessPhaseText on _EAMProcessPhaseText.EAMProcessPhaseCode = $projection.MaintOrdProcessPhaseCode
association [0..*] to I_EAMProcessSubPhaseText as _EAMProcessSubPhaseText on _EAMProcessSubPhaseText.EAMProcessSubPhaseCode = $projection.MaintOrdProcessSubPhaseCode
association [0..1] to I_MaintOrderTechObj as _MaintOrderTechObj on _MaintOrderTechObj.MaintenanceOrder = $projection.MaintenanceOrder
association of one to many I_OrderTypeText as _MaintenanceOrderTypeText on _MaintenanceOrderTypeText.OrderType = $projection.MaintenanceOrderType
association of one to many I_MaintenanceActivityTypeText as _MaintenanceActivityTypeText on _MaintenanceActivityTypeText.MaintenanceActivityType = $projection.MaintenanceActivityType
association of one to many I_MaintOrdProcessingContextT as _MaintOrdProcessingContextText on _MaintOrdProcessingContextText.MaintOrderProcessingContext = $projection.MaintOrderProcessingContext
association of one to many I_MaintOrdPlngDegreeCodeText as _MaintOrdPlanningCodeText on _MaintOrdPlanningCodeText.MaintenanceOrderPlanningCode = $projection.MaintenanceOrderPlanningCode
association of one to many I_MaterialText as _AssemblyText on _AssemblyText.Material = $projection.Assembly
association of one to many I_EquipmentText as _EquipmentText on _EquipmentText.Equipment = $projection.Equipment
association of one to many I_MaintOperationSystConditionT as _OperationSystemConditionText on _OperationSystemConditionText.OperationSystemCondition = $projection.OperationSystemCondition
association of one to many I_CostingSheetProcedureText as _CostingSheetProcedureText on _CostingSheetProcedureText.ConditionUsage = $projection.ConditionUsage
and _CostingSheetProcedureText.ConditionApplication = $projection.ConditionApplication
and _CostingSheetProcedureText.CostingSheetProcedure = $projection.CostingSheet
association of one to many I_CostingVariantText as _PlannedCostingVariantText on _PlannedCostingVariantText.CostingVariant = $projection.PlannedCostsCostingVariant
association of one to many I_CostingVariantText as _ActualCostingVariantText on _ActualCostingVariantText.CostingVariant = $projection.ActualCostsCostingVariant
association of one to many I_ABCIndicatorText as _ABCIndicatorText on _ABCIndicatorText.ABCIndicator = $projection.abcindicator
association of one to many I_ControllingObjectClassT as _ControllingObjectClassText on _ControllingObjectClassText.ControllingObjectClass = $projection.ControllingObjectClass
association of one to many I_BusinessAreaText as _BusinessAreaText on _BusinessAreaText.BusinessArea = $projection.BusinessArea
association of one to many I_BusinessAreaText as _LocAcctAssgmtBusinessAreaText on _LocAcctAssgmtBusinessAreaText.BusinessArea = $projection.LocAcctAssgmtBusinessArea
association of one to many I_CtrlgSettlementProfileText as _CtrlgSettlementProfileText on _CtrlgSettlementProfileText.ControllingSettlementProfile = $projection.controllingsettlementprofile
association of one to many I_PMNotifPriorityTypeText as _MaintPriorityTypeText on _MaintPriorityTypeText.MaintPriorityType = $projection.MaintPriorityType
association of one to many I_PMNotificationPriorityText as _MaintPriorityText on _MaintPriorityText.MaintPriorityType = $projection.MaintPriorityType
and _MaintPriorityText.MaintPriority = $projection.MaintPriority
association of one to many I_SchedulingTypeText as _BasicSchedulingTypeText on _BasicSchedulingTypeText.SchedulingType = $projection.BasicSchedulingType
association of one to many I_MaintenanceOrderPhaseText as _MaintProcessingPhaseText on _MaintProcessingPhaseText.MaintenanceProcessingPhase = $projection.MaintenanceProcessingPhase
association of one to one I_CostCenterText as _ResponsibleCostCenterText on _ResponsibleCostCenterText.ControllingArea = $projection.ControllingArea
and _ResponsibleCostCenterText.CostCenter = $projection.ResponsibleCostCenter
and _ResponsibleCostCenterText.ValidityEndDate >= $session.system_date
and _ResponsibleCostCenterText.ValidityStartDate <= $session.system_date
and _ResponsibleCostCenterText.Language = $session.system_language
association of one to one I_CostCenterText as _CostCenterText on _CostCenterText.ControllingArea = $projection.ControllingArea
and _CostCenterText.CostCenter = $projection.costcenter
and _CostCenterText.ValidityEndDate >= $session.system_date
and _CostCenterText.ValidityStartDate <= $session.system_date
and _CostCenterText.Language = $session.system_language
association of one to one I_ProfitCenterText as _ProfitCenterText on _ProfitCenterText.ControllingArea = $projection.ControllingArea
and _ProfitCenterText.ProfitCenter = $projection.ProfitCenter
and _ProfitCenterText.ValidityEndDate >= $session.system_date
and _ProfitCenterText.ValidityStartDate <= $session.system_date
and _ProfitCenterText.Language = $session.system_language
// association [0..1] to P_MaintOrdNoOfCheckList as _MaintOrdOpNoOfCheckList on $projection.MaintenanceOrder = _MaintOrdOpNoOfCheckList.MaintenanceOrder
{
key MaintenanceOrder,
MaintOrderRoutingNumber,
MaintenanceOrderType,
MaintenanceOrderDesc,
case when MaintOrdBasicStartTime = '240000' and MaintOrdBasicStartDate is not initial then
cast(dats_tims_to_tstmp( dats_add_days( MaintOrdBasicStartDate, 1, 'NULL') , cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL') as timestamp preserving type)
else cast(dats_tims_to_tstmp( MaintOrdBasicStartDate, MaintOrdBasicStartTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client,'NULL') as timestamp preserving type)
end as MaintOrdBasicStartDateTime,
case when MaintOrdBasicEndTime = '240000' and MaintOrdBasicEndDate is not initial then
cast(dats_tims_to_tstmp( dats_add_days( MaintOrdBasicEndDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL') as timestamp preserving type)
else cast(dats_tims_to_tstmp( MaintOrdBasicEndDate, MaintOrdBasicEndTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL') as timestamp preserving type)
end as MaintOrdBasicEndDateTime,
case when MaintOrdBasicStartTime = '240000' and MaintOrdBasicStartDate is not initial then
tstmp_to_dats( dats_tims_to_tstmp(dats_add_days( MaintOrdBasicStartDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
else tstmp_to_dats( dats_tims_to_tstmp(MaintOrdBasicStartDate, MaintOrdBasicStartTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
end as MaintOrdBasicStartDate,
case when MaintOrdBasicStartTime = '240000' and MaintOrdBasicStartDate is not initial then
tstmp_to_tims( dats_tims_to_tstmp(dats_add_days( MaintOrdBasicStartDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
else tstmp_to_tims( dats_tims_to_tstmp(MaintOrdBasicStartDate, MaintOrdBasicStartTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
end as MaintOrdBasicStartTime,
case when MaintOrdBasicEndTime = '240000' and MaintOrdBasicEndDate is not initial then
tstmp_to_dats( dats_tims_to_tstmp(dats_add_days( MaintOrdBasicEndDate, 1, 'NULL'),
cast( '000000' as abap.tims ), abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
else tstmp_to_dats( dats_tims_to_tstmp(MaintOrdBasicEndDate, MaintOrdBasicEndTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
end as MaintOrdBasicEndDate,
case when MaintOrdBasicEndTime = '240000' and MaintOrdBasicEndDate is not initial then
tstmp_to_tims( dats_tims_to_tstmp(dats_add_days( MaintOrdBasicEndDate, 1, 'NULL'),
cast( '000000' as abap.tims ), abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
else tstmp_to_tims( dats_tims_to_tstmp(MaintOrdBasicEndDate, MaintOrdBasicEndTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
end as MaintOrdBasicEndTime,
case when ScheduledBasicStartTime = '240000' and ScheduledBasicStartDate is not initial
then cast(dats_tims_to_tstmp( dats_add_days( ScheduledBasicStartDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL') as timestamp preserving type)
else cast(dats_tims_to_tstmp( ScheduledBasicStartDate, ScheduledBasicStartTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client,'NULL') as timestamp preserving type)
end as MaintOrdSchedldBscStrtDateTime,
case when ScheduledBasicEndTime = '240000' and ScheduledBasicEndDate is not initial
then cast(dats_tims_to_tstmp( dats_add_days( ScheduledBasicEndDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL') as timestamp preserving type)
else cast(dats_tims_to_tstmp( ScheduledBasicEndDate, ScheduledBasicEndTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client,'NULL') as timestamp preserving type)
end as MaintOrdSchedldBscEndDateTime,
case when ScheduledBasicStartTime = '240000' and ScheduledBasicStartDate is not initial
then tstmp_to_dats( dats_tims_to_tstmp(dats_add_days( ScheduledBasicStartDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
else tstmp_to_dats( dats_tims_to_tstmp(ScheduledBasicStartDate, ScheduledBasicStartTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
end as ScheduledBasicStartDate,
case when ScheduledBasicStartTime = '240000' and ScheduledBasicStartDate is not initial
then tstmp_to_tims( dats_tims_to_tstmp(dats_add_days( ScheduledBasicStartDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
else tstmp_to_tims( dats_tims_to_tstmp(ScheduledBasicStartDate, ScheduledBasicStartTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
end as ScheduledBasicStartTime,
case when ScheduledBasicEndTime = '240000' and ScheduledBasicEndDate is not initial
then tstmp_to_dats( dats_tims_to_tstmp(dats_add_days( ScheduledBasicEndDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
else tstmp_to_dats( dats_tims_to_tstmp(ScheduledBasicEndDate, ScheduledBasicEndTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
end as ScheduledBasicEndDate,
case when ScheduledBasicEndTime = '240000' and ScheduledBasicEndDate is not initial
then tstmp_to_tims( dats_tims_to_tstmp(dats_add_days( ScheduledBasicEndDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
else tstmp_to_tims( dats_tims_to_tstmp(ScheduledBasicEndDate, ScheduledBasicEndTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
end as ScheduledBasicEndTime,
case when MaintOrderReferenceTime = '240000' and MaintOrderReferenceDate is not initial
then cast(dats_tims_to_tstmp( dats_add_days( MaintOrderReferenceDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL') as timestamp preserving type)
else cast(dats_tims_to_tstmp( MaintOrderReferenceDate, MaintOrderReferenceTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client,'NULL') as timestamp preserving type)
end as MaintOrderReferenceDateTime,
case when MaintOrderReferenceTime = '240000' and MaintOrderReferenceDate is not initial
then tstmp_to_dats( dats_tims_to_tstmp(dats_add_days( MaintOrderReferenceDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
else tstmp_to_dats( dats_tims_to_tstmp(MaintOrderReferenceDate, MaintOrderReferenceTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
end as MaintOrderReferenceDate,
case when MaintOrderReferenceTime = '240000' and MaintOrderReferenceDate is not initial
then tstmp_to_tims( dats_tims_to_tstmp(dats_add_days( MaintOrderReferenceDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
else tstmp_to_tims( dats_tims_to_tstmp(MaintOrderReferenceDate, MaintOrderReferenceTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
end as MaintOrderReferenceTime,
MainWorkCompletedDateTime,
MaintenanceNotification,
OrdIsNotSchedldAutomatically,
WorkCenterInternalID as MainWorkCenterInternalID,
WorkCenterTypeCode as MainWorkCenterTypeCode,
_MainWorkCenter.WorkCenter as MainWorkCenter,
_MainWorkCenter.Plant as MainWorkCenterPlant,
ControllingArea,
//ServiceDetails for MOVE team
ServiceDocumentType,
ServiceDocument,
ServiceDocumentItem,
AccountingIndicatorCode,
//ServiceDetails for MOVE team
MaintenancePlanningPlant,
Assembly,
MaintOrdProcessPhaseCode,
MaintOrdProcessSubPhaseCode,
CompanyCode,
BusinessArea,
ReferenceElement,
FunctionalArea,
AdditionalDeviceData,
Equipment,
MaintenanceOrderPlanningCode,
MaintenancePlannerGroup,
MaintenanceActivityType,
MaintPriority,
MaintPriorityType,
OrderProcessingGroup,
ProfitCenter,
ResponsibleCostCenter,
CostingSheet,
ConditionUsage,
ConditionApplication,
Currency,
MaintenanceRevision,
cast ( SerialNumber as vdm_eam_gernr ) as SerialNumber,
Material as Product,
SuperiorProjectNetwork,
OperationSystemCondition,
@ObjectModel.foreignKey.association: '_WBSElement'
cast ( I_MaintenanceOrder.WBSElementInternalID as ps_s4_pspnr ) as WBSElementInternalID,
cast( ProjectInternalID as ps_s4_proj_pspnr ) as ProjectInternalID,
// Location Assignment
cast ( _LocationAccountAssignment.WBSElementInternalID as ps_s4_pspnr preserving type ) as LocAcctAssgmtWBSElmntIntID,
_LocationAccountAssignment.CostCenter,
ControllingObjectClass,
cast ( _LocationAccountAssignment.FunctionalLocation as vdm_eam_tplnr ) as FunctionalLocation,
-- Location Data
_LocationAccountAssignment.MaintenancePlant,
_LocationAccountAssignment.AssetLocation,
_LocationAccountAssignment.AssetRoom,
_LocationAccountAssignment.PlantSection,
_LocationAccountAssignment.ABCIndicator,
_LocationAccountAssignment.MaintObjectFreeDefinedAttrib,
_LocationAccountAssignment.WorkCenterInternalID,
_LocationAccountAssignment.WorkCenterTypeCode,
_LocationAccountAssignment._WorkCenter.WorkCenter,
_LocationAccountAssignment.BusinessArea as LocAcctAssgmtBusinessArea,
_LocationAccountAssignment.SettlementOrder,
_LocationAccountAssignment.MasterFixedAsset,
_LocationAccountAssignment.FixedAsset,
_LocationAccountAssignment.StandingOrderNumber,
_LocationAccountAssignment.SalesOrganization,
_LocationAccountAssignment.DistributionChannel,
_LocationAccountAssignment.OrganizationDivision,
_LocationAccountAssignment.ControllingArea as LocAcctAssgmtControllingArea,
_LocationAccountAssignment.CompanyCode as LocAcctAssgmtCompanyCode,
//_MaintOrderHasOpenMainWork.MaintOrdHasOpenMainWork,
MaintenanceOrderInternalID,
MaintenanceItemObjectList,
I_MaintenanceOrder.MaintObjectLocAcctAssgmtNmbr,
@Feature: 'EAM_ORD_CHANGE_SETTLMT_PROFILE' //should be featured?
_CtrlgObjectSettlementRule.ControllingSettlementProfile,
BasicSchedulingType,
LatestAcceptableCompletionDate,
MaintOrdPersonResponsible,
@Feature: 'EAM_F5241_HEADER_CONTROL_DATA'
LastChangeByUser,
@ObjectModel.readOnly: null
LastChangeDateTime,
CreatedByUser,
case when CreationTime = '240000' and CreationDate is not initial
then cast(dats_tims_to_tstmp( dats_add_days( CreationDate, 1, 'NULL'), cast( '000000' as abap.tims ),
abap_system_timezone( $session.client,'NULL' ),
$session.client, 'NULL') as timestamp preserving type)
else cast(dats_tims_to_tstmp( CreationDate, CreationTime,
abap_system_timezone( $session.client,'NULL' ),
$session.client,'NULL') as timestamp preserving type)
end as MaintOrderCreationDateTime,
OrderHasLongText,
MaintOrderProcessingContext,
@Feature: 'EAM_F5241_HEADER_CONTROL_DATA'
MaintenanceOrderOverheadCode,
@Feature: 'EAM_F5241_HEADER_CONTROL_DATA'
PlannedCostsCostingVariant,
@Feature: 'EAM_F5241_HEADER_CONTROL_DATA'
ActualCostsCostingVariant,
/*Mainteannce Plan*/
MaintenancePlan,
MaintenanceCall,
MaintenanceItem,
LeadingOrder,
TaskListType,
TaskListGroup,
TaskListGroupCounter,
OrderIsRefurbishmentOrder,
hextobin( '00000000000000000000000000000000' ) as MaintenanceOrderUUID,
MaintenanceProcessingPhase,
// _MaintOrdOpNoOfCheckList.NumberOfMaintenanceChecklists,
// _MaintOrdOpNoOfCheckList.MaintOrdOperationHasCheckList,
/*Mainteannce Plan*/
// associations
_MaintenanceOrderOperation,
_MaintOrderObjectListItem,
_MaintOrderSettlmtDistrRule,
_MaintOrderSettlmtDistrRule_2,
_MaintenanceOrderPhaseControl,
_MaintenanceOrderPartner,
_FunctionalLocationLabel,
_EAMProcessPhase,
_EAMProcessSubPhase,
_LocationAccountAssignment,
_WBSElement,
_MainWorkCenter,
_MaintenancePlanningPlant,
_MaintenancePlannerGroup,
_LocAcctAssgmtWBSElement,
_ProjectBasicData,
_CtrlgObjectSettlementRule,
_MaintOrderTypeControlParam,
_MaintOrderHasOpenMainWork,
// _MaintOrdOpNoOfCheckList,
// associations of texts
_EAMProcessPhaseText,
_EAMProcessSubPhaseText,
_MaintenanceOrderTypeText,
_MaintenanceActivityTypeText,
_MaintOrdProcessingContextText,
_MaintOrdPlanningCodeText,
_AssemblyText,
_EquipmentText,
_OperationSystemConditionText,
@Feature: 'EAM_F5241_HEADER_CONTROL_DATA'
_CostingSheetProcedureText,
@Feature: 'EAM_F5241_HEADER_CONTROL_DATA'
_PlannedCostingVariantText,
@Feature: 'EAM_F5241_HEADER_CONTROL_DATA'
_ActualCostingVariantText,
_ABCIndicatorText,
_BusinessAreaText,
_ResponsibleCostCenterText,
_ControllingObjectClassText,
_ProfitCenterText,
_CostCenterText,
_LocAcctAssgmtBusinessAreaText,
_CtrlgSettlementProfileText,
_MaintPriorityTypeText,
_MaintPriorityText,
@Feature: 'EAM_F5241_HEADER_SCHED_DETAILS'
_BasicSchedulingTypeText,
_MaintProcessingPhaseText,
_MaintenanceNotification,
//old associations of texts
_MaintenanceActivityType,
_MaintenanceOrderType,
_MaintOrderTechObj,
_MaintOrdPlngDegreeCode,
_Assembly,
_OperationSystemCondition,
_Equipment,
@Feature: 'EAM_F5241_HEADER_CONTROL_DATA'
_CostingSheetProcedure,
@Feature: 'EAM_F5241_HEADER_CONTROL_DATA'
_PlannedCostingVariant,
@Feature: 'EAM_F5241_HEADER_CONTROL_DATA'
_ActualCostingVariant,
_BusinessArea,
_ResponsibleCostCenter,
_ControllingObjectClass,
_ProfitCenter,
_MaintenancePriorityType,
_MaintenancePriority,
@Feature: 'EAM_F5241_HEADER_SCHED_DETAILS'
_BasicSchedulingType,
_MaintenanceOrderPhase,
_StatusObjectActiveStatus,
_MaintenanceOrderLongText,
_ControllingArea,
_CompanyCode,
_PersonResponsible,
_MaintenanceRevision,
_OrderComponent,
_OrderService,
_OrderPrtTool,
_MaintenancePlan,
_MaintenanceItem,
_MaintenanceCall,
_LeadingOrder,
@Feature: 'EAM_F5241_HEADER_CONTROL_DATA'
_OverheadCode
}