R_MaintOrdObjectListItemTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Maintenance Order Object List Item'
@VDM.viewType: #TRANSACTIONAL
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}

define view entity R_MaintOrdObjectListItemTP
  as select from I_MaintOrderObjectListItem
  composition of exact one to many R_MaintOrdOpObjListLinkTP as _AssignedMaintOrderOperations
  association              to parent R_MaintenanceOrderTP    as _MaintenanceOrder   on $projection.MaintenanceOrder = _MaintenanceOrder.MaintenanceOrder
  association of one       to one I_FunctionalLocation       as _FunctionalLocation on _FunctionalLocation.FunctionalLocation = $projection.FunctionalLocation

{
  key MaintenanceOrder,
  key MaintenanceOrderObjectList,
  key MaintenanceObjectListItem,
      @ObjectModel.editableFieldFor: 'MaintenanceOrderObjectList'
      cast( MaintenanceOrderObjectList    as objknr preserving type ) as MaintOrderObjectListForEdit,
      @ObjectModel.editableFieldFor: 'MaintenanceObjectListItem'
      cast( MaintenanceObjectListItem as objza preserving type )      as MaintObjectListItemForEdit,
      Equipment,
      MaintenanceNotification,
      Assembly,
      Material,
      SerialNumber,
      UniqueItemIdentifier,
      cast ( FunctionalLocation as vdm_eam_tplnr )                    as FunctionalLocation,
      MaintObjectListItemSequence,
      _MaintenanceOrder._MaintenanceNotification.NotificationText     as NotificationText,
      /* Associations */
      _Assembly,
      _Equipment,
      _FunctionalLocation,
      _MaintenanceNotification,
      _Product,
      _MaintenanceOrder,
      _AssignedMaintOrderOperations
}