R_MaintOrderOpComponentTP

@AccessControl.authorizationCheck: #CHECK
@VDM: { viewType: #TRANSACTIONAL, lifecycle.contract.type: #SAP_INTERNAL_API }
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
@EndUserText.label: 'Maintenance Order Operation Component TP'

@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'R_MaintOrderOpComponentTP_2'
define view entity R_MaintOrderOpComponentTP
  as select from I_MaintenanceOrderComponent

  association        to parent R_MaintenanceOrderOperationTP as _MaintenanceOrderOperation on (
     $projection.MaintenanceOrderOperation        = _MaintenanceOrderOperation.MaintenanceOrderOperation
     and $projection.MaintenanceOrderSubOperation = _MaintenanceOrderOperation.MaintenanceOrderSubOperation
     and $projection.MaintenanceOrder             = _MaintenanceOrderOperation.MaintenanceOrder
   )

  composition [0..*] of R_MaintOrderOpCompLongTextTP         as _MaintOrderOpCompLongText

  association [1..1] to R_MaintenanceOrderTP                 as _MaintenanceOrder          on $projection.MaintenanceOrder = _MaintenanceOrder.MaintenanceOrder

  association [0..1] to I_WBSElementBasicData                as _WBSElement                on _WBSElement.WBSElementInternalID = $projection.MaintOrdOpCompAssgdWBSElmntInt

{

  key MaintenanceOrder,
  key cast( MaintenanceOrderOperation    as maintenanceorderoperation preserving type )    as MaintenanceOrderOperation,
  key cast( MaintenanceOrderSubOperation as maintenanceordersuboperation preserving type ) as MaintenanceOrderSubOperation,
  key cast( MaintenanceOrderComponent    as maintenanceordercomponent preserving type )    as MaintenanceOrderComponent,

      @ObjectModel.editableFieldFor: 'MaintenanceOrderOperation'
      cast( MaintenanceOrderOperation    as maintenanceorderoperation preserving type )    as MaintOrderOperationForEdit,
      @ObjectModel.editableFieldFor: 'MaintenanceOrderSubOperation'
      cast( MaintenanceOrderSubOperation as maintenanceordersuboperation preserving type ) as MaintOrderSubOperationForEdit,
      @ObjectModel.editableFieldFor: 'MaintenanceOrderComponent'
      cast( MaintenanceOrderComponent    as maintenanceordercomponent preserving type )    as MaintOrderComponentForEdit,

      Reservation,
      ReservationItem,
      ReservationType,
      MaintOrderRoutingNumber,
      MaintOrderOperationCounter,
      Material                                                                             as Product,
      case when Material = ''
        then ComponentDescription
        else _MaterialText[1:Language = $session.system_language ].MaterialName end        as MaintOrdOperationComponentText,
      RequirementQuantityInBaseUnit                                                        as MaintOrdOpCompRequiredQuantity,
      BaseUnit,
      QuantityInUnitOfEntry,
      UnitOfEntry,
      case RequirementTime when '240000'
      then tstmp_to_dats( dats_tims_to_tstmp(dats_add_days( RequirementDate, 1, 'NULL'), cast( '000000' as abap.tims ),
                       abap_system_timezone( $session.client,'NULL' ),
                       $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      else tstmp_to_dats( dats_tims_to_tstmp(RequirementDate, RequirementTime,
                       abap_system_timezone( $session.client,'NULL' ),
                       $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      end                                                                                  as RequirementDate,
      case RequirementTime when '240000'
      then tstmp_to_tims( dats_tims_to_tstmp(dats_add_days( RequirementDate, 1, 'NULL'), cast( '000000' as abap.tims ),
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      else tstmp_to_tims( dats_tims_to_tstmp(RequirementDate, RequirementTime,
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      end                                                                                  as RequirementTime,
      case RequirementTime when '240000'
      then cast(dats_tims_to_tstmp( dats_add_days( RequirementDate, 1, 'NULL'), cast( '000000' as abap.tims ),
                              abap_system_timezone( $session.client,'NULL' ),
                              $session.client, 'NULL') as timestamp preserving type)
      else cast(dats_tims_to_tstmp( RequirementDate,   RequirementTime,
                              abap_system_timezone( $session.client,'NULL' ),
                              $session.client, 'NULL') as timestamp preserving type)
      end                                                                                  as RequirementDateTime,
      Supplier,
      Plant,
      StorageLocation,
      ItemCategory                                                                         as MaintOrdOpCompItemCategory,
      //_ItemCategoryText[1:Language = $session.system_language ].BillOfMaterialItemCategoryDesc as BillOfMaterialItemCategoryDesc,

      GoodsMovementType,
      ReservationIsFinallyIssued,
      MaterialGroup,
      PurReqnOrResvnGeneration                                                             as MaintOrdOpCompIsMRPRelevant,
      MaterialCompIsProcuredDirectly,
      ProductTypeCode,
      ServicePerformer,
      case PerformancePeriodStartTime when '240000'
      then cast(dats_tims_to_tstmp( dats_add_days( PerformancePeriodStartDate, 1, 'NULL'), cast( '000000' as abap.tims ),
                              abap_system_timezone( $session.client,'NULL' ),
                              $session.client, 'NULL') as timestamp preserving type)
      else cast(dats_tims_to_tstmp( PerformancePeriodStartDate,   PerformancePeriodStartTime,
                              abap_system_timezone( $session.client,'NULL' ),
                              $session.client, 'NULL') as timestamp preserving type)
      end                                                                                  as PerformancePeriodStartDateTime,
      case PerformancePeriodStartTime when '240000'
      then tstmp_to_dats( dats_tims_to_tstmp(dats_add_days( PerformancePeriodStartDate, 1, 'NULL'), cast( '000000' as abap.tims ),
                       abap_system_timezone( $session.client,'NULL' ),
                       $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      else tstmp_to_dats( dats_tims_to_tstmp(PerformancePeriodStartDate, PerformancePeriodStartTime,
                       abap_system_timezone( $session.client,'NULL' ),
                       $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      end                                                                                  as PerformancePeriodStartDate,

      case PerformancePeriodStartTime when '240000'
      then tstmp_to_tims( dats_tims_to_tstmp(dats_add_days( PerformancePeriodStartDate, 1, 'NULL'), cast( '000000' as abap.tims ),
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      else tstmp_to_tims( dats_tims_to_tstmp(PerformancePeriodStartDate, PerformancePeriodStartTime,
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      end                                                                                  as PerformancePeriodStartTime,
      case PerformancePeriodEndTime when '240000'
      then cast(dats_tims_to_tstmp( dats_add_days( PerformancePeriodEndDate, 1, 'NULL'), cast( '000000' as abap.tims ),
                                    abap_system_timezone( $session.client,'NULL' ),
                                    $session.client, 'NULL') as timestamp preserving type)
      else cast(dats_tims_to_tstmp( PerformancePeriodEndDate,   PerformancePeriodEndTime,
                                    abap_system_timezone( $session.client,'NULL' ),
                                    $session.client, 'NULL') as timestamp preserving type)
      end                                                                                  as PerformancePeriodEndDateTime,
      case PerformancePeriodEndTime when '240000'
      then tstmp_to_dats( dats_tims_to_tstmp(dats_add_days( PerformancePeriodEndDate, 1, 'NULL'), cast( '000000' as abap.tims ),
                        abap_system_timezone( $session.client,'NULL' ),
                        $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      else tstmp_to_dats( dats_tims_to_tstmp(PerformancePeriodEndDate, PerformancePeriodEndTime,
                        abap_system_timezone( $session.client,'NULL' ),
                        $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      end                                                                                  as PerformancePeriodEndDate,

      case PerformancePeriodEndTime when '240000'
      then tstmp_to_tims( dats_tims_to_tstmp(dats_add_days( PerformancePeriodEndDate, 1, 'NULL'), cast( '000000' as abap.tims ),
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      else tstmp_to_tims( dats_tims_to_tstmp(PerformancePeriodEndDate, PerformancePeriodEndTime,
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client, 'NULL'), 'UTC', $session.client, 'NULL' )
      end                                                                                  as PerformancePeriodEndTime,
      LeanServiceDuration,
      LeanServiceDurationUnit,
      DistributionFunction,
      MaintOrdCompDeliveryDateAdjmt,
      SrvcSchedgIsAlignedWthOpWrkCtr,
      MaintOrderCompDebitCreditCode,
      GoodsMovementIsAllowed,
      MaintenanceOrderComponentBatch,
      MaintOrderComponentInternalID,
      QuantityIsFixed,
      MaintOrdOpComponentCurrency,
      MaintOrdOpComponentGLAccount,
      MaintOrdOpCompCostingRelevancy,
      MaintCompAltvProdUsgeRateInPct,
      MaintOrderOpComponentSortText,
      MaintOrdOpCompIsBulkProduct,
      MaterialProvisionType,
      MaintOrdOpCompAssgdWBSElmntInt,
      cast ( _WBSElement.WBSElement as vdm_ps_posid preserving type )                      as WBSElement,
      MaintOrderOpComponentPrice,
      MaintOrdOpCompPriceUnitQty,
      MatlCompIsMarkedForBackflush,
      PurchasingGroup,
      DeliveryTimeInDays,
      MaintOrdOpCompGdsRecipientName,
      MaintOrdOpCompUnloadingPtTxt,
      GoodsReceiptDurationInWorkDays,
      PurchasingInfoRecord,
      OperationLeadTimeOffset,
      OpsLeadTimeOffsetUnit,
      MaintOrdOpCompRequisitioner,
      MaintOrdOpCompProcmtTrckgNmbr,
      ResponsiblePurchaseOrg,
      PurchaseRequisition,
      PurchaseRequisitionItem,
      OverallLimitAmount,
      ExpectedOverallLimitAmount,
      //      MaintOrdCompIsDirectlyProcured,

      MaintOrdOpCompSpecialStockType,
      VariableSizeDimension1,
      VariableSizeDimensionUnit,
      VariableSizeCompFormulaKey,
      VariableSizeDimension2,
      NumberOfVariableSizeItem,
      VariableSizeDimension3,
      VariableSizeItemQuantity,
      VariableSizeComponentUnit,
      RqmtDateIsEnteredManually,
      SupplierProduct,
      MaintOrdCompCmtdQtyIsKept,
      MaintOrdOpCompPurOutlineAgrmt,
      MaintOrdCompPurOutlineAgrmtItm,
      IsDeleted,
      MaintOrdOpCompProcmtCatalog,
      MaintOrdOpCompProcmtCatalogItm,
      QuantityWithdrawnInBaseUnit,
      ConfirmedAvailableQuantity,

      _ReservationItem.RecipientLocationCode,
      _MaintenanceOrder.ControllingArea,
      _MaintenanceOrder,
      _MaintenanceOrderOperation,
      _ReservationItem,
      _UnitOfMeasure,
      _UnitOfMeasureEntry,
      _Plant,
      _StorageLocation,
      _ItemCategoryText,
      _ProductTypeCode,
      _ReservationIsFinallyIssued,
      _MaterialGroup,
      _PurReqnOrResvnGeneration,
      _Supplier,
      _MaintOrderOpCompLongText,
      _MaintOrdCompDelivDateAdjmtT

}
where
  _StatusObjectActiveStatus [1: StatusCode = 'I0013'].StatusCode is null // mark for deletion based on system status

//and IsDeleted                                                                                 = ''