R_HandlingUnitTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Handling Unit TP View'

@Search.searchable: true

@ObjectModel: {
   usageType: {
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #XL
   }
}

@ObjectModel.sapObjectNodeType.name:'HandlingUnit'

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

define root view entity R_HandlingUnitTP
  as select from I_HandlingUnitHeaderCombined
  composition [0..*] of R_HandlingUnitItemTP                      as _HandlingUnitItem


  composition [0..*] of R_HandlingUnitReferenceDocTP              as _HandlingUnitReferenceDoc

  composition [0..*] of R_HandlingUnitAlternativeIdTP             as _HandlingUnitAlternativeID

  //Extensibility

  association [0..1] to E_HandlingUnitHeader                      as _Extension on $projection.HandlingUnitExternalID = _Extension.HandlingUnitExternalID

{

      @Search.defaultSearchElement : true
      @Search.fuzzinessThreshold : 0.8
      @Search.ranking : #HIGH
  key HandlingUnitExternalID,
  key Warehouse,
      cast(HandlingUnitCharUUID as char32)                        as HandlingUnitCharUUID, //proper casting needs to be implemented | Edm.GUID


      HandlingUnitExternalIdType,
      cast( '' as lohum_hu_extid_check_disabled preserving type ) as HndlgUnitExtIDCheckIsDisabled,

      Plant,
      StorageLocation,
      ShippingPoint,

      HandlingUnitInternalID,
      HandlingUnitLowerLevelRefer,
      ParentHandlingUnitNumber,
      HighestLevelHandlingUnitNumber,

      PackagingMaterial,
      PackagingMaterialType,

      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      GrossWeight,
      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      NetWeight,
      @Semantics.quantity.unitOfMeasure: 'WeightUnit'
      HandlingUnitMaxWeight,
      WeightUnit,

      @Semantics.quantity.unitOfMeasure: 'HandlingUnitTareWeightUnit'
      HandlingUnitTareWeight,
      HandlingUnitTareWeightUnit,

      @Semantics.quantity.unitOfMeasure: 'VolumeUnit'
      GrossVolume,
      @Semantics.quantity.unitOfMeasure: 'VolumeUnit'
      HandlingUnitNetVolume,
      @Semantics.quantity.unitOfMeasure: 'VolumeUnit'
      HandlingUnitMaxVolume,
      VolumeUnit,

      @Semantics.quantity.unitOfMeasure: 'HandlingUnitTareVolumeUnit'
      HandlingUnitTareVolume,
      HandlingUnitTareVolumeUnit,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasureDimension'
      HandlingUnitLength,
      HandlingUnitWidth,
      HandlingUnitHeight,
      UnitOfMeasureDimension,

      HandlingUnitPackingObjectType,
      //remove leading zeros

      ltrim( HandlingUnitReferenceDocument, '0'   )               as HandlingUnitReferenceDocument,
      HandlingUnitHasCrossRefDoc,

      CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      cast( CreationDateTime as tzntstmps)                        as CreationDateTime,
      LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast( LastChangeDateTime as tzntstmps)                      as LastChangeDateTime,

      HandlingUnitInternalStatus,

      HandlingUnitProcessStatus,

      SourceHandlingUnitUUID,
      PackingInstruction,
      HandlingUnitSecondExternalId,
      HandlingUnitSlotNumber,
      HndlgUnitRlvnceForJIT,

      // EWM fields

      StorageType,
      StorageSection,
      StorageBin,
      EWMResource,
      EWMConsolidationGroup,
      HandlingUnitIsClosed,
      // EWM fields Process Oriented Storage Control (POSC)

      // E.g., After packing create a warehouse task to move a HU from a work center to the staging/goods issue area

      ExternalStorageProcessStep,
      StorageProcess,
      EWMHUProcessStepIsCompleted,
      // EWM fields HU Process Status

      EWMHandlingUnitIsPlanned,
      EWMHandlingUnitIsInStock,
      EWMHandlingUnitIsUnloaded,
      EWMHandlingUnitIsLoaded,
      EWMTranspUnitIsAssigned,
      // EWM fields HU Blocked Status

      EWMHUContentChangeIsBlocked,
      EWMHUMovementChangeIsBlocked,
      EWMHUAttributeChangeIsBlocked,
      EWMHUPostingChangeIsBlocked,
      EWMHUIsBlockedByCustoms,
      EWMHUIsPackedForShipping,

      HandlingUnitType                                            as EWMHandlingUnitType,

      EWMSrlNmbrForPackagingMaterial,

      @Semantics.quantity.unitOfMeasure: 'HandlingUnitMaxDimensionUnit'
      HandlingUnitMaxLength,
      @Semantics.quantity.unitOfMeasure: 'HandlingUnitMaxDimensionUnit'
      HandlingUnitMaxWidth,
      @Semantics.quantity.unitOfMeasure: 'HandlingUnitMaxDimensionUnit'
      HandlingUnitMaxHeight,
      HandlingUnitMaxDimensionUnit,

      // Multifitment Point

      EWMHUIsJITUpdateRelevant,
      EWMHUDestinationProdnSupArea,
      EWMHUDestinationStorageBin,

      /* Associations */
      _HandlingUnitItem,
      _HandlingUnitReferenceDoc,
      _HandlingUnitAlternativeID,
      _UnitOfMeasureDimension,
      _VolumeUnit,
      _VolumeUnitTare,
      _WeightUnit,
      _WeightUnitTare
}