R_HandlingUnitItemTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Handling Unit Item TP View'

@Search.searchable: true

@ObjectModel: {
   usageType: {
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #XL
   }
}

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

define view entity R_HandlingUnitItemTP
  as select from I_HandlingUnitItemCombined
  association to parent R_HandlingUnitTP as _HandlingUnit on  $projection.HandlingUnitExternalID = _HandlingUnit.HandlingUnitExternalID
                                                          and $projection.Warehouse              = _HandlingUnit.Warehouse
                                                          
 composition [0..*] of R_HandlingUnitItemSerialNoTP as _HandlingUnitItemSerialNumber                    
                                                          
{
      @Search.defaultSearchElement : true
      @Search.fuzzinessThreshold : 0.8
      @Search.ranking : #HIGH
  key HandlingUnitExternalID,
  key Warehouse,
  key StockItemUUID,
  
      HandlingUnitItem,
      Material,
      HandlingUnitInternalID,
      HandlingUnitTypeOfContent,
      cast( '00000000000000000000' as exidv) as HandlingUnitNestedExternalID,     
      HandlingUnitReferenceDocument,
      HandlingUnitRefDocumentItem,
      
      @Semantics.quantity.unitOfMeasure: 'HandlingUnitQuantityUnit'
      cast ( HandlingUnitQuantity as vemng ) as HandlingUnitQuantity,
      HandlingUnitQuantityUnit,
      HandlingUnitAltUnitOfMeasure,
      

      MaterialName,
      
      Batch,
      
      Plant,
      StorageLocation,
      
      ShelfLifeExpirationDate,
      HandlingUnitGoodsReceiptDate,
      
      CountryOfOrigin,
      
      HandlingUnitNrOfAuxPackgMat,
      
      HandlingUnitNumberOfSerialNumb,
      SerialNumberProfile,

// Extension for JIT Call Reference

      InternalJITCallNumber, 
      JITCallComponentGrpItemNumber,
            
      /* Associations */
      _HandlingUnit,
      _HandlingUnitAltUnitOfMeasure,
      _HandlingUnitQuantityUnit,
      _HandlingUnitItemSerialNumber 
}