P_MfgOrderCompAssemblyAction

@AbapCatalog.sqlViewName: 'PMPECOMPASSYACTN'
@AbapCatalog.compiler.compareFilter:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view P_MfgOrderCompAssemblyAction
  as select from I_MfgOrderComponentAssembly
{
      //I_MfgOrderComponentAssembly

  key AssemblyDocument,
  key AssemblyDocumentItem,
  key cast(case
        when DebitCreditCode = 'S' then case
      -- Assembly with regard to by-product
          when MaterialComponentQuantity < 0 then
            case
              when AssemblyShopFloorItem = 0 then 'SAP_MATERIAL_REASSEMBLY_OA'
              else 'SAP_MATERIAL_REASSEMBLY_SFI'
            end
          else
            case
              when AssemblyShopFloorItem = 0 then 'SAP_MATERIAL_RETURN_OA'
              else 'SAP_MATERIAL_RETURN_SFI'
            end
          end
        else case
      -- Assembly with regard to standard component
          when MaterialComponentQuantity < 0 then
            case
              when AssemblyShopFloorItem = 0 then 'SAP_COMP_DISASSEMBLY_OA'
              else 'SAP_COMP_DISASSEMBLY_SFI'
            end
          else
            case
              when AssemblyShopFloorItem = 0 then 'SAP_COMP_ASSEMBLY_OA'
              else 'SAP_COMP_ASSEMBLY_SFI'
            end
          end
      end as mpe_action_name_type) as MfgProcgExecAction,
      Reservation,
      ReservationItem,
      RecordType,
      OpActyNtwkInstance,
      OpActyNtwkElement,
      AssemblyShopFloorItem,
      ShopFloorItem,
      Batch,
      Material,
      RequiredQuantity,
      MaterialComponentQuantity,
      MaterialBaseUnit,
      CreationDateTime,
      CreatedByUser,
      Plant,
      StorageLocation,
      InventoryUsabilityCode,
      CompAssemblyGoodsMvtStatus,
      PostingIsRetroactive,
      QuantityInEntryUnit,
      EntryUnit,
      MaterialDocument,
      MaterialDocumentYear,
      GoodsMovementException,
      GoodsMovementExceptionItem,
      ExecOpActyNtwkInstance,
      ExecOpActyNtwkElement,
      DebitCreditCode,
      OpActySFIGrpAssemblyDocument,
      OpActySFIGrpAssyDocumentItem,

      _ExecOpActyNtwkInstance,
      _ExecOperationActivityInstance,
      _GoodsMovementException,
      _GoodsMovementExceptionItem,
      _Material,
      _MaterialBaseUnit,
      _MaterialDocumentHeader,
      _MaterialDocumentYear,
      _OpActyNtwkInstance,
      _OperationActivityInstance,
      _ParentShopFloorItem,
      _Plant,
      _Reservation,
      _ReservationItem,
      _ShopFloorItem,
      _StorageLocation
}
where
  AssemblyCorrectionDocument = 0