I_MFGORDERCOMPONENTASSEMBLY
Manufacturing Order Component Assembly
I_MFGORDERCOMPONENTASSEMBLY is a CDS View in S/4HANA. Manufacturing Order Component Assembly. It contains 34 fields. 16 CDS views read from this table.
CDS Views using this table (16)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_MfgOrderCompAssemblyInstce | view | from | BASIC | Manufacturing order component assembly instance |
| I_OpActyAssemblyByComponent | view | from | COMPOSITE | OA Assembly by Component, Material and Plant |
| I_SFIAtOpActyAssyByComponent | view | from | COMPOSITE | SFI at OA Assembly by Component, Material and Plant |
| I_SFIDisassemblyByComponent | view_entity | from | COMPOSITE | SFI Disassembly by Component |
| I_SFODisassemblyByComponent | view_entity | from | COMPOSITE | Shop Floor Order Disassembly by Component |
| P_MfgOrdCompAssyByOpActyParSFI | view | from | CONSUMPTION | |
| P_MfgOrderCompAssemblyAction | view | from | COMPOSITE | |
| P_MfgOrderCompAssemblyAggrgn | view | from | COMPOSITE | |
| P_MfgOrderCompAssyWthoutInstce | view | from | COMPOSITE | |
| P_MfgOrderCompInstceAssyQty | view | inner | COMPOSITE | |
| P_MfgOrderComponentAssemblyAgg | view | from | CONSUMPTION | |
| P_MfgOrderOriglComponentAssy | view | from | COMPOSITE | |
| P_OpActyInstanceAssembledComp | view | from | COMPOSITE | |
| P_SFIOpActyUnplndCompAssmblAgg | view | from | CONSUMPTION | |
| P_ShopFloorItemAssembly | view | from | COMPOSITE | |
| P_ShopFloorItemComponents | view | from | COMPOSITE |
Fields (34)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | AssemblyDocument | AssemblyDocument | 3 |
| KEY | AssemblyDocumentItem | AssemblyDocumentItem | 3 |
| KEY | AssemblyShopFloorItem | AssemblyShopFloorItem | 9 |
| KEY | Batch | Batch | 5 |
| KEY | CreationDateTime | CreationDateTime | 2 |
| KEY | Material | Material | 9 |
| KEY | OpActyNtwkElement | OpActyNtwkElement | 11 |
| KEY | OpActyNtwkInstance | OpActyNtwkInstance | 11 |
| KEY | Plant | Plant | 9 |
| KEY | RecordType | RecordType | 11 |
| KEY | Reservation | Reservation | 12 |
| KEY | ReservationItem | ReservationItem | 11 |
| KEY | ShopFloorItem | ShopFloorItem | 6 |
| _BatchDistinct | _BatchDistinct | 3 | |
| _Material | _Material | 8 | |
| _MaterialBaseUnit | _MaterialBaseUnit | 1 | |
| _OpActyNtwkInstance | _OpActyNtwkInstance | 9 | |
| _OperationActivityInstance | _OperationActivityInstance | 7 | |
| _ParentShopFloorItem | _ParentShopFloorItem | 7 | |
| _Plant | _Plant | 5 | |
| _Reservation | _Reservation | 7 | |
| _ReservationItem | _ReservationItem | 3 | |
| _ShopFloorItem | _ShopFloorItem | 5 | |
| _StorageLocation | _StorageLocation | 2 | |
| CreatedByUser | CreatedByUser | 1 | |
| DebitCreditCode | DebitCreditCode | 4 | |
| EntryUnit | EntryUnit | 2 | |
| InventoryUsabilityCode | InventoryUsabilityCode | 1 | |
| MaterialBaseUnit | MaterialBaseUnit | 3 | |
| MaterialComponentQuantity | MaterialComponentQuantity | 1 | |
| PostingIsRetroactive | PostingIsRetroactive | 1 | |
| QuantityInEntryUnit | QuantityInEntryUnit | 1 | |
| RequiredQuantity | RequiredQuantity | 1 | |
| StorageLocation | StorageLocation | 3 |
@AbapCatalog.sqlViewName: 'IMPECOMPASSEMBLE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC
@EndUserText.label: 'Manufacturing Order Component Assembly'
define view I_MfgOrderComponentAssembly
as select from mpe_comp_assembl as asm
association [1..1] to I_Material as _Material on $projection.Material = _Material.Material
association [1..1] to I_OpActyNtwkInstance as _OpActyNtwkInstance on $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
association [1..1] to I_OperationActivityInstance as _OperationActivityInstance on $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
and $projection.OpActyNtwkElement = _OperationActivityInstance.OpActyNtwkElement
association [0..1] to I_ShopFloorItem as _ShopFloorItem on $projection.ShopFloorItem = _ShopFloorItem.ShopFloorItem
association [1..1] to I_ShopFloorItem as _ParentShopFloorItem on $projection.AssemblyShopFloorItem = _ParentShopFloorItem.ShopFloorItem
association [0..1] to I_BatchDistinct as _BatchDistinct on (
$projection.Plant = _BatchDistinct.Plant
or _BatchDistinct.Plant = ' '
)
and $projection.Material = _BatchDistinct.Material
and $projection.Batch = _BatchDistinct.Batch
association [0..1] to I_ReservationDocumentHeader as _Reservation on $projection.Reservation = _Reservation.Reservation
association [0..1] to I_ReservationItem as _ReservationItem on $projection.Reservation = _ReservationItem.Reservation
and $projection.ReservationItem = _ReservationItem.ReservationItem
and $projection.RecordType = _ReservationItem.RecordType
association [0..1] to I_UnitOfMeasure as _MaterialBaseUnit on $projection.MaterialBaseUnit = _MaterialBaseUnit.UnitOfMeasure
association [0..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [0..1] to I_StorageLocation as _StorageLocation on $projection.Plant = _StorageLocation.Plant
and $projection.StorageLocation = _StorageLocation.StorageLocation
association [0..1] to I_MaterialDocumentYear as _MaterialDocumentYear on $projection.MaterialDocumentYear = _MaterialDocumentYear.MaterialDocumentYear
association [0..1] to I_MaterialDocumentHeader as _MaterialDocumentHeader on $projection.MaterialDocument = _MaterialDocumentHeader.MaterialDocument
and $projection.MaterialDocumentYear = _MaterialDocumentHeader.MaterialDocumentYear
association [0..1] to I_GoodsMovementException as _GoodsMovementException on $projection.GoodsMovementException = _GoodsMovementException.GoodsMovementException
association [0..1] to I_GoodsMovementExceptionItem as _GoodsMovementExceptionItem on $projection.GoodsMovementException = _GoodsMovementExceptionItem.GoodsMovementException
and $projection.GoodsMovementExceptionItem = _GoodsMovementExceptionItem.GoodsMovementExceptionItem
association [1..1] to I_OpActyNtwkInstance as _ExecOpActyNtwkInstance on $projection.ExecOpActyNtwkInstance = _ExecOpActyNtwkInstance.OpActyNtwkInstance
association [1..1] to I_OperationActivityInstance as _ExecOperationActivityInstance on $projection.ExecOpActyNtwkInstance = _ExecOperationActivityInstance.OpActyNtwkInstance
and $projection.ExecOpActyNtwkElement = _ExecOperationActivityInstance.OpActyNtwkElement
association [0..1] to I_MfgOrderCompAssyCorrection as _MfgOrderCompAssyCorrection on $projection.AssemblyCorrectionDocument = _MfgOrderCompAssyCorrection.AssemblyCorrectionDocument
{
key asm.adoc_number as AssemblyDocument,
key asm.adoc_item as AssemblyDocumentItem,
@ObjectModel.foreignKey.association: '_Reservation'
asm.rsnum as Reservation,
asm.rspos as ReservationItem,
asm.rsart as RecordType,
@ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyNtwkInstanceStdVH', element: 'OpActyNtwkInstance' } } ]
asm.oan_instance_id as OpActyNtwkInstance,
@ObjectModel.foreignKey.association: '_OperationActivityInstance'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyInstceStdVH', element: 'OpActyNtwkElement' } } ]
asm.oan_element_number as OpActyNtwkElement,
@ObjectModel.foreignKey.association: '_ParentShopFloorItem'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ShopFloorItemStdVH', element: 'ShopFloorItem' } } ]
asm.parent_sfi_id as AssemblyShopFloorItem,
@ObjectModel.foreignKey.association: '_ShopFloorItem'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_ShopFloorItemStdVH', element: 'ShopFloorItem' } } ]
asm.sfi_id as ShopFloorItem,
asm.batch as Batch,
--asm.batch_plant as Plant,
@ObjectModel.foreignKey.association: '_Material'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
asm.material as Material,
@Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
asm.pl_quantity as RequiredQuantity,
@Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
asm.quantity as MaterialComponentQuantity,
@Semantics.unitOfMeasure: true
asm.uom as MaterialBaseUnit,
@Semantics.systemDateTime.createdAt: true
asm.crtn_time as CreationDateTime,
@Semantics.user.createdBy: true
asm.crtn_user as CreatedByUser,
@ObjectModel.foreignKey.association: '_Plant'
asm.werks as Plant,
@ObjectModel.foreignKey.association: '_StorageLocation'
asm.lgort as StorageLocation,
cast(asm.insmk as inventoryusabilitycode preserving type) as InventoryUsabilityCode,
asm.gm_status as CompAssemblyGoodsMvtStatus,
asm.is_posted_retroactively as PostingIsRetroactive,
@Semantics.quantity.unitOfMeasure: 'EntryUnit'
asm.erfmg as QuantityInEntryUnit,
@Semantics.unitOfMeasure: true
asm.erfme as EntryUnit,
@ObjectModel.foreignKey.association: '_MaterialDocumentHeader'
asm.mblnr as MaterialDocument,
@ObjectModel.foreignKey.association: '_MaterialDocumentYear'
asm.mjahr as MaterialDocumentYear,
@ObjectModel.foreignKey.association: '_GoodsMovementException'
cast(asm.weblnr as pph_weblnr preserving type) as GoodsMovementException,
@ObjectModel.foreignKey.association: '_GoodsMovementExceptionItem'
cast(asm.weblpos as pph_weblpos preserving type) as GoodsMovementExceptionItem,
@ObjectModel.foreignKey.association: '_ExecOpActyNtwkInstance'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyNtwkInstanceStdVH', element: 'OpActyNtwkInstance' } } ]
asm.exec_oan_instance_id as ExecOpActyNtwkInstance,
@ObjectModel.foreignKey.association: '_ExecOperationActivityInstance'
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyInstceStdVH', element: 'OpActyNtwkElement' } } ]
asm.exec_oan_element_number as ExecOpActyNtwkElement,
asm.shkzg as DebitCreditCode,
asm.crrtn_doc_number as AssemblyCorrectionDocument,
asm.crrtn_item_type as AssemblyCorrectionItemType,
asm.sfi_grp_assy_doc_number as OpActySFIGrpAssemblyDocument,
asm.sfi_grp_assy_doc_item as OpActySFIGrpAssyDocumentItem,
_OpActyNtwkInstance,
_OperationActivityInstance,
_ShopFloorItem,
_ParentShopFloorItem,
_BatchDistinct,
_Material,
_Plant,
_StorageLocation,
_Reservation,
_ReservationItem,
_MaterialBaseUnit,
_MaterialDocumentHeader,
_MaterialDocumentYear,
_GoodsMovementException,
_GoodsMovementExceptionItem,
_ExecOpActyNtwkInstance,
_ExecOperationActivityInstance,
_MfgOrderCompAssyCorrection
}