P_InternalOrderGroupNode

@AbapCatalog: {
  compiler.compareFilter: true,
  preserveKey: true,
  sqlViewName: 'PWUIOGRPNODE'
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
  private: true,
  viewType: #COMPOSITE
}
define view P_InternalOrderGroupNode
  with parameters
    P_InternalOrder : aufnr
  as select from I_Setnode
    left outer to one join P_InternalOrderGroupLeaf as IOGleaf
      on I_Setnode.ChildSetClass       = IOGleaf.SetClass
        and I_Setnode.ChildSetSubClass = IOGleaf.SetSubClass
        and I_Setnode.ChildSetID       = IOGleaf.SetID
        and IOGleaf.SetRangeFromValue <= :P_InternalOrder
        and IOGleaf.SetRangeToValue   >= :P_InternalOrder
    association [0..*] to P_InternalOrderGroupNode as _parent
      on $projection.ChildSetClass       = _parent.SetClass
        and $projection.ChildSetSubClass = _parent.SetSubClass
        and $projection.ChildSetID       = _parent.SetID
{
  //i_setnode

  key I_Setnode.SetClass,
  key I_Setnode.SetSubClass,
  key I_Setnode.SetID,
  key I_Setnode.SetLineNumber,
  key IOGleaf.SetLineNumber as leafsetlinenumber,
  
  ChildSetClass,
  ChildSetSubClass,
  ChildSetID,
  SetNodeIsLeaf,
  SetRangeFromValue,
  SetRangeToValue,

  /* associations */
  _parent,

  //i_setnode

  i_setnode._Set
}
where I_Setnode.SetClass = '0103'

// add leaves those stand as root themselves, therefore they are not a part of the setnode table

union all
  select from P_InternalOrderGroupLeaf as IOGLeaf
    left outer to one join I_Setnode
      on IOGLeaf.SetClass = I_Setnode.ChildSetClass
        and IOGLeaf.SetSubClass = I_Setnode.ChildSetSubClass
        and IOGLeaf.SetID = I_Setnode.ChildSetID
    association [0..*] to P_InternalOrderGroupNode as _Parent
      on $projection.ChildSetClass       = _Parent.SetClass
        and $projection.ChildSetSubClass = _Parent.SetSubClass
        and $projection.ChildSetID       = _Parent.SetID
{
  //I_Setnode

  key IOGLeaf.SetClass,
  key IOGLeaf.SetSubClass,
  key IOGLeaf.SetID,
  key IOGLeaf.SetLineNumber,
  key IOGLeaf.SetLineNumber as LeafSetLineNumber,
  
  IOGLeaf.SetClass as ChildSetClass,
  IOGLeaf.SetSubClass as ChildSetSubClass,
  IOGLeaf.SetID as ChildSetID,
  SetNodeIsLeaf,
  SetRangeFromValue,
  SetRangeToValue,

  /* Associations */
  _Parent,

  //I_Setnode

  IOGLeaf._Set
}
where I_Setnode.ChildSetClass is null
  and IOGLeaf.SetClass = '0103'
  and IOGLeaf.SetRangeFromValue <= :P_InternalOrder
  and IOGLeaf.SetRangeToValue   >= :P_InternalOrder