P_EHSTaskOutCome

@AbapCatalog: {
   sqlViewName: 'PEHSTASKOUTCOME',
   buffering.status: #SWITCHED_OFF,
   buffering.type: #NONE,
   preserveKey:true
 }
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
//@EndUserText.label: 'Outcome of an EHS Task'

@VDM: {
  private: true,
  viewType: #CONSUMPTION
}
define view P_EHSTaskOutCome
  as select from           I_WorkflowTask
    left outer to one join I_EHSWorkflowDecisionStatus  as _WorkflowDecisionStatus        on I_WorkflowTask.WorkflowTaskInternalID = _WorkflowDecisionStatus.WorkflowTaskInternalID
    left outer to one join I_EHSWrkflwDecisionConfign as _WorkflowDecisionConfiguration on  _WorkflowDecisionConfiguration.WorkflowTaskDefinition = I_WorkflowTask.TopLevelWorkflowTaskDefinition
                                                                                           and _WorkflowDecisionConfiguration.EHSWorkflowStep           = _WorkflowDecisionStatus.EHSWorkflowStep
                                                                                           and _WorkflowDecisionConfiguration.EHSWorkflowDecisionOption = _WorkflowDecisionStatus.EHSWorkflowDecisionOption
    left outer to one join I_EHSWrkflwDecisionConfignText   as _WorkflowDecisionConfignText   on  _WorkflowDecisionConfignText.WorkflowTaskDefinition = I_WorkflowTask.TopLevelWorkflowTaskDefinition
                                                                                           and _WorkflowDecisionConfignText.EHSWorkflowStep           = _WorkflowDecisionStatus.EHSWorkflowStep
                                                                                           and _WorkflowDecisionConfignText.EHSWorkflowDecisionOption = _WorkflowDecisionStatus.EHSWorkflowDecisionOption
                                                                                           and _WorkflowDecisionConfignText.Language               = $session.system_language
  association [0..*] to I_OTRText as _OTRText on _OTRText.Language = $session.system_language
{
  key I_WorkflowTask.WorkflowTaskInternalID,
      I_WorkflowTask.TopLevelWorkflowTask,
      I_WorkflowTask.WorkflowTaskStatus,
      _WorkflowDecisionStatus.EHSWorkflowDecisionOption as EHSTaskReturnValue,
      case _WorkflowDecisionConfiguration.EHSWorkflowDecisionOptionNatr
        when 'POSITIVE' then 'Positive'
        when 'NEGATIVE' then 'Negative'
        else
          case WorkflowTaskStatus
            when 'COMPLETED' then 'Positive'
            else 'Neutral'
         end
      end                                            as EHSTaskState,
      case WorkflowTaskStatus
        when 'READY' then _OTRText[1: OnlnTxtRpstryConceptID = '8CDCD4008ED01EE7B99729E18D2581F1'].Text
        when 'WAITING' then _OTRText[1: OnlnTxtRpstryConceptID = '8CDCD4008ED01EE7B997323DF0A2420F'].Text
        when 'SELECTED' then _OTRText[1: OnlnTxtRpstryConceptID = '8CDCD4008ED01EE7B9973520F486626E'].Text
        when 'STARTED' then _OTRText[1: OnlnTxtRpstryConceptID = '8CDCD4008ED01EE7B9973520F486626E'].Text
        when 'CANCELLED' then _OTRText[1: OnlnTxtRpstryConceptID = '8CDCD4008ED01EE7B9973803E9FBA271'].Text
        when 'CHECKED' then _OTRText[1: OnlnTxtRpstryConceptID= '0894EF4587211ED8928F0E1C77285C8B'].Text
        when 'COMPLETED' then
          case
            when _WorkflowDecisionConfignText.EHSWorkflowDecisionOptionName != '' then _WorkflowDecisionConfignText.EHSWorkflowDecisionOptionName
            else _OTRText[1: OnlnTxtRpstryConceptID = '8CDCD4008ED01EE7B9973BB0BF4DC276'].Text
          end
        else _OTRText[1: OnlnTxtRpstryConceptID = '8CDCD4008ED01EE7B9974E2D974642E2'].Text
      end                                            as EHSTaskStateText
}