P_DwnPaytReqProcessor

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'VSDPR Current Processor'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.private:true
@VDM.viewType: #COMPOSITE

// Processor Logic: Completed or cancelled

// task of TS78500119 is required for Manually approved with status complated and cancelled

// task of TS78500120 is required for auto-approved with status completed


// Processor Logic: like Submit

// Processor of Manually approved is retrieved from I_WorkflowTaskOrglObject 

define view entity P_DwnPaytReqProcessor as select from I_WorkflowTask {
  key WorkflowTaskInternalID,
      TopLevelWorkflowTask,
      
      case WorkflowTaskStatus
        when 'COMPLETED'
          then WorkflowTaskCurrentUser
        when 'CANCELLED'
          then WorkflowTaskCreatedByUser
        else '' 
        end as WorkflowTaskCurrentUser,
          
      cast('X' as xfeld) as IsApproved,
      WorkflowTaskResult 
      
}where ( WorkflowTaskDefinition = 'TS78500119' or WorkflowTaskDefinition = 'TS78500120' )  
   and ( WorkflowTaskStatus = 'COMPLETED' or WorkflowTaskStatus = 'CANCELLED' ) 

union select from I_WorkflowTaskOrglObject as _PendingTask
      association [1..1] to I_WorkflowTask as _Task 
                                           on _PendingTask.WorkflowTaskInternalID = _Task.WorkflowTaskInternalID
  {
  key WorkflowTaskInternalID,
      _Task.TopLevelWorkflowTask,
      WorkflowOrglObject as WorkflowTaskCurrentUser,
      cast('' as xfeld) as IsApproved,
      cast('' as xfeld) as WorkflowTaskResult 

}where WorkflowTaskDefinition = 'TS78500119'
   and WorkflowTaskIsVisibleInInbox is initial  //not relevant should be false. such as case of forward, the vlaue is true