P_ChmlProdCatztnReuse

@AbapCatalog:
{
  -- SQL view name (16 characters)
  sqlViewName: 'PCHMLPRDCZREUSE',

  --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true,
  preserveKey: true
}

--Access Control: Authorizations Checks
@AccessControl:
{
  // authorization check not required as view only reads domain values

  authorizationCheck: #NOT_REQUIRED
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

--VDM view type
@VDM.viewType: #BASIC

@VDM.private: true

@ObjectModel:
{

  --Performance Annotations
  usageType:
  {
    dataClass: #META,
    sizeCategory: #S,
    serviceQuality: #B
  },
  representativeKey: 'ProdCmplncPhrs'
}
/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] } */
define view P_ChmlProdCatztnReuse
  --Select data from domain value table
  as select from dd07l as P_ChmlProdCatztn

  --Text association
  association [0..*] to P_ChmlProdCatztnReuseText as _Text on $projection.ProdCmplncPhrs = _Text.ProdCmplncPhrs
{

  key hextobin('00000000000000000000000000000000')                     as ProdCmplncPhrsUUID,

      @ObjectModel.text.association: '_Text'
  key P_ChmlProdCatztn.domvalue_l                                      as ProdCmplncPhrs,

      _Text[1: Language = $session.system_language].ProdCmplncPhrsText as ProdCmplncPhrsText,

      /*Association*/
      _Text
}
where
      P_ChmlProdCatztn.domname  = 'EHFND_CHM_PROD_CATZTN_PH_REUSE'
  and P_ChmlProdCatztn.as4local = 'A'