P_ChmlProdCatztnReuseText

@AbapCatalog:
{
  sqlViewName: 'PCHMLPRDCZREUSET',
  compiler.compareFilter: true,
  preserveKey: true
}

// authorization check not required as view only reads domain values

@AccessControl.authorizationCheck: #NOT_REQUIRED

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC
@VDM.private: true

@ObjectModel:
{
  --Performance annotation
  usageType:
  {
    dataClass: #META,
    serviceQuality: #B,
    sizeCategory: #S
  },
  --Representative Key
  representativeKey: 'ProdCmplncPhrs'
}

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] } */
define view P_ChmlProdCatztnReuseText
  --Select data from domain value description table
  as select from dd07t as P_ChmlProdCatztnText

  --association to I_Language
  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      --Domain Value of Basic Data Status
  key hextobin('00000000000000000000000000000000') as ProdCmplncPhrsUUID,

  key P_ChmlProdCatztnText.domvalue_l              as ProdCmplncPhrs,

      --Language
      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key P_ChmlProdCatztnText.ddlanguage              as Language,

      --language-dependent description of domain value
      @Semantics.text: true
      P_ChmlProdCatztnText.ddtext                  as ProdCmplncPhrsText,

      /* Associations */
      _Language
}
where
      P_ChmlProdCatztnText.domname  = 'EHFND_CHM_PROD_CATZTN_PH_REUSE'
  and P_ChmlProdCatztnText.as4local = 'A'