P_Bseg_Add

@VDM.viewType: #BASIC
@VDM.private:true
@AccessControl.authorizationCheck: #NOT_ALLOWED
@AbapCatalog.buffering.status: #NOT_ALLOWED
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'PBSEGADD' 

define view P_Bseg_Add 
   as select from bseg_add
    
   left outer to one join I_JournalEntry   on  bseg_add.bukrs = I_JournalEntry.CompanyCode 
                                           and bseg_add.belnr = I_JournalEntry.AccountingDocument
                                           and bseg_add.gjahr = I_JournalEntry.FiscalYear 
{
  key cast( bukrs as fis_bukrs )                                           as CompanyCode,
  key cast( belnr as farp_belnr_d )                                        as AccountingDocument,
  key cast( gjahr as fis_gjahr )                                           as FiscalYear,
  key cast( cast( SUBSTRING(buzei, 4, 3) as abap.numc(3) ) as farp_buzei ) as AccountingDocumentItem,
  
  cast( augbl as farp_augbl preserving type )                              as ClearingJournalEntry, 
  cast( auggj as fis_auggj_no_conv preserving type )                       as ClearingJournalEntryFiscalYear,
  cast( koart as farp_koart )                                              as FinancialAccountType,
  cast( bstat as fis_bstat )                                               as AccountingDocumentCategory,
  cast( zuonr as fis_zuonr )                                               as AssignmentReference,
  cast( sgtxt as farp_sgtxt )                                              as DocumentItemText,
  cast( rebzg as fis_rebzg )                                               as InvoiceReference,
  cast( rebzt as farp_rebzt )                                              as FollowOnDocumentType,
  cast( hkont as fis_racct )                                               as GLAccount,
  buzid                                                                    as AccountingDocumentItemType,
  rfzei                                                                    as PaymentCardItem,  
  
  @Semantics.currencyCode:true
  I_JournalEntry.CompanyCodeCurrency,
  I_JournalEntry.AccountingDocumentType,
  I_JournalEntry.PostingDate,
  I_JournalEntry.DocumentDate,
  I_JournalEntry.ReferenceDocumentType,
  
  @Semantics.currencyCode:true
  I_JournalEntry.AdditionalCurrency1,
  
  @Semantics.currencyCode:true
  I_JournalEntry.AdditionalCurrency2,
  
  @DefaultAggregation: #SUM
  @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} } 
   cast(case shkzg  
               when 'H' then   cast(-dmbtr as abap.curr( 23,2))
               when 'S' then   cast( dmbtr as abap.curr( 23,2))
               else cast( dmbtr as abap.curr( 23,2))
        end as fis_hsl)                                                    as AmountInCompanyCodeCurrency,
        
   
   
  @DefaultAggregation: #SUM
  @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} } 
   cast(case shkzg  
               when 'H' then   cast(-dmbe2 as abap.curr( 23,2))
               when 'S' then   cast( dmbe2 as abap.curr( 23,2))
               else cast( dmbe2 as abap.curr( 23,2))
        end as fis_dmbe2)                                                  as AmountInAdditionalCurrency1,
        
  @DefaultAggregation: #SUM
  @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} } 
   cast(case shkzg  
               when 'H' then   cast(-dmbe3 as abap.curr( 23,2))
               when 'S' then   cast( dmbe3 as abap.curr( 23,2))
               else cast( dmbe3 as abap.curr( 23,2))
        end as fis_dmbe3)                                                  as AmountInAdditionalCurrency2
}