P_BOOOperationChangeState

@AbapCatalog.sqlViewName: 'PPPBOOOPERCS'
@AbapCatalog.compiler.compareFilter:true 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@VDM.private: true

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view P_BOOOperationChangeState
  as select from I_BillOfOperationsOpBasic     as plpo
    inner join   I_BOOSqncOperationAssgmtChgSt as plas on  plas.BillOfOperationsType   =  plpo.BillOfOperationsType
                                                       and plas.BillOfOperationsGroup  =  plpo.BillOfOperationsGroup
                                                       and plas.BOOOperationInternalID =  plpo.BOOOperationInternalID
                                                       and plas.ValidityStartDate      <= plpo.ValidityEndDate
                                                       and plas.ValidityEndDate        >= plpo.ValidityStartDate

  -- Application is always '*' in T430
  /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
  association [1..1] to I_OperationControlProfile      as _OperationControlProfile       on  $projection.OperationControlProfile = _OperationControlProfile.OperationControlProfile

  /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
  association [1..1] to I_OperationStandardText        as _OperationStandardText         on  $projection.OperationStandardTextCode = _OperationStandardText.OperationStandardTextCode


  /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
  association [0..1] to I_EmployeeWageGroup            as _EmployeeWageGroup             on  $projection.EmployeeWageGroup = _EmployeeWageGroup.EmployeeWageGroup
                                                                                         and $projection.Plant             = _EmployeeWageGroup.Plant
  /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
  association [0..1] to I_EmployeeSuitability          as _EmployeeSuitability           on  $projection.EmployeeSuitability = _EmployeeSuitability.EmployeeSuitability
                                                                                         and $projection.Plant               = _EmployeeSuitability.Plant
  /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
  association [0..1] to I_OperationSetupType           as _OperationSetupType            on  $projection.OperationSetupType = _OperationSetupType.OperationSetupType
                                                                                         and $projection.Plant              = _OperationSetupType.Plant

  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter1 on  $projection.standardworkformulaparam1 = _StandardWorkFormulaParameter1.StandardWorkFormulaParameter
  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter2 on  $projection.standardworkformulaparam2 = _StandardWorkFormulaParameter2.StandardWorkFormulaParameter
  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter3 on  $projection.standardworkformulaparam3 = _StandardWorkFormulaParameter3.StandardWorkFormulaParameter
  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter4 on  $projection.standardworkformulaparam4 = _StandardWorkFormulaParameter4.StandardWorkFormulaParameter
  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter5 on  $projection.standardworkformulaparam5 = _StandardWorkFormulaParameter5.StandardWorkFormulaParameter
  association [0..1] to I_StandardWorkFormulaParameter as _StandardWorkFormulaParameter6 on  $projection.standardworkformulaparam6 = _StandardWorkFormulaParameter6.StandardWorkFormulaParameter

{
  key plas.BillOfOperationsType,
  key plas.BillOfOperationsGroup,
  key plas.BillOfOperationsVariant,
  key plas.BillOfOperationsSequence,
  key plas.BOOOperationInternalID,
  key plas.BOOSqncOpAssgmtIntVersionCntr,
  key plpo.BOOOpInternalVersionCounter,

      plpo.BillOfOperationsVersion, // NOT a key field in THIS view !


      // ***************** Technical fields not on the CEWB-UI *****************


      plpo.WorkCenterInternalID,
      plpo.WorkCenterTypeCode,

      case when plpo.IsDeleted = ' ' then plas.IsDeleted
      else plpo.IsDeleted end
                                            as   IsDeleted,
      case when plpo.IsImplicitlyDeleted = ' ' then plas.IsImplicitlyDeleted
      else plpo.IsImplicitlyDeleted end
                                            as   IsImplicitlyDeleted,

      // ************************** Operation Header ***************************


      plpo.OperationExternalID,
      plpo.Operation,
      plpo.Operation_2,

      plpo.SuperiorOperationInternalID,

      // ************************** Operation General **************************


      -- Operation
      plpo.OperationText,

      plpo.LongTextLanguageCode,

      plpo.Plant,

      @ObjectModel.foreignKey.association: '_OperationControlProfile'
      case plpo._WorkCenter.OpControlProfileIsReferenced
        when 'X' then plpo._WorkCenter.OperationControlProfile
        else plpo.OperationControlProfile end    as   OperationControlProfile,

      @ObjectModel.foreignKey.association: '_OperationStandardText'
      case plpo._WorkCenter.StandardTextIDIsReferenced
        when 'X' then plpo._WorkCenter.StandardTextInternalID
        else plpo.OperationStandardTextCode end  as   OperationStandardTextCode,

      plpo.FactoryCalendar,

      -- Origin
      plpo.BillOfOperationsRefType,
      plpo.BillOfOperationsRefGroup,
      plpo.BillOfOperationsRefVariant,

      -- Production Line
      plpo.LineSegmentTakt,

      -- Transfer to Orders     (-> Suboperations)
      plpo.OperationStdWorkQtyGrpgCat,

      plpo.OrderHasNoSubOperations,

      // ************************** Processing Times ***************************


      -- Standard Values
      plpo.OperationReferenceQuantity,
      plpo.OperationUnit,

      plpo.OpQtyToBaseQtyNmrtr,
      plpo.OpQtyToBaseQtyDnmntr,

      plpo.BillOfOperationsBreakDuration,
      plpo.BillOfOperationsBreakDurnUnit,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam1,
      StandardWorkQuantity1,
      StandardWorkQuantityUnit1,
      CostCtrActivityType1,
      PerfEfficiencyRatioCode1,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam2,
      StandardWorkQuantity2,
      StandardWorkQuantityUnit2,
      CostCtrActivityType2,
      PerfEfficiencyRatioCode2,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam3,
      StandardWorkQuantity3,
      StandardWorkQuantityUnit3,
      CostCtrActivityType3,
      PerfEfficiencyRatioCode3,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam4,
      StandardWorkQuantity4,
      StandardWorkQuantityUnit4,
      CostCtrActivityType4,
      PerfEfficiencyRatioCode4,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam5,
      StandardWorkQuantity5,
      StandardWorkQuantityUnit5,
      CostCtrActivityType5,
      PerfEfficiencyRatioCode5,

      _WorkCenter._StandardWorkFmlaParamGroup.StandardWorkFormulaParam6,
      StandardWorkQuantity6,
      StandardWorkQuantityUnit6,
      CostCtrActivityType6,
      PerfEfficiencyRatioCode6,

      plpo.BusinessProcess,

      // ************************ Interoperation Times *************************


      -- Interoperation Times
      LeadTimeReductionStrategy,

      TeardownAndWaitIsParallel,

      MaximumWaitDuration,
      MaximumWaitDurationUnit,

      MinimumWaitDuration,
      MinimumWaitDurationUnit,

      StandardQueueDuration,
      StandardQueueDurationUnit,

      MinimumQueueDuration,
      MinimumQueueDurationUnit,

      StandardMoveDuration,
      StandardMoveDurationUnit,

      MinimumMoveDuration,
      MinimumMoveDurationUnit,

      // **************************** Control Data *****************************


      --- Splitting
      OperationSplitIsRequired,

      MaximumNumberOfSplits,

      MinProcessingDurationPerSplit,
      MinProcessingDurnPerSplitUnit,

      --- Overlapping
      OperationOverlappingIsRequired,
      OperationOverlappingIsPossible,
      OperationsIsAlwaysOverlapping,

      OverlapMinimumDuration,
      OverlapMinimumDurationUnit,

      OverlapMinimumTransferQty,
      OverlapMinimumTransferQtyUnit,

      // ********************* Additional Operation Data ***********************


      --- General Data
      plpo.OperationScrapPercent,

      case _WorkCenter.NmbrOfTimeTicketsIsReferenced
        when 'X' then _WorkCenter.NumberOfTimeTickets
        else NumberOfTimeTickets end        as   NumberOfTimeTickets,
      case _WorkCenter.NumberOfConfSlipsIsReferenced
        when 'X' then _WorkCenter.NumberOfConfirmationSlips
        else NumberOfConfirmationSlips end  as   NumberOfConfirmationSlips,

      @ObjectModel.foreignKey.association: '_EmployeeWageGroup'
      case _WorkCenter.EmployeeWageGroupIsReferenced
        when 'X' then _WorkCenter.EmployeeWageGroup
        else EmployeeWageGroup end          as   EmployeeWageGroup,
      case _WorkCenter.EmployeeWageTypeIsReferenced
        when 'X' then _WorkCenter.EmployeeWageType
        else EmployeeWageType end           as   EmployeeWageType,

      @ObjectModel.foreignKey.association: '_EmployeeSuitability'
      case _WorkCenter.EmplSuitabilityIsReferenced
        when 'X' then _WorkCenter.EmployeeSuitability
        else EmployeeSuitability end        as   EmployeeSuitability,

      plpo.NumberOfEmployees,

      -- Setup
      @ObjectModel.foreignKey.association: '_OperationSetupType'
      case _WorkCenter.WorkCenterSetpTypeIsReferenced
        when 'X' then _WorkCenter.WorkCenterSetupType
        else OperationSetupType end         as   OperationSetupType,
      OperationSetupGroupCategory,
      OperationSetupGroup,

      OperationCostingRelevancyType,

      IsNonValueAddedOperation, //visible only in CA02


      // ************************ External Processing **************************


      -- External Processing
      plpo.OpIsExtlyProcdWithSubcontrg,

      plpo.PurchasingInfoRecord,

      plpo.PurchasingOrganization,

      plpo.PurchaseContract,
      plpo.PurchaseContractItem,

      plpo.PurchasingInfoRecdAddlGrpgName,

      plpo.MaterialGroup,

      plpo.PurchasingGroup,

      plpo.Supplier,

      plpo.PlannedDeliveryDuration,

      plpo.NumberOfOperationPriceUnits,

      plpo.OpExternalProcessingPrice,

      plpo.InspectionLotType,

      plpo.CostElement,
      
      plpo.CompanyCode,

      plpo.OpExternalProcessingCurrency,

      // ************************* Process Control Data ************************


      plpo.BOOOperationIsPhase,
      plpo.BOOPhaseSuperiorOpInternalID,

      plpo.ControlRecipeDestination,

      // ************************* Qualification Data **************************


      plpo.CapacityCategoryCode,

      // ************************* Quality Management **************************


      -- Quality management: general
      plpo.InspResultRecordingView,

      -- Quality management: inspection points
      plpo.InspSbstCompletionConfirmation,
      plpo.InspSbstHasNoTimeOrQuantity,

      // ***************************** User Fields *****************************


      FreeDefinedTableFieldSemantic,
      FreeDefinedAttribute01,
      FreeDefinedAttribute02,
      FreeDefinedAttribute03,
      FreeDefinedAttribute04,
      FreeDefinedQuantity1,
      FreeDefinedQuantity1Unit,
      FreeDefinedQuantity2,
      FreeDefinedQuantity2Unit,
      FreeDefinedAmount1,
      FreeDefinedAmount1Currency,
      FreeDefinedAmount2,
      FreeDefinedAmount2Currency,
      FreeDefinedDate1,
      FreeDefinedDate2,
      FreeDefinedIndicator1,
      FreeDefinedIndicator2,

      // *************************** Administration ****************************


      -- Administrative Data
      plpo.CreationDate,
      plpo.CreatedByUser,

      plpo.LastChangeDate,
      plpo.LastChangedByUser,

      -- Validity
      plpo.ChangeNumber,

      cast(case when plpo.ValidityStartDate > plas.ValidityStartDate then plpo.ValidityStartDate
      else plas.ValidityStartDate
      end as pph_begda preserving type)
                                            as   ValidityStartDate,
      cast(case when plpo.ValidityEndDate < plas.ValidityEndDate then plpo.ValidityEndDate
      else plas.ValidityEndDate
      end as pph_endda preserving type)
                                            as   ValidityEndDate,

      // **************************** Associations *****************************


      plas._BillOfOperationsType,
      plas._BillOfOperationsGroup,
      plas._BillOfOperations,
      plas._BillOfOperationsSequence,
      plas._BOOOperationInternalID,

      plpo._BillOfOperationsBreakDurnUnit,
      plpo._CapacityCategory,
      plpo._ChangeMaster,
      plpo._ControlRecipeDestination,
      _EmployeeSuitability,
      _EmployeeWageGroup,
      plpo._FactoryCalendar,
      plpo._FreeDefinedAmount1Currency,
      plpo._FreeDefinedAmount2Currency,
      plpo._FreeDfndTableFieldSemantic,
      plpo._InspResultRecordingView,
      plpo._InspectionLotType,
      plpo._LeadTimeReductionStrategy,
      plpo._LongTextLanguage,
      plpo._MaterialGroup,
      plpo._MaximumWaitDurationUnit,
      plpo._MinProcessingDurnPerSplitUnit,
      plpo._MinimumMoveDurationUnit,
      plpo._MinimumQueueDurationUnit,
      plpo._MinimumWaitDurationUnit,
      plpo._OpExternalProcessingCurrency,
      _OperationControlProfile,
      plpo._OperationSetupGroup,
      plpo._OperationSetupGroupCategory,
      _OperationSetupType,
      _OperationStandardText,
      plpo._OperationStdWorkQtyGrpgCat,
      plpo._OperationUnit,
      plpo._OverlapMinimumDurationUnit,
      plpo._OverlapMinimumTransferQtyUnit,
      plpo._PerformanceEfficiencyRatio1,
      plpo._PerformanceEfficiencyRatio2,
      plpo._PerformanceEfficiencyRatio3,
      plpo._PerformanceEfficiencyRatio4,
      plpo._PerformanceEfficiencyRatio5,
      plpo._PerformanceEfficiencyRatio6,
      plpo._Plant,
      plpo._PurchaseContract,
      plpo._PurchaseContractItem,
      plpo._PurchasingGroup,
      plpo._PurchasingInfoRecord,
      plpo._PurchasingOrganization,
      plpo._StandardMoveDurationUnit,
      plpo._StandardQueueDurationUnit,
      _StandardWorkFormulaParameter1,
      _StandardWorkFormulaParameter2,
      _StandardWorkFormulaParameter3,
      _StandardWorkFormulaParameter4,
      _StandardWorkFormulaParameter5,
      _StandardWorkFormulaParameter6,
      plpo._StandardWorkQuantityUnit1,
      plpo._StandardWorkQuantityUnit2,
      plpo._StandardWorkQuantityUnit3,
      plpo._StandardWorkQuantityUnit4,
      plpo._StandardWorkQuantityUnit5,
      plpo._StandardWorkQuantityUnit6,
      plpo._Supplier,
      plpo._WorkCenter,
      plpo._WorkCenterType
}
where
  plpo.SuperiorOperationInternalID = '00000000';