I_OperationSetupType

@AbapCatalog.sqlViewName: 'IPPOPSETUPTYPE'
@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'OperationSetupType'
@ObjectModel.semanticKey: ['OperationSetupType', 'Plant']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Operation Setup Type'

define view I_OperationSetupType
  as select from t428
  association [1..1] to I_Plant                  as _Plant on  $projection.Plant = _Plant.Plant
  association [0..*] to I_OperationSetupTypeText as _Text  on  $projection.OperationSetupType = _Text.OperationSetupType
                                                           and $projection.Plant              = _Text.Plant
{
      // Key

      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      @ObjectModel.text.association: '_Text'
  key cast(rasch as pph_rasch preserving type) as OperationSetupType,
      @ObjectModel.foreignKey.association: '_Plant'
  key werks                                    as Plant,

      // Associations

      _Plant,
      _Text
};