P_AR_PurchaseVATRateDetail

@AbapCatalog.sqlViewName: 'PARPURCVATRD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #CONSUMPTION
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_AR_PurchaseVATRateDetail
  with parameters
    P_RptgAmountIsInTransCrcy : fiar_use_transaction_currency

  as select from           P_AR_PurVATRateAggregatedAmt2                                         as PurVATRateAggregatedAmt

    inner join             P_AR_JrnlEntryWthOfclDocType( P_AR_Report : 'RPFIGLAR_TAXREPORTING' ) as JournalEntry     on  JournalEntry.CompanyCode        = PurVATRateAggregatedAmt.CompanyCode
                                                                                                                     and JournalEntry.FiscalYear         = PurVATRateAggregatedAmt.FiscalYear
                                                                                                                     and JournalEntry.AccountingDocument = PurVATRateAggregatedAmt.AccountingDocument


    left outer to one join P_AR_NumberOfVATRates                                                 as NumberOfVATRates on  NumberOfVATRates.CompanyCode        = PurVATRateAggregatedAmt.CompanyCode
                                                                                                                     and NumberOfVATRates.FiscalYear         = PurVATRateAggregatedAmt.FiscalYear
                                                                                                                     and NumberOfVATRates.AccountingDocument = PurVATRateAggregatedAmt.AccountingDocument
                                                                                                                     and NumberOfVATRates.TaxType            = 'V'

{
  key JournalEntry.CompanyCode,
  key JournalEntry.FiscalYear,
  key JournalEntry.AccountingDocument,
  key PurVATRateAggregatedAmt.StatryRptCategory,
  key PurVATRateAggregatedAmt.StatryRptgEntity,
  key PurVATRateAggregatedAmt.StatryRptRunID,
  key PurVATRateAggregatedAmt.TaxRate as TaxRate,
      JournalEntry.PostingDate,
      JournalEntry.DocumentDate,
      JournalEntry.ReportingDate,
      JournalEntry.TaxReportingDate,
      JournalEntry.AccountingDocumentType,
      JournalEntry.DocumentReferenceID,
      JournalEntry.AR_PrintCharacter,
      JournalEntry.AR_Branch,
      JournalEntry.AR_OfficialDocumentNumber,
      JournalEntry.AR_OfficialDocumentType,
      JournalEntry.AR_OfficialDocumentClass,
      PurVATRateAggregatedAmt.CompanyCodeCountry,

      @Semantics.currencyCode:true
      JournalEntry.CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      PurVATRateAggregatedAmt.TaxAmountInCoCodeCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      PurVATRateAggregatedAmt.TaxBaseAmountInCoCodeCrcy,

      @Semantics.currencyCode:true
      JournalEntry.TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      PurVATRateAggregatedAmt.TaxAmountInTransCrcy,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      PurVATRateAggregatedAmt.TaxBaseAmountInTransCrcy,

      @Semantics.currencyCode:true
      cast(
        case $parameters.P_RptgAmountIsInTransCrcy
          when 'X'
            then JournalEntry.TransactionCurrency
          else JournalEntry.CompanyCodeCurrency
        end as glo_reporting_currency preserving type
      )                               as ReportingCurrency,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast(
        case $parameters.P_RptgAmountIsInTransCrcy
          when 'X'
            then PurVATRateAggregatedAmt.TaxAmountInTransCrcy
          else PurVATRateAggregatedAmt.TaxAmountInCoCodeCrcy
        end as glo_tax_amount_rptg_crcy preserving type
      )                               as TaxAmountInRptgCrcy,

      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast(
        case $parameters.P_RptgAmountIsInTransCrcy
          when 'X'
            then PurVATRateAggregatedAmt.TaxBaseAmountInTransCrcy
          else PurVATRateAggregatedAmt.TaxBaseAmountInCoCodeCrcy
        end as glo_taxbase_amount_rptg_crcy preserving type
      )                               as TaxBaseAmountInRptgCrcy,

      NumberOfVATRates.NmbrOfVATRates,
      JournalEntry._OneTimeAccountBP
}
// considers the lines with taxes or lines with zero vat but without additional tax lines (<>zero)


where
       ( PurVATRateAggregatedAmt.TaxRate <> '0.00'
    or     ( PurVATRateAggregatedAmt.TaxRate = '0.00'
       and ( NumberOfVATRates.NmbrOfVATRates = 0 or NumberOfVATRates.NmbrOfVATRates is null ) ) )
  and
      ( ( JournalEntry.AR_PrintCharacter <> 'B' and JournalEntry.AR_PrintCharacter <> 'C' )
    or
       JournalEntry.AR_OfficialDocumentType = '033' )