P_AR_JrnlEntryWthOfclDocType

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@VDM.viewType: #CONSUMPTION
@VDM.private: true
define view entity P_AR_JrnlEntryWthOfclDocType
  with parameters
    @EndUserText.label: 'Statutory Report Name'
    P_AR_Report : progname

  as select from           P_AR_JournalEntry             as JournalEntry

    inner join             I_CompanyCode                 as CompanyCode                    on JournalEntry.CompanyCode = CompanyCode.CompanyCode

    left outer to one join I_CountrySpecificDocumentType as CountrySpecificDocumentType    on  CountrySpecificDocumentType.Country                = CompanyCode.Country
                                                                                           and CountrySpecificDocumentType.AccountingDocumentType = JournalEntry.AccountingDocumentType

    left outer to one join I_AR_OfficialDocumentTypeDetn as OfficialDocumentTypeDetn       on  OfficialDocumentTypeDetn.AR_OfficialDocumentClass = CountrySpecificDocumentType.AR_OfficialDocumentClass
                                                                                           and OfficialDocumentTypeDetn.Country                  = CompanyCode.Country
                                                                                           and OfficialDocumentTypeDetn.AR_Report                = $parameters.P_AR_Report
                                                                                           and OfficialDocumentTypeDetn.AR_PrintCharacter        = JournalEntry.AR_PrintCharacter

    left outer to one join I_AR_OfficialDocumentTypeDetn as OfclDocTypeDetnWthBlnkPrntChar on  OfclDocTypeDetnWthBlnkPrntChar.AR_OfficialDocumentClass = CountrySpecificDocumentType.AR_OfficialDocumentClass
                                                                                           and OfclDocTypeDetnWthBlnkPrntChar.Country                  = CompanyCode.Country
                                                                                           and OfclDocTypeDetnWthBlnkPrntChar.AR_Report                = $parameters.P_AR_Report
                                                                                           and OfclDocTypeDetnWthBlnkPrntChar.AR_PrintCharacter        = ''
{
  key JournalEntry.CompanyCode,
  key JournalEntry.FiscalYear,
  key JournalEntry.AccountingDocument,
      JournalEntry.FiscalPeriod,
      JournalEntry.PostingDate,
      JournalEntry.DocumentDate,
      JournalEntry.TaxReportingDate,
      JournalEntry.ReportingDate,
      JournalEntry.AccountingDocumentType,
      JournalEntry.AccountingDocumentCategory,
      JournalEntry.DocumentReferenceID,

      cast(
        case
          when OfficialDocumentTypeDetn.AR_PrintCharacter is not null
            then JournalEntry.AR_Branch
         else ''
        end as fiar_branch preserving type
      ) as AR_Branch,

      cast(
        case
          when OfficialDocumentTypeDetn.AR_PrintCharacter is not null
            then OfficialDocumentTypeDetn.AR_PrintCharacter
         else ''
        end as j_1apchar preserving type
      ) as AR_PrintCharacter,

      cast(
        case
          when OfficialDocumentTypeDetn.AR_PrintCharacter is not null
            then JournalEntry.AR_OfficialDocumentNumber
         else ''
        end as fiar_odn preserving type
      ) as AR_OfficialDocumentNumber,

      cast(
        case
          when OfficialDocumentTypeDetn.AR_PrintCharacter is not null
            then OfficialDocumentTypeDetn.AR_OfficialDocumentType
         else OfclDocTypeDetnWthBlnkPrntChar.AR_OfficialDocumentType
        end as j_1aoftp_d preserving type
      ) as AR_OfficialDocumentType,

      cast(
        case
          when OfficialDocumentTypeDetn.AR_OfficialDocumentClass is not null
            then OfficialDocumentTypeDetn.AR_OfficialDocumentClass
         else OfclDocTypeDetnWthBlnkPrntChar.AR_OfficialDocumentClass
        end as doccls preserving type
      ) as AR_OfficialDocumentClass,


      JournalEntry.ExchangeRateDate,
      JournalEntry.ExchangeRate,
      JournalEntry.CompanyCodeCurrency,
      JournalEntry.TransactionCurrency,
      JournalEntry._OneTimeAccountBP
}