I_StoreProductRFIDCount

@AbapCatalog.sqlViewName: 'IRTSTCPRCOUNT'
@EndUserText.label: 'Store Product RFID Count'

@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #BASIC
@ObjectModel: {
    compositionRoot: true,
    representativeKey: 'StoreProductRFIDCountUUID',
    usageType.serviceQuality: #B,
    usageType.sizeCategory: #M,
    usageType.dataClass: #TRANSACTIONAL
}
define view I_StoreProductRFIDCount
  as select from rtst_cpr_count

  association [0..*] to I_StoreProductRFIDCountProduct as _StoreProductRFIDCountProduct  on  $projection.StoreProductRFIDCountUUID = _StoreProductRFIDCountProduct.StoreProductRFIDCountUUID
  association [0..*] to I_StoreProdRFIDCntProdInstance as _StoreProdRFIDCntProdInstance  on  $projection.StoreProductRFIDCountUUID = _StoreProdRFIDCntProdInstance.StoreProductRFIDCountUUID

  // Previous counts for the same store/storage location

  association [0..*] to I_StoreProductRFIDCount        as _PreviousStoreProductRFIDCount on  _PreviousStoreProductRFIDCount.Store            = $projection.Store
                                                                                         and _PreviousStoreProductRFIDCount.StorageLocation  = $projection.StorageLocation
                                                                                         and _PreviousStoreProductRFIDCount.CreationDateTime < $projection.CreationDateTime

  // Administrative data

  association [0..1] to I_User                         as _CreatedByUser                 on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _SubmittedByUser               on  $projection.SubmittedByUser = _SubmittedByUser.UserID
{
  key storeproductrfidcountuuid      as StoreProductRFIDCountUUID,

      store                          as Store,
      storagelocation                as StorageLocation,
      numberofexpecteditems          as NumberOfExpectedItems,
      numberofsubmitteditems         as NumberOfSubmittedItems,
      numberofsubmittedmissingitems  as NumberOfSubmittedMissingItems,
      numberofsubmittedsurplusitems  as NumberOfSubmittedSurplusItems,
      notpostednrofsubmdmissingitems as NotPostedNrOfSubmdMissingItems,
      notpostednrofsubmdsurplusitems as NotPostedNrOfSubmdSurplusItems,
      skippednrofsubmdmissingitems   as SkippedNrOfSubmdMissingItems,
      skippednrofsubmdsurplusitems   as SkippedNrOfSubmdSurplusItems,
      unprocessedsalesareconsidered  as UnprocessedSalesAreConsidered,
      storeproductrfidcntprocgstatus as StoreProductRFIDCntProcgStatus,
      storeprodrfidcntexprtndtetme   as StoreProdRFIDCntExprtnDteTme,

      @Semantics.systemDate.createdAt: true
      creationdatetime               as CreationDateTime,
      createdbyuser                  as CreatedByUser,
      submissiondatetime             as SubmissionDateTime,
      submittedbyuser                as SubmittedByUser,

      _CreatedByUser,
      _SubmittedByUser,
      _PreviousStoreProductRFIDCount,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _StoreProductRFIDCountProduct,
      _StoreProdRFIDCntProdInstance
}