I_QltyNotificationTaskVH

@AbapCatalog.sqlViewName: 'IQNOTIFTSKVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@VDM.viewType: #COMPOSITE

@EndUserText.label: 'Search for Quality Notification Task'
@ClientHandling.algorithm: #SESSION_VARIABLE


@ObjectModel: {
    representativeKey: 'NotificationTask',
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #A },
    dataCategory: #VALUE_HELP
} 

define view I_QltyNotificationTaskVH
  as select from I_NotificationTask
    inner join   I_QltyNotification on I_NotificationTask.Notification = I_QltyNotification.QualityNotification

{
//=== Key Fields

    key I_NotificationTask.Notification as QualityNotification,
    key I_NotificationTask.NotificationTask,

//        I_NotificationTask.QualityTask,

        case when ( I_NotificationTask.Notification like '$%' ) 
          then substring(I_NotificationTask.Notification,2,11)
          else concat(I_NotificationTask.Notification,I_NotificationTask.NotificationTask) 
        end                                          as QualityTask,
        
//=== Common Fields

        I_NotificationTask.QualityTaskOrigin,
        I_NotificationTask.NotificationTaskText,
        I_NotificationTask.NotifTaskPlannedEndDate,
        I_NotificationTask.NotifTaskPlannedEndTime,
        I_NotificationTask.NotifTaskTimeZone,     
        I_NotificationTask.NotifTaskCompletionDate,
        I_NotificationTask.NotifTaskCompletionTime,
        I_NotificationTask.NotifTaskResubmissionDate,
        I_NotificationTask.NotifTaskResubmissionTime,
        I_NotificationTask.ResponsiblePersonFunctionCode,
        I_NotificationTask.ResponsiblePerson,
        I_NotificationTask.NotificationItem,
        I_NotificationTask.CreationDate,
//=== Notification Fields        

        I_QltyNotification.NotificationType,
        I_QltyNotification.Plant,
        I_QltyNotification.NotificationOrigin,
        I_QltyNotification.Supplier,
        I_QltyNotification.Customer,
        I_QltyNotification.NotificationText,
        I_QltyNotification.CreatedByUser,
        I_QltyNotification.NotificationCompletionDate,
        
        @Consumption.hidden: true 
        I_QltyNotification.IsBusinessPurposeCompleted,
        @Consumption.hidden: true 
        I_NotificationTask._Notification,
        @Consumption.hidden: true 
        I_NotificationTask._QualityTaskOrigin,
        @Consumption.hidden: true 
        I_NotificationTask._PartnerFunction,
        @Consumption.hidden: true 
        I_QltyNotification._Plant,
        @Consumption.hidden: true 
        I_NotificationTask._ContactPerson,
        @Consumption.hidden: true         
        I_NotificationTask._Employee,
        @Consumption.hidden: true         
        I_NotificationTask._Customer,
        @Consumption.hidden: true 
        I_NotificationTask._Supplier
                
} 
where I_NotificationTask.IsDeleted = '' and
      I_QltyNotification.IsDeleted = ''