I_NotificationTask

@AbapCatalog.sqlViewName: 'INOTIFTSK'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUserContactCard', '_LastChangedByUserContactCard', '_StsObjConcatActiveStsILL']

@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@EndUserText.label: 'Notification Task'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
    representativeKey: 'NotificationTask',
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #A }
}
define view I_NotificationTask
  as select from qmsm
  //=== Assocation to notification specific views

  association [0..1] to I_Notification               as _Notification                 on  $projection.Notification = _Notification.Notification
  association [0..*] to I_NotifTaskFllwUpActionParam as _NotifTaskFllwUpActionParam   on  $projection.Notification     = _NotifTaskFllwUpActionParam.Notification
                                                                                      and $projection.NotificationTask = _NotifTaskFllwUpActionParam.NotificationTask

  association [1..1] to I_QltyTaskOrigin             as _QualityTaskOrigin            on  $projection.QualityTaskOrigin = _QualityTaskOrigin.QualityTaskOrigin
  association [0..1] to I_BusinessPartner            as _QualityTaskProcessor         on  $projection.QualityTaskProcessor = _QualityTaskProcessor.BusinessPartner
  association [0..1] to I_PartnerFunction            as _PartnerFunction              on  $projection.ResponsiblePersonFunctionCode = _PartnerFunction.PartnerFunction
  association [0..1] to I_UserContactCard            as _CreatedByUserContactCard     on  $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard            as _LastChangedByUserContactCard on  $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID
  association [0..1] to I_StsObjConcatActiveStsILL   as _StsObjConcatActiveStsILL     on  $projection.StatusObject = _StsObjConcatActiveStsILL.StatusObject
                                                                                   
  /* Associations - DPP */
  association [0..1] to I_ContactPerson              as _ContactPerson                on  _ContactPerson.ContactPerson = $projection.ResponsiblePerson
  association [0..1] to I_Customer                   as _Customer                     on  _Customer.Customer = $projection.ResponsiblePerson
  association [0..1] to I_WorkforcePerson            as _Employee                     on  _Employee.PersonExternalID = $projection.ResponsiblePerson
  association [0..1] to I_Supplier                   as _Supplier                     on  _Supplier.Supplier = $projection.ResponsiblePerson

{
      //=== Key Fields

      @ObjectModel.foreignKey.association: '_Notification'
  key qmsm.qmnum                                             as Notification,
  key qmsm.manum                                             as NotificationTask,

      //=== Common Fields

      @ObjectModel.foreignKey.association: '_QualityTaskOrigin'
      qmsm.taskorigin                                        as QualityTaskOrigin,
      qmsm.tasktype                                          as QualityTaskType,
      @ObjectModel.foreignKey.association: '_QualityTaskProcessor'
      qmsm.processor                                         as QualityTaskProcessor,
      @Semantics.text: true
      qmsm.matxt                                             as NotificationTaskText,
      qmsm.kzloesch                                          as IsDeleted,
      qmsm.pster                                             as NotifTaskPlannedStartDate,
      qmsm.pstur                                             as NotifTaskPlannedStartTime,
      qmsm.peter                                             as NotifTaskPlannedEndDate,
      qmsm.objnr                                             as StatusObject,
      qmsm.petur                                             as NotifTaskPlannedEndTime,
      qmsm.tzonsm                                            as NotifTaskTimeZone,
      qmsm.erlnam                                            as NotifTaskCompletedByUser,
      qmsm.erldat                                            as NotifTaskCompletionDate,
      qmsm.erlzeit                                           as NotifTaskCompletionTime,
      qmsm.wdvdat                                            as NotifTaskResubmissionDate,
      qmsm.wdvzeit                                           as NotifTaskResubmissionTime,
      @ObjectModel.foreignKey.association: '_PartnerFunction'
      cast(qmsm.parvw  as vdm_q_parvw_vera preserving type ) as ResponsiblePersonFunctionCode,
      qmsm.parnr                                             as ResponsiblePerson,
      qmsm.qsmnum                                            as NotificationTaskSortNumber,
      qmsm.fenum                                             as NotificationItem,
      qmsm.urnum                                             as NotificationCauseID,
      qmsm.mnkat                                             as NotificationTaskCatalog,
      qmsm.mngrp                                             as NotificationTaskCodeGroup,
      qmsm.mncod                                             as NotificationTaskCode,
      qmsm.folgeact                                          as QltyTaskFollowUpAction,
      qmsm.statfoa                                           as QltyTaskFllwUpActionSts,
      
      //====Time Recording for Task

      @Semantics.quantity.unitOfMeasure: 'QltyTaskTimeBasedEffortUoM'
      qmsm.timebasedeffort                                   as QltyTaskTimeBasedEffort,
      @Semantics.unitOfMeasure: true
      qmsm.timebasedeffortuom                                as QltyTaskTimeBasedEffortUoM,

      //=== Administrative Data

      case qmsm.changeddatetime
        when 0 then cast( '19000101010101' as tzntstmps )
        else qmsm.changeddatetime                        end as ChangedDateTime,
      @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
      qmsm.ernam                                             as CreatedByUser,
      @Semantics.systemDate.createdAt: true
      qmsm.erdat                                             as CreationDate,
      qmsm.erzeit                                            as CreationTime,
      @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
      qmsm.aenam                                             as LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      qmsm.aedat                                             as LastChangeDate,
      qmsm.aezeit                                            as LastChangeTime,

      //=== Expose Associations

      _Notification,
      _NotifTaskFllwUpActionParam,
      _QualityTaskOrigin,
      _QualityTaskProcessor,
      _CreatedByUserContactCard,
      _LastChangedByUserContactCard,
      _StsObjConcatActiveStsILL,
      _PartnerFunction,
      _ContactPerson,
      _Employee,
      _Supplier,
      _Customer

}