I_ProductionRoutingVersion

@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@EndUserText.label: 'Production Routing Version'

define view entity I_ProductionRoutingVersion
  as select from I_BillOfOperationsVersion     as ProdnRtgVersion

    inner join   I_BillOfOperationsChangeState as BillOfOperationChangeState on  BillOfOperationChangeState.BillOfOperationsType    = ProdnRtgVersion.BillOfOperationsType
                                                                             and BillOfOperationChangeState.BillOfOperationsGroup   = ProdnRtgVersion.BillOfOperationsGroup
                                                                             and BillOfOperationChangeState.BillOfOperationsVariant = ProdnRtgVersion.BillOfOperationsVariant
                                                                             and BillOfOperationChangeState.BillOfOperationsVersion = ProdnRtgVersion.BillOfOperationsVersion

    inner join   I_BillOfOperations            as BillOfOperations           on  BillOfOperations.BillOfOperationsType    = ProdnRtgVersion.BillOfOperationsType
                                                                             and BillOfOperations.BillOfOperationsGroup   = ProdnRtgVersion.BillOfOperationsGroup
                                                                             and BillOfOperations.BillOfOperationsVariant = ProdnRtgVersion.BillOfOperationsVariant

  association [0..1] to I_WorkCenterBySemanticKey  as _WorkCenterBySemanticKey  on  $projection.WorkCenter = _WorkCenterBySemanticKey.WorkCenter
                                                                                and $projection.Plant      = _WorkCenterBySemanticKey.Plant

  association [1..1] to I_Plant                    as _Plant                    on  $projection.Plant = _Plant.Plant

  association [0..1] to I_ProductionRoutingVersion as _ProdnRtgReferenceVersion on  $projection.BillOfOperationsType    = _ProdnRtgReferenceVersion.BillOfOperationsType
                                                                                and $projection.BillOfOperationsGroup   = _ProdnRtgReferenceVersion.BillOfOperationsGroup
                                                                                and $projection.BillOfOperationsVariant = _ProdnRtgReferenceVersion.BillOfOperationsVariant
                                                                                and $projection.BOOReferenceVersion     = _ProdnRtgReferenceVersion.BillOfOperationsVersion
{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key ProdnRtgVersion.BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key ProdnRtgVersion.BillOfOperationsGroup,

      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key ProdnRtgVersion.BillOfOperationsVariant,

      @ObjectModel.text.element: ['BillOfOperationsDesc']
  key ProdnRtgVersion.BillOfOperationsVersion,

      // ***************** Technical fields not on the CEWB-UI *****************

      @ObjectModel.text.element: null
      BillOfOperationChangeState.BOOInternalVersionCounter,

      BillOfOperationChangeState.IsDeleted,

      BillOfOperationChangeState.WorkCenterTypeCode                                                        as   WorkCenterTypeCode,
      BillOfOperationChangeState.WorkCenterInternalID,

      BillOfOperations.BillOfOperationsVersionType,
      BillOfOperations.BillOfOperationsSubtype, //same as BillOfOperationsVersionType, kept for compatibility reasons

      BillOfOperations.BillOfOperationsVariantDesc,      
      BillOfOperations.RoutingIsReworkRouting,
      BillOfOperations.ProdnProcgIsFlexible,
      BillOfOperations.BillOfOperationIsExecutedInMES,
      BillOfOperations.BillOfOperationsIsTrnsfdToERP,
      BillOfOperations.ShopFloorRtgTemplateCategory,
      BillOfOperations.ShopFloorRoutingTemplateType,
      BillOfOperations.ShopFloorRtgTemplateSubType,
      BillOfOperations.ShopFloorRoutingTemplateOwner,      

      // *************************** Header General ****************************


      -- General data
      cast(BillOfOperationChangeState.BillOfOperationsDesc as mpe_rtg_version_description preserving type) as   BillOfOperationsDesc,
      @ObjectModel.foreignKey.association: '_Plant'
      cast(BillOfOperationChangeState.Plant as pwwrk preserving type)                                      as   Plant,

      BillOfOperationChangeState.BillOfOperationsUsage,

      BillOfOperationChangeState.BillOfOperationsStatus,

      BillOfOperationChangeState.ResponsiblePlannerGroup,

      @ObjectModel.foreignKey.association: '_WorkCenterBySemanticKey'
      BillOfOperationChangeState._WorkCenter.WorkCenter                                                    as   WorkCenter,

      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      @DefaultAggregation: #MIN
      BillOfOperationChangeState.MinimumLotSizeQuantity,
      
      @Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
      @DefaultAggregation: #MAX
      BillOfOperationChangeState.MaximumLotSizeQuantity,
      
      cast(BillOfOperationChangeState.BillOfOperationsUnit as mpe_rtg_unit preserving type)                as   BillOfOperationsUnit,

      BillOfOperationChangeState.ReplacedBillOfOperations,

      BillOfOperationChangeState.IsMarkedForDeletion,

      // ************************* Quality Management **************************


      -- Parameter for dynamic modification/inspection points
      BillOfOperationChangeState.InspSubsetFieldCombination,

      BillOfOperationChangeState.InspectionPartialLot,

      BillOfOperationChangeState.SmplDrawingProcedure,
      BillOfOperationChangeState.SmplDrawingProcedureVersion,

      BillOfOperationChangeState.InspectionLotDynamicLevel,

      BillOfOperationChangeState.InspLotDynamicRule,

      BillOfOperationChangeState.MaintenanceStrategy,

      -- Further QM data
      BillOfOperationChangeState.InspExternalNumberingOfValues,

      // *************************** Administration ****************************


      -- Administrative Data
      ProdnRtgVersion.CreationDateTime,
      ProdnRtgVersion.CreatedByUser,

      ProdnRtgVersion.LastChangeDateTime,
      ProdnRtgVersion.LastChangedByUser,

      BillOfOperationChangeState.ChangeNumber,

      -- Validity
      BillOfOperationChangeState.ValidityStartDate,
      BillOfOperationChangeState.ValidityEndDate,

      -- Additional Data
      BillOfOperationChangeState.LastReorganizationDate,
      BillOfOperationChangeState.LastUsageDate,
      BillOfOperationChangeState.NumberOfUsages,

      // ************************* Version (not CEWB) **************************


      ProdnRtgVersion.BillOfOperationsVersionStatus,
      ProdnRtgVersion.IsLatestBOOVersion,
      ProdnRtgVersion.NumberOfBOOVersionSuccessors,
      ProdnRtgVersion.BillOfOperationsRefType,
      ProdnRtgVersion.BillOfOperationsRefGroup,
      ProdnRtgVersion.BillOfOperationsRefVariant,
      @ObjectModel.foreignKey.association: '_ProdnRtgReferenceVersion'
      ProdnRtgVersion.BOOReferenceVersion,
      
      // ************************* Order specific Routing **************************

      ProdnRtgVersion.OrderID,

      // **************************** Associations *****************************


      BillOfOperationChangeState._BillOfOperationsStatus,
      BillOfOperationChangeState._BillOfOperationsUnit,
      BillOfOperationChangeState._BillOfOperationsUsage,
      BillOfOperationChangeState._ChangeMaster,
      BillOfOperationChangeState._InspExtNumbering,
      BillOfOperationChangeState._InspLotDynamicRule,
      BillOfOperationChangeState._InspPartialLotAssignment,
      BillOfOperationChangeState._InspSubsetFieldCombination,
      BillOfOperationChangeState._InspectionLotDynamicLevel,
      BillOfOperationChangeState._MaintenanceStrategy,
      //      BillOfOperationChangeState._Plant

      _ProdnRtgReferenceVersion,
      BillOfOperationChangeState._ResponsiblePlannerGroup,
      BillOfOperationChangeState._SampleDrawingProcedure,
      BillOfOperationChangeState._SmplDrwgProcedureVersion,
      BillOfOperationChangeState._WorkCenter,
      BillOfOperationChangeState._WorkCenterType,
      _Plant,
      ProdnRtgVersion._BOOVersionStatus,
      ProdnRtgVersion._BillOfOperations,
      ProdnRtgVersion._BillOfOperationsGroup,
      ProdnRtgVersion._BillOfOperationsType,
      ProdnRtgVersion._CreatedByUser,
      ProdnRtgVersion._LastChangedByUser,
      _WorkCenterBySemanticKey,
      BillOfOperations._BillOfOperationsVersionType

}