I_PostingKeyWthSpclGLCodeTxt

@AbapCatalog: { sqlViewName: 'IFIPSTNGKEYGLCDT',
                preserveKey: true,
                compiler.compareFilter: true,
                buffering: { status: #ACTIVE,          
                             type: #GENERIC,
                             numberOfKeyFields: 2 } }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics: { dataExtraction.enabled: true }
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Posting Key With Special General Leder Code - Text'
@ObjectModel: { dataCategory: #TEXT,
                representativeKey: 'SpecialGLCode'
,                usageType: { sizeCategory: #S,
                 dataClass:  #CUSTOMIZING,
                 serviceQuality: #A },
                supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE, #SEARCHABLE_ENTITY ],
                modelingPattern: #LANGUAGE_DEPENDENT_TEXT }                  
@Metadata.ignorePropagatedAnnotations: true 
@Search.searchable: true 
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API

define view I_PostingKeyWthSpclGLCodeTxt as select from tbslt inner join tbsl on tbslt.bschl = tbsl.bschl

association [0..1] to I_Language             as _Language             on $projection.Language = _Language.Language
association [0..1] to I_PostingKey           as _PostingKey           on  $projection.PostingKey    = _PostingKey.PostingKey 
association [0..1] to I_SpecialGLCode        as _SpecialGLCode        on $projection.SpecialGLCode = _SpecialGLCode.SpecialGLCode
                                                                      and $projection.FinancialAccountType = _SpecialGLCode.FinancialAccountType
association [0..1] to I_FinancialAccountType as _FinancialAccountType on $projection.FinancialAccountType = _FinancialAccountType.FinancialAccountType

{

@Semantics.language   
key tbslt.spras as Language,
@ObjectModel.foreignKey.association: '_PostingKey'
key cast(tbsl.bschl as fis_bschl preserving type) as PostingKey,
@ObjectModel.foreignKey.association: '_SpecialGLCode'
key cast(tbslt.umskz as fac_umskz preserving type ) as SpecialGLCode,
@ObjectModel.foreignKey.association: '_FinancialAccountType'
cast (tbsl.koart as farp_koart preserving type ) as FinancialAccountType, 
@Semantics.text
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8 
cast (tbslt.ltext as fis_bschl_name preserving type ) as PostingKeyName,

_Language,
_PostingKey,
_SpecialGLCode,
_FinancialAccountType

};