I_PostingKey

@AbapCatalog: { sqlViewName: 'IFIPOSTINGKEY',
                preserveKey: true,
                compiler.compareFilter: true,
                buffering: { status: #ACTIVE,          
                             type: #FULL,
                             numberOfKeyFields: 1 } }
@AccessControl.authorizationCheck: #NOT_REQUIRED   // #CHECK 

@Analytics:{
    dataCategory: #DIMENSION,
    dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
        mapping: 
            [
              { 
                table: 'tbsl',
                role: #MAIN,
                viewElement: ['PostingKey'],
                tableElement: ['bschl']
              }
            ] 
        }
    }
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Posting Key'
@ObjectModel: { representativeKey: 'PostingKey',    
                sapObjectNodeType.name: 'PostingKey', 
                usageType: { sizeCategory: #S, 
                             dataClass:  #CUSTOMIZING,
                             serviceQuality: #A },
                compositionRoot: true,
                supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE, #SEARCHABLE_ENTITY],
                modelingPattern: #ANALYTICAL_DIMENSION }                 
@Metadata.ignorePropagatedAnnotations: true 
@Search.searchable: true 
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API

define view I_PostingKey as select from tbsl 

association [0..*] to I_PostingKeyText as _PostingKeyText on $projection.PostingKey = _PostingKeyText.PostingKey
association [0..*] to I_PostingKeyT as _Text on $projection.PostingKey = _Text.PostingKey 
{
@ObjectModel.text.association: '_PostingKeyText'
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8 
key cast(tbsl.bschl as fis_bschl preserving type) as PostingKey,
cast(tbsl.shkzg as fis_shkzg preserving type ) as DebitCreditCode,
cast(tbsl.koart as farp_koart preserving type ) as FinancialAccountType, 
cast(tbsl.xumsw as farp_xumsw preserving type) as IsSalesRelated,
tbsl.xzahl as IsUsedInPaymentTransaction,
tbsl.stbsl as ReversalPostingKey,
tbsl.xsonu as IsSpecialGLTransaction,

@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_PostingKeyText,

@API.element.releaseState: #DEPRECATED
@API.element.successor:    '_PostingKeyText'
@VDM.lifecycle.status:     #DEPRECATED
@VDM.lifecycle.successor:  '_PostingKeyText'
_Text

};