I_PPM_BPForObjectDirect

@AbapCatalog.sqlViewName: 'IPPMBP4OBJDRCT'
@AbapCatalog.compiler.compareFilter: true

@EndUserText.label: 'Directly Assigned Project Managers'

@VDM.viewType: #BASIC

@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck:    #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.representativeKey: 'BusinessPartnerUUID'
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API

define view I_PPM_BPForObjectDirect as select from dpr_entity_link as elink
    inner join      dpr_bupa_link   as blink    on blink.participant_guid = elink.participant_guid
    inner join      cgpl_hierarchy  as cgplhier on cgplhier.guid = elink.participant_guid
    association [0..1]  to I_BusinessUserBasic      as _BusinessUser
                    on ( $projection.BusinessPartnerUUID    = _BusinessUser.BusinessPartnerUUID )
    association [0..*]  to I_PPM_Text               as _ProjectRoleName
                    on ( $projection.ProjectRoleUUID        = _ProjectRoleName.ReferencedObjectUUID ) 
{
  key elink.entity_guid            as ReferencedObjectUUID,
  key blink.bupa_guid              as BusinessPartnerUUID,
 cast(cgplhier.up                  as /s4ppm/tv_entity_guid preserving type ) as ProjectRoleUUID,
      elink.responsible            as IsBusinessPartnerResponsible,
      
      cast(blink.beg_tmstmp as /s4ppm/tv_constraint_time preserving type) as StaffingPeriodStartDateTime,
      cast(blink.planstart  as /s4ppm/tv_planstart       preserving type) as PlannedStartDateTime,
      cast(elink.end_tmstmp as /s4ppm/tv_constraint_time preserving type) as StaffingPeriodFinishDateTime,
      cast(blink.planfinish as /s4ppm/tv_planfinish      preserving type) as PlannedEndDateTime,
      
      _BusinessUser,
      _ProjectRoleName
}