I_OperationActivityInstance

@AbapCatalog.sqlViewName: 'IMPEOAINST'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@ObjectModel.representativeKey: 'OpActyNtwkElement'
@VDM.viewType: #BASIC
@EndUserText.label: 'Operation Activity Instance'
@AbapCatalog.preserveKey:true
define view I_OperationActivityInstance
  as select from mpe_oa_instance as oa
  association [0..1] to I_OpActyInstanceStatusBasic as _OpActyInstanceStatusBasic on  $projection.OpActyNtwkInstance = _OpActyInstanceStatusBasic.OpActyNtwkInstance
                                                                                  and $projection.OpActyNtwkElement  = _OpActyInstanceStatusBasic.OpActyNtwkElement
  association [0..1] to I_UnitOfMeasure             as _UnitOfMeasure             on  $projection.ProductionUnit = _UnitOfMeasure.UnitOfMeasure
  association [1..1] to I_OpActyNtwkInstance        as _OpActyNtwkInstance        on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [1..1] to I_OpActyNtwkInstanceBasic   as _OpActyNtwkInstanceBasic   on  $projection.OpActyNtwkInstance = _OpActyNtwkInstanceBasic.OpActyNtwkInstance

  association [1..1] to I_SASSchema                 as _SASSchema                 on  $projection.StatusAndActionSchema = _SASSchema.StatusAndActionSchema
{
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_OpActyNtwkInstanceStdVH', element: 'OpActyNtwkInstance' } } ]
  key oa.oan_instance_id    as OpActyNtwkInstance,
  key oa.oan_element_number as OpActyNtwkElement,
      @ObjectModel.foreignKey.association: '_SASSchema'
      oa.sas_name           as StatusAndActionSchema,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      oa.expd_yield         as OpPlannedYieldQuantity,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      oa.expd_scrap         as OpPlannedScrapQuantity,
      @Semantics.unitOfMeasure: true
      oa.uom                as ProductionUnit,
      @Semantics.durationInSeconds: true
      expd_exec_durn        as OpActyExpdExecDurnInSeconds,
      @Semantics.durationInSeconds: true
      expd_exec_labor_time  as OpActyExpdExecLaborDurnInSecs,
      plnty                 as BillOfOperationsType,
      plnnr                 as BillOfOperationsGroup,
      plnal                 as BillOfOperationsVariant,
      plnkn                 as BOOOperationInternalID,
      versn                 as BillOfOperationsVersion,


      _OpActyInstanceStatusBasic,
      _UnitOfMeasure,
      _OpActyNtwkInstance,
      _OpActyNtwkInstanceBasic,
      _SASSchema
}