I_MasterProject

@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IMASTERPROJECT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@ObjectModel.representativeKey: 'MasterProject'
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #MIXED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Master Project'
@Metadata.allowExtensions:true
@AbapCatalog.preserveKey:true
define view I_MasterProject
  as select from /cpd/d_mp_hdr   as MPList
  inner join   /cpd/d_mp_hdr_s as MasterProjectText on MPList.db_key = MasterProjectText.parent_key
  association [0..1] to I_MasterProjectType        as _MasterProjectType         on  $projection.MasterProjectType = _MasterProjectType.MasterProjectType
  association [0..1] to I_EngagementProjectStage   as _MasterProjectStage        on  $projection.MasterProjectStage = _MasterProjectStage.EngagementProjectStage
  association [0..1] to I_Customer                 as _Customer                  on  $projection.Customer = _Customer.Customer
  association [0..1] to I_BusinessPartner          as _ProjectManager            on  $projection.ProjectManager = _ProjectManager.BusinessPartner
  association [0..1] to I_EngagementProjectSrvcOrg as _MasterProjectOrganization on  $projection.MasterProjectOrganization = _MasterProjectOrganization.EngagementProjectServiceOrg
  association [0..1] to I_Country                  as _Country                   on  $projection.Country = _Country.Country
  association [0..1] to I_Region                   as _Region                    on  $projection.Country = _Region.Country
                                                                                 and $projection.Region  = _Region.Region
  association [0..1] to I_CpdIndustry              as _Industry                  on  $projection.Industry = _Industry.Industry
  association [0..1] to I_Cpdprojectrisk           as _ProjectRisk               on  $projection.ProjectRisk = _ProjectRisk.ProjectRisk
  association [0..1] to I_Cpdfinancialrisk         as _FinancialRisk             on  $projection.FinancialRisk = _FinancialRisk.FinancialRisk
  association [0..1] to I_Cpdtechnicalrisk         as _TechnicalRisk             on  $projection.TechnicalRisk = _TechnicalRisk.TechnicalRisk
  association [0..1] to I_Cpdprojectrisk           as _OverallRisk               on  $projection.OverallRisk = _OverallRisk.ProjectRisk
  association [1..*] to I_MPContactPerson          as _ContactPerson             on  $projection.MasterProjectUUID = _ContactPerson.MasterProjectUUID
  association [0..1] to I_MasterProjectVH          as _MasterProject             on  $projection.MasterProject = _MasterProject.MasterProject
  association [0..1] to I_Cpdworktype              as _WorkType                  on  $projection.WorkType = _WorkType.WorkType 
//  association [0..1] to I_EmployeeWorkplaceAddress as _Employee                  on  $projection.ProjectManager = _Employee.EmployeeInternalID        //HRDecoupling

  association [0..1] to I_WorkforcePerson as _Employee                  on  $projection.ProjectManager = _Employee.Person                               //HRDecoupling

  association [1..1] to E_MasterProject            as _Extension                 on  $projection.MasterProjectUUID = _Extension.MasterProjectUUID
  association [0..1] to E_MasterProjectKPI         as _ExtensionKPI              on  $projection.MasterProject = _ExtensionKPI.MasterProject
{
      @ObjectModel.text.element: 'MasterProjectName' 
      key cast(MPList.mp_id  as /cpd/cpm_comlprojid)                                                                                  as  MasterProject,
      MPList.db_key                                                                                                                   as  MasterProjectUUID,
      @Semantics.text: true
      cast(MasterProjectText.text as /cpd/cpm_comlprojname)                                                                           as  MasterProjectName,
      @ObjectModel: {foreignKey.association: '_MasterProjectType'}
      cast(MPList.mp_type as /cpd/cpm_mp_type)                                                                                        as  MasterProjectType,
      @ObjectModel: {foreignKey.association: '_MasterProjectStage'}
      cast(MPList.mp_stage as /cpd/cpm_mp_stage)                                                                                      as  MasterProjectStage,

      MPList.start_date                                                                                                               as  StartDate,

      MPList.end_date                                                                                                                 as  EndDate,
      MPList.active                                                                                                                   as  StatusIsActive,
      @ObjectModel: {foreignKey.association: '_Customer'}
      MPList.customer                                                                                                                 as  Customer,
      @ObjectModel: {foreignKey.association: '_MasterProjectOrganization'}
      cast(MPList.org_id as /cpd/cpm_comlprojorg)                                                                                     as  MasterProjectOrganization,

      cast(MPList.confidential as /cpd/cpm_comlprojcofl )                                                                             as  MasterProjectIsConfidential,
      @ObjectModel: {foreignKey.association: '_Country'}
      cast(MPList.country as /cpd/cpm_country)                                                                                        as  Country,
      @ObjectModel: {foreignKey.association: '_Region'}
      MPList.region                                                                                                                   as  Region,
      @ObjectModel: {foreignKey.association: '_WorkType'}
      MPList.work_type                                                                                                                as  WorkType,
      @ObjectModel: {foreignKey.association: '_Industry'}
      MPList.industry                                                                                                                 as  Industry,
      @ObjectModel: {foreignKey.association: '_ProjectRisk'}
      cast(MPList.proj_risk as /cpd/cpm_projrisk)                                                                                     as  ProjectRisk,
      @ObjectModel: {foreignKey.association: '_FinancialRisk'}
      MPList.fin_risk                                                                                                                 as  FinancialRisk,
      @ObjectModel: {foreignKey.association: '_TechnicalRisk'}
      MPList.tech_risk                                                                                                                as  TechnicalRisk,
      @ObjectModel: {foreignKey.association: '_OverallRisk'}
      cast(MPList.overall_risk as /cpd/cpm_overalprojrisk)                                                                            as  OverallRisk,
      MPList.int_inspect_date                                                                                                         as  InspectionDate,
      cast(MPList.int_inspect_date as /cpd/cpm_intinsdate)                                                                            as  InternalInspectionDate,
      cast(MPList.ext_inspect_date as /cpd/cpm_extinsdate)                                                                            as  ExternalInspectionDate,
      MPList.created_by                                                                                                               as  CreatedByUser,
      // MPList.created_by                                                                                                               as  CreatedBy,

      cast(MPList.created_on as /cpd/cpm_createdon)                                                                                   as   CreationDateTime,
      cast(MPList.changed_on as /cpd/cpm_changedon)                                                                                   as  ProjectLastChangedDateTime,


      MPList.changed_by                                                                                                               as  ChangedBy,
      @ObjectModel: {foreignKey.association: '_ProjectManager'}
      MPList.proj_mgr_bupa_id                                                                                                         as  ProjectManager,
      
      bintohex(MPList.db_key)                                                                                                         as  ProjectUUID,
      
      MPList.proj_currency                                                                                                            as  Currency,
      MPList.cut_off_date                                                                                                             as  MstrProjCutOffDate,
      _MasterProjectType,
      _MasterProjectStage,
      _Customer,
      _ProjectManager,
      _MasterProjectOrganization,
      _Country,
      _Region,
      _Industry,
      _ProjectRisk,
      _FinancialRisk,
      _TechnicalRisk,
      _OverallRisk,
      _ContactPerson,
      _MasterProject,
      _WorkType,
      _Employee
      //_MPDetails

}