I_EngagementProjectSrvcOrg

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IEPSRVCORG'
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'EngagementProjectServiceOrg'
@ObjectModel.sapObjectNodeType.name: 'EngagementProjectServiceOrg'
@EndUserText.label: 'Service Org of Engagement Project'
@AccessControl.authorizationCheck:#CHECK
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@AbapCatalog.buffering.status: #ACTIVE
@AbapCatalog.buffering.numberOfKeyFields: 000
@AbapCatalog.buffering.type: #FULL
@Metadata.allowExtensions:true
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel: {modelingPattern: #ANALYTICAL_DIMENSION, 
               supportedCapabilities: [#ANALYTICAL_DIMENSION,
                                       #CDS_MODELING_ASSOCIATION_TARGET,
                                       #CDS_MODELING_DATA_SOURCE,
                                       #SQL_DATA_SOURCE]
}
define view I_EngagementProjectSrvcOrg
  as select from /cpd/pwsc_orgid
  left outer join /cpd/pwsc_org_at on /cpd/pwsc_orgid.org_unit_id = /cpd/pwsc_org_at.org_unit_id
  association [0..*] to I_EngagementProjectSrvcOrgText as _Text                         on  $projection.EngagementProjectServiceOrg = _Text.EngagementProjectServiceOrg
  association [0..*] to I_EngagementProjectSrvcOrgDets as _EngagementProjectSrvcOrgDets on  $projection.EngagementProjectServiceOrg = _EngagementProjectSrvcOrgDets.EngagementProjectServiceOrg
  association [0..1] to I_EngagementProjectSrvcOrgDets as _CompanyCode                  on  $projection.EngagementProjectServiceOrg    = _CompanyCode.EngagementProjectServiceOrg
                                                                                        and _CompanyCode.AssignedOrganisationIsDefault = 'X'
                                                                                        and _CompanyCode.AssignedOrganisationType      = 'CC'
  association [0..1] to I_EngagementProjectSrvcOrgDets as _ControllingArea              on  $projection.EngagementProjectServiceOrg        = _ControllingArea.EngagementProjectServiceOrg
                                                                                        and _ControllingArea.AssignedOrganisationIsDefault = 'X'
                                                                                        and _ControllingArea.AssignedOrganisationType      = 'CA'
  association [0..1] to I_EngmntProjServiceOrgDetails  as _CompanyCodeAuth              on  $projection.EngagementProjectServiceOrg = _CompanyCodeAuth.EngagementProjectServiceOrg                                                                        
                                                 
{
      @ObjectModel.text.association: '_Text'
  key /cpd/pwsc_orgid.org_unit_id                   as EngagementProjectServiceOrg,
      @Semantics.booleanIndicator:true
      /cpd/pwsc_orgid.sales_org                     as EngmtProjServiceOrgIsSales,
      @Semantics.booleanIndicator:true
      /cpd/pwsc_orgid.delivery_org                  as EngmtProjServiceOrgIsDelivery,
      
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'RestrictedTimePosting'
      /cpd/pwsc_org_at.restrict_time_posting        as TimePostingIsRestricted,
      
      /cpd/pwsc_org_at.restrict_time_posting        as RestrictedTimePosting,
      
      _Text,
      _EngagementProjectSrvcOrgDets,
      _CompanyCode,
      _ControllingArea,
       @Consumption.hidden: true
      _CompanyCodeAuth
}