I_ManufacturingObjectLog

@AbapCatalog.sqlViewName: 'IMPEOBJLOG'
@AbapCatalog.compiler.compareFilter:true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_MfgExecDocumentNote']
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #BASIC
@EndUserText.label: 'Log of Manufacturing Objects'
define view I_ManufacturingObjectLog
  as select from mpe_object_log as log
  association [0..1] to I_MfgActionReasonCode         as _MfgActionReasonCode       on  $projection.MfgActionReasonCodeGroupCtlg  = _MfgActionReasonCode.MfgActionReasonCodeGroupCtlg
                                                                                    and $projection.MfgActionReasonCodeGroup      = _MfgActionReasonCode.MfgActionReasonCodeGroup
                                                                                    and $projection.ManufacturingActionReasonCode = _MfgActionReasonCode.ManufacturingActionReasonCode
                                                                                    and _MfgActionReasonCode.Version              = '000001'
  association [0..1] to I_OrdInternalBillOfOperations as _OrderInternalID           on  $projection.OrderInternalID = _OrderInternalID.OrderInternalBillOfOperations
  association [0..1] to I_MfgOrder                    as _MfgOrder                  on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
  association [0..1] to I_MfgOrder                    as _ChildOrder                on  $projection.MfgOrderSplitChildOrder = _ChildOrder.ManufacturingOrder
  association [0..1] to I_ShopFloorItem               as _ShopFloorItem             on  $projection.ShopFloorItem = _ShopFloorItem.ShopFloorItem
  association [0..1] to I_Material                    as _Material                  on  $projection.Material = _Material.Material
  association [1..1] to I_MfgObjectLogEventType       as _MfgObjectLogEventType     on  $projection.MfgObjectLogEventType = _MfgObjectLogEventType.MfgObjectLogEventType
  association [0..1] to I_UnitOfMeasure               as _ProductionUnit            on  $projection.ProductionUnit = _ProductionUnit.UnitOfMeasure
  association [0..1] to I_OpActyNtwkInstance          as _OpActyNtwkInstance        on  $projection.OpActyNtwkInstance = _OpActyNtwkInstance.OpActyNtwkInstance
  association [0..1] to I_OperationActivityInstance   as _OperationActivityInstance on  $projection.OpActyNtwkInstance = _OperationActivityInstance.OpActyNtwkInstance
                                                                                    and $projection.OpActyNtwkElement  = _OperationActivityInstance.OpActyNtwkElement
  association [0..1] to I_MfgExecDocumentNote         as _MfgExecDocumentNote       on  _MfgExecDocumentNote.MfgExecDocumentCategory  = 9
                                                                                    and $projection.ManufacturingObjectLog            = _MfgExecDocumentNote.ManufacturingExecutionDocument
                                                                                    and _MfgExecDocumentNote.MfgExecutionDocumentItem = 0
  association [0..1] to I_Material                    as _MaterialComponent         on  $projection.MaterialComponent = _MaterialComponent.Material
  association [0..1] to I_Material                    as _SubstitutedProduct        on  $projection.SubstitutedProduct = _SubstitutedProduct.Material
{
  key log.log_id               as ManufacturingObjectLog,
      log.object               as MfgObjectLogObjectType,
      @ObjectModel.foreignKey.association: '_MfgObjectLogEventType'
      log.event                as MfgObjectLogEventType,
      @ObjectModel.foreignKey.association: '_MfgOrder'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
      log.aufnr                as ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_ShopFloorItem'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ShopFloorItemStdVH', element: 'ShopFloorItem' } } ]
      log.sfi_id               as ShopFloorItem,
      @Semantics.systemDateTime.createdAt: true
      log.event_time           as CreationDateTime,
      @Semantics.user.createdBy: true
      log.event_user           as CreatedByUser,
      log.code                 as ManufacturingActionReasonCode,
      log.katalogart           as MfgActionReasonCodeGroupCtlg,
      log.codegruppe           as MfgActionReasonCodeGroup,
      @ObjectModel.foreignKey.association: '_Material'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      log.matnr                as Material,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      log.total_qty            as MfgObjectLogObjectQuantity,
      @Semantics.unitOfMeasure: true
      log.unit                 as ProductionUnit,
      @ObjectModel.foreignKey.association: '_OrderInternalID'
      log.aufpl                as OrderInternalID,
      log.aplzl                as OrderOperationInternalID,
      @ObjectModel.foreignKey.association: '_ChildOrder'
      log.child_aufnr          as MfgOrderSplitChildOrder,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      log.split_qty            as MfgOrderSplitQuantity,
      log.msg_nmbr             as SystemMessageNumber,
      log.msg_id               as SystemMessageIdentification,
      log.msg_varbl1           as MfgExecHistMsgVarblField1,
      log.msg_varbl2           as MfgExecHistMsgVarblField2,
      log.msg_varbl3           as MfgExecHistMsgVarblField3,
      log.msg_varbl4           as MfgExecHistMsgVarblField4,
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
      log.oan_instance_id      as OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
      log.oan_element_number   as OpActyNtwkElement,
      log.filename             as MfgProcgExecAttachmentName,
      log.explosion_date       as BOMExplosionDate,
      @ObjectModel.foreignKey.association: '_MaterialComponent'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      log.component_matnr      as MaterialComponent,
      @ObjectModel.foreignKey.association: '_SubstitutedProduct'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      log.exchanged_comp_matnr as SubstitutedProduct,
      log.alpgr                as AlternativeItemGroup,

      _MfgActionReasonCode,
      _OrderInternalID,
      _MfgOrder,
      _ChildOrder,
      _ShopFloorItem,
      _Material,
      _MfgObjectLogEventType,
      _ProductionUnit,
      _OpActyNtwkInstance,
      _OperationActivityInstance,
      _MfgExecDocumentNote,
      _MaterialComponent,
      _SubstitutedProduct
}