I_MAIFDynamicFormObjectKeyVH

@AccessControl.authorizationCheck: #MANDATORY

@EndUserText.label: 'Mobile App Dynamic Form Object Keys'

@Analytics.technicalName: 'IMAIFDYNAMICFORMOBJECTKEYVH'
@Consumption.ranked: true
@Search.searchable: true
@ObjectModel: {
  dataCategory: #VALUE_HELP,
  representativeKey: 'MAIFDynamicFormObjectKey',
  usageType: {
    dataClass: #MIXED,
    serviceQuality: #D,
    sizeCategory: #XL
  }
}

@Metadata.ignorePropagatedAnnotations: true

@VDM.viewType: #COMPOSITE

define view entity I_MAIFDynamicFormObjectKeyVH
  as select from I_EquipmentStdVH as Equipment
    inner join I_EquipmentTimeSeg as CurrentTimeSegment on Equipment.Equipment = CurrentTimeSegment.Equipment
                                                        and CurrentTimeSegment.EquipUsagePeriodSequenceNumber = '001'
                                                        and CurrentTimeSegment.ValidityEndDate                = '99991231'
{
  @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
  @UI.textArrangement: #TEXT_ONLY
  @EndUserText: { label: 'Object Key', quickInfo: 'Object Key' }
  key cast( Equipment.Equipment as /smfnd/sdf_bo_object_key_dte ) as MAIFDynamicFormObjectKey,

  @Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
  @EndUserText: { label: 'Description', quickInfo: 'Description' }
  Equipment.EquipmentName                                        as MAIFDynFormObjectDescription,

  @UI.hidden: true
  cast( 'EQUIPMENT' as /smfnd/sdf_bo_object_type_dte )            as MAIFDynamicFormObjectType
}

union all

 select from I_FunctionalLocationLabelStdVH as FunctionalLocation
{
  key cast( FunctionalLocation.FunctionalLocationLabelName as /smfnd/sdf_bo_object_key_dte ) as MAIFDynamicFormObjectKey,

  FunctionalLocation.FunctionalLocationName                                                  as MAIFDynFormObjectDescription,

  cast( 'FUNCLOC' as /smfnd/sdf_bo_object_type_dte )                                         as MAIFDynamicFormObjectType
}

union all

  select from I_MaintenanceNotification as Notification
{
  key cast( Notification.MaintenanceNotification as /smfnd/sdf_bo_object_key_dte ) as MAIFDynamicFormObjectKey,

  Notification.NotificationText                                                    as MAIFDynFormObjectDescription,

  cast( 'NOTIFICATION' as /smfnd/sdf_bo_object_type_dte )                          as MAIFDynamicFormObjectType
}
  where IsDeleted = ''

union all

  select from I_ServiceOrderStdVH as ServiceOrder
{
  key cast( ServiceOrder.ServiceDocument  as /smfnd/sdf_bo_object_key_dte ) as MAIFDynamicFormObjectKey,

  ServiceOrder.ServiceDocumentDescription                                   as MAIFDynFormObjectDescription,

  cast( 'S4_SRV_ORDER' as /smfnd/sdf_bo_object_type_dte )                   as MAIFDynamicFormObjectType
}

union all

  select from I_Order as OrderMaster
{
  key cast( OrderMaster.OrderID as /smfnd/sdf_bo_object_key_dte ) as MAIFDynamicFormObjectKey,

  OrderMaster.OrderDescription                                    as MAIFDynFormObjectDescription,

  cast( 'WORK_ORDER' as /smfnd/sdf_bo_object_type_dte )           as MAIFDynamicFormObjectType
}
where OrderInternalID is not null