I_SERVICEORDERSTDVH

CDS View

Service Order Value Help

I_SERVICEORDERSTDVH is a CDS View in S/4HANA. Service Order Value Help. It contains 1 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 1 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_BusSolnPrtfloSrvcOrderVH view from CONSUMPTION Value Help: Service Order
I_MAIFDynamicFormObjectKeyVH view_entity union_all COMPOSITE Mobile App Dynamic Form Object Keys

Fields (1)

KeyField CDS FieldsUsed in Views
ServiceDocumentDescription MAIFDynFormObjectDescription 1 
@AbapCatalog.sqlViewName: 'ISERVORDVH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'ServiceDocument'
@VDM.viewType: #BASIC
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #XL, dataClass: #TRANSACTIONAL }
@ObjectModel.supportedCapabilities: [#VALUE_HELP_PROVIDER]
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'Service Order Value Help'

@Search: {
  searchable: true
}
@Consumption.ranked:true

define view I_ServiceOrderStdVH
  as select from I_ServiceDocument
{

      @Search: { ranking: #LOW,
      defaultSearchElement: true }
      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
  key ServiceDocumentType,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key ServiceDocument,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      @Consumption.hidden: true
      ServiceObjectType,
      @Search: { defaultSearchElement: true, ranking: #LOW }
      ServiceDocumentDescription,

      //     @ObjectModel.foreignKey.association: '_RespEmployee'

      //     ResponsibleEmployee,

      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SoldToParty'
      SoldToParty,
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      SalesOrganizationOrgUnitID,
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      SalesOfficeOrgUnitID,
      @Search.ranking: #LOW
      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      SalesGroupOrgUnitID,
      @Search.ranking: #LOW
      ServiceOrganization,
      @Search.ranking: #LOW
      ResponsibleEmployee as RespEmployeeBusinessPartnerId,
      _ServiceDocumentType,
      _ServiceObjType,
      //     _RespEmployee,

      _SoldToParty,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesOrganizationOrgUnit_2'
      _SalesOrganizationOrgUnit,
      _SalesOrganizationOrgUnit_2,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesOfficeOrgUnit_2'
      _SalesOfficeOrgUnit,
      _SalesOfficeOrgUnit_2,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_SalesGroupOrgUnit_2'
      _SalesGroupOrgUnit,
      _SalesGroupOrgUnit_2,
      _SalesOrganization,
      _SalesOffice,
      _SalesGroup,
      _DistributionChannel,
      _Division
}

where
      ServiceObjectType           = 'BUS2000116'

  and ServiceDocumentIsQuotation  = ' '
  and ServiceDocumentTemplateType = ' '

Learn More