I_InternalOrderSystemStatus

@EndUserText.label: 'Internal Order System Status'
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@Analytics.internalName:#LOCAL
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFIINDORDSYSSTS'
@AbapCatalog.preserveKey:true 
@AbapCatalog.compiler.compareFilter:true 
@AccessControl.authorizationCheck: #CHECK //Inserted by VDM CDS Suite Plugin

@ObjectModel.representativeKey: 'ControllingObjectStatus'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Metadata.allowExtensions:true

define view I_InternalOrderSystemStatus
  as select from(
           jest
      join aufk on jest.objnr = aufk.objnr
  )
  association [0..*] to I_InternalOrderSystemStatusT as _Text              on $projection.ControllingObjectStatus = _Text.SystemStatus
  association [0..1] to I_ControllingObject          as _ControllingObject on $projection.ControllingObject = _ControllingObject.ControllingObject
{
      @ObjectModel.foreignKey.association: '_ControllingObject'
  key jest.objnr as ControllingObject,
      @ObjectModel.text.association: '_Text'
  key jest.stat  as ControllingObjectStatus,
      jest.inact as StatusIsInactive,
      jest.chgnr as StatusObjectStatusChangeNumber,
      aufk.kokrs as ControllingArea,
      
      _Text,
      _ControllingObject
}
where
  (
       jest.stat  = 'I0001' //Status: Created

    or jest.stat  = 'I0002' //Status: Released

    or jest.stat  = 'I0045' //Status: Technically completed

    or jest.stat  = 'I0046'
  ) //Status: Closed

  //   or jest.stat = 'I0076' )     //Status: Deletion Flag

  and  jest.inact = ' '
  and  ( aufk.autyp = '01' or aufk.autyp = '02' )