I_InsurancePolicyCoverage

@EndUserText.label: 'Coverage of Cvrg Package in Insur Plcy'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
                    privilegedAssociations:  [  '_InsurPlcyCvrgSurchrgDiscount',
                                                '_InsurancePolicyCvrgLimit',
                                                '_InsurancePolicyCvrgClause',
                                                '_InsurPolicyCvrgDeductible',
                                                '_InsurancePolicyInsuredObject',
                                                '_InsurPlcySubCoverage',
                                                '_InsurPlcyCvrgTypeRegionalCl',
                                                '_InsurPlcyCvrgPremComparison',
                                                '_InsurCvrgPlndProcessing']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyCoverageID',
   semanticKey: [ 'InsurPlcyInsuranceCoverage' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IPPlcyCvrg'
}

define view entity I_InsurancePolicyCoverage
  as select from I_InsurPlcyCoverageBasic as Coverage

  // Join to Regular Premium on Coveragelevel

    inner join   R_InsurancePolicyPremium as RegularPremium        on  RegularPremium.InsurPlcyUUID              = Coverage.InsurPlcyUUID
                                                                   and RegularPremium.InsurPlcyInsurContr        = Coverage.InsurPlcyInsurContr
                                                                   and RegularPremium.InsurPlcyCoveragePackageID = Coverage.InsurPlcyCoveragePackageID
                                                                   and RegularPremium.InsurPlcyCoverageID        = Coverage.InsurPlcyCoverageID

  // Get Template of Contract

    inner join   I_InsuranceContract      as InsuranceContractTmpl on  Coverage.InsurPlcyUUID       = InsuranceContractTmpl.InsurPlcyUUID
                                                                   and Coverage.InsurPlcyInsurContr = InsuranceContractTmpl.InsurPlcyInsurContr

  // Filter Premium Objects

    inner join   I_InsurPlcyRegPremConfig as PremiumConfig         on  PremiumConfig.InsurPlcyProductTemplate = InsuranceContractTmpl.InsurPlcyProductTemplate
                                                                   and PremiumConfig.InsurPremType            = RegularPremium.InsurPremType

  association        to parent I_InsurPlcyCoveragePackage as _InsurPlcyCoveragePackage  on  $projection.InsurPlcyUUID              = _InsurPlcyCoveragePackage.InsurPlcyUUID
                                                                                        and $projection.InsurPlcyInsurContr        = _InsurPlcyCoveragePackage.InsurPlcyInsurContr
                                                                                        and $projection.InsurPlcyCoveragePackageID = _InsurPlcyCoveragePackage.InsurPlcyCoveragePackageID

  composition [0..*] of I_InsurPlcyCvrgSurchrgDiscount    as _InsurPlcyCvrgSurchrgDiscount
  composition [0..*] of I_InsurancePolicyCvrgLimit        as _InsurancePolicyCvrgLimit
  composition [0..*] of I_InsurancePolicyCvrgClause       as _InsurancePolicyCvrgClause
  composition [0..*] of I_InsurPolicyCvrgDeductible       as _InsurPolicyCvrgDeductible
  composition [0..*] of I_InsurancePolicyInsuredObject    as _InsurancePolicyInsuredObject
  composition [0..*] of I_InsurPlcySubCoverage            as _InsurPlcySubCoverage
  composition [0..*] of I_InsurPlcyCvrgTypeRegionalCl     as _InsurPlcyCvrgTypeRegionalCl
  composition [0..*] of I_InsurPlcyCvrgPremComparison     as _InsurPlcyCvrgPremComparison
  composition [0..*] of I_InsurCvrgPlannedProcessing      as _InsurCvrgPlndProcessing
  composition [0..*] of I_InsurPlcyCoverageBonusMalus     as _InsurPlcyCoverageBonusMalus

  association [1..1] to I_Currency                        as _PremiumCurrency           on  $projection.InsurPlcyPremiumCurrency = _PremiumCurrency.Currency
  association [1..1] to I_Currency                        as _CoverageCurrency          on  $projection.InsurPlcyCoverageCurrency = _CoverageCurrency.Currency
  association [1..1] to I_InsurContrCanclnReason          as _InsurContrCanclnReason    on  $projection.InsurContrCanclnRsn = _InsurContrCanclnReason.InsurContrCanclnRsn
  association [1..1] to I_InsurPlcyCvrgLifeCycSts         as _InsurPlcyCvrgLifeCycSts   on  $projection.InsurPlcyCvrgLifeCycleStatus = _InsurPlcyCvrgLifeCycSts.InsurPlcyCvrgLifeCycleStatus
  association [1..1] to I_InsurPlcyCvrgInsrdSumCalc       as _InsurPlcyCvrgInsrdSumCalc on  $projection.InsurPlcyCvrgInsrdSumCalcMeth = _InsurPlcyCvrgInsrdSumCalc.InsurPlcyCvrgInsrdSumCalcMeth
  association [1..1] to I_InsurPlcyCvrgSuspension         as _InsurPlcyCvrgSuspension   on  $projection.InsurPlcyCoverageSuspension = _InsurPlcyCvrgSuspension.InsurPlcyCoverageSuspension
  association [1..*] to I_InsurPlcyTemplateT              as _InsurPlcyTemplateT        on  $projection.InsurPlcyElementaryProdTmpl = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurPlcyCvrgPremExmpRsnLink    as _InsurPlcyCvrgPremExmpRsn  on  $projection.InsurPlcyCvrgPremExmpReason = _InsurPlcyCvrgPremExmpRsn.InsurPlcyCvrgPremExmpReason
                                                                                        and $projection.InsurPlcyElementaryProdTmpl = _InsurPlcyCvrgPremExmpRsn.InsurancePolicyCoverageControl

{

  key Coverage.InsurPlcyUUID,
  key Coverage.InsurPlcyInsurContr,
  key Coverage.InsurPlcyCoveragePackageID,
  key Coverage.InsurPlcyCoverageID,
      Coverage.InsurPlcyJrnlNmbr,
      Coverage.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Coverage.InsurPlcyProductPackageID,
      Coverage.InsurPlcyInsuranceCoverage,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Coverage.InsurPlcyElementaryProdTmpl,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCoverageStartDateTime,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCoverageEndDateTime,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgPremExmpRsn'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCvrgPremExmpReason'
      Coverage.InsurPlcyCvrgPremExmpReason,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgLifeCycSts'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCvrgLifeCycleStatus'
      Coverage.InsurPlcyCvrgLifeCycleStatus,
      @ObjectModel.foreignKey.association: '_InsurContrCanclnReason'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurContrCancellationReason'
      Coverage.InsurContrCanclnRsn,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgCanclnDateTime,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgSuspension'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyCoverageSuspension'
      Coverage.InsurPlcyCoverageSuspension,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgSuspnStrtDateTime,
      @Semantics.dateTime:true
      Coverage.InsurPlcyCvrgSuspnEndDateTime,
      @Semantics.amount.currencyCode: 'InsurPlcyCoverageCurrency'
      Coverage.InsurPlcyCvrgInsuredSumAmount,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgInsrdSumCalc'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCvrgInsrdSumCalcMeth'
      Coverage.InsurPlcyCvrgInsrdSumCalcMeth,
      Coverage.InsurPlcyCvrgInsuredSumPercent,
      @ObjectModel.foreignKey.association: '_CoverageCurrency'
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      Coverage.InsurPlcyCoverageCurrency,
      //FS-PM Auto sibling specific fields

      Coverage.InsurPlcyBonusRestorerType,
      Coverage.InsurPlcyVehDeregistrationDate,
      Coverage.InsurPlcyBonusMalusIsNotCeded,
      Coverage.InsurPlcyInsurEndMsgSendDate,
      Coverage.InsurPlcySubcoverageVariant,
      Coverage.InsurPlcyVehInsurCoverEndDate,
      Coverage.InsurPlcyNrOfVehClaimsRestored,
      Coverage.InsurPlcyCrteInsurEndMessage,
      Coverage.InsurPlcyDiscProtIsActive,
      @Semantics.systemDateTime.lastChangedAt: true
      Coverage.LastChangeDateTime,

      RegularPremium.InsurancePolicyPremium,
      RegularPremium.InsurPlcyJrnlNmbr    as InsurPlcyPremiumJournalNumber,
      RegularPremium.InsurPlcyJrnlEndNmbr as InsurPlcyPremJournalEndNumber,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPerdPremBfrTaxPaytAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPerdPremAftTaxPaytAmt,
      RegularPremium.InsurPremType,
      @Semantics.booleanIndicator:true
      RegularPremium.InsurPlcyCvrgIsPremiumExempt,
      RegularPremium.InsurPlcyCvrgPremExmpEndDate,
      @ObjectModel.foreignKey.association: '_PremiumCurrency'
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      RegularPremium.InsurPlcyPremiumCurrency,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPlcyTotAnnPremAmt,
      @Semantics.amount.currencyCode: 'InsurPlcyPremiumCurrency'
      RegularPremium.InsurPlcyPerdPremBfrTxPaytAmt,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      RegularPremium.InsurPlcyPremiumTemplate,

      /* Associations */
      _InsurPlcyCoveragePackage,
      _InsurPlcyCvrgSurchrgDiscount,
      _InsurancePolicyCvrgLimit,
      _InsurancePolicyCvrgClause,
      _InsurPlcyCvrgTypeRegionalCl,
      _InsurPlcyCvrgPremComparison,
      _InsurPolicyCvrgDeductible,
      _InsurancePolicyInsuredObject,
      _InsurPlcySubCoverage,
      _InsurCvrgPlndProcessing,
      _InsurPlcyCoverageBonusMalus,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurContrCanclnReason,
      @Consumption.hidden: true
      _InsurPlcyCvrgLifeCycSts,
      @Consumption.hidden: true
      _InsurPlcyCvrgSuspension,
      @Consumption.hidden: true
      _InsurPlcyCvrgInsrdSumCalc,
      @Consumption.hidden: true
      _CoverageCurrency,
      @Consumption.hidden: true
      _PremiumCurrency,
      @Consumption.hidden: true
      _InsurPlcyCvrgPremExmpRsn

}
where
      Coverage.InsurPlcyJrnlEndNmbr       =  2147483647
  and Coverage.InsurPlcyBusinessObject    =  'P'
  and Coverage.InsurPlcyCoveragePackageID <> 0