I_InsurancePolicyInsuredObject

@EndUserText.label: 'Cvrg InsOb of Cvrg Pckg in Insur Plcy'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_InsurPlcyCvrgInsrdObjClause',
                              '_InsurPlcyCvrgInsrdObjDcbl',
                              '_InsurPlcyCvrgObjSurchrgDisc',
                              '_InsurPolicyInsuredVehicle',
                              '_InsurPolicyInsrdObjNmdDrvr',
                              '_InsurPolicyInsrdObjSpclEquip',
                              '_InsurPlcyCvrgPckgCvrgBldng']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyInsuredObjectID',
   semanticKey: [ 'InsurPlcyInsrdObjUnqID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IPPlcyInsrdObj'
}

define view entity I_InsurancePolicyInsuredObject
  as select from I_InsurPlcyInsuredObjectBasic as Subject

  association        to parent I_InsurancePolicyCoverage as _InsurancePolicyCoverage  on  $projection.InsurPlcyUUID              = _InsurancePolicyCoverage.InsurPlcyUUID
                                                                                      and $projection.InsurPlcyInsurContr        = _InsurancePolicyCoverage.InsurPlcyInsurContr
                                                                                      and $projection.InsurPlcyCoveragePackageID = _InsurancePolicyCoverage.InsurPlcyCoveragePackageID
                                                                                      and $projection.InsurPlcyCoverageID        = _InsurancePolicyCoverage.InsurPlcyCoverageID

  composition [0..*] of I_InsurPlcyCvrgInsrdObjClause    as _InsurPlcyCvrgInsrdObjClause
  composition [0..*] of I_InsurPlcyCvrgInsrdObjDcbl      as _InsurPlcyCvrgInsrdObjDcbl
  composition [0..*] of I_InsurPlcyCvrgObjSurchrgDisc    as _InsurPlcyCvrgObjSurchrgDisc
  composition [0..1] of I_InsurPolicyInsuredVehicle      as _InsurPolicyInsuredVehicle
  composition [0..*] of I_InsurPolicyInsrdObjNmdDrvr     as _InsurPolicyInsrdObjNmdDrvr
  composition [0..*] of I_InsurPolicyInsrdObjSpclEquip   as _InsurPolicyInsrdObjSpclEquip
  composition [0..1] of I_InsurPlcyCvrgPckgCvrgBldng     as _InsurPlcyCvrgPckgCvrgBldng

  association [1..1] to I_InsurInsrdObjectCategory       as _InsurInsrdObjectCategory on  $projection.InsurPlcyInsuredObjectCategory = _InsurInsrdObjectCategory.InsurPlcyInsuredObjectCategory
  association [1..1] to I_InsurInsrdObjSubCategory       as _InsurInsrdObjSubCategory on  $projection.InsurPlcyInsrdObjSubCategory = _InsurInsrdObjSubCategory.InsurPlcyInsrdObjSubCategory
  association [1..*] to I_InsurPlcyTemplateT             as _InsurPlcyTemplateT       on  $projection.InsurPlcyInsrdObjectTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurInsurableObject           as _InsurInsurableObject     on  $projection.InsurPlcyInsrdObjUnqID = _InsurInsurableObject.InsurInsrblObj
                                                                                      and $projection.InsurInsrblObjJrnlNmbr = _InsurInsurableObject.InsurInsrblObjJrnlNmbr

{

  key Subject.InsurPlcyUUID,
  key Subject.InsurPlcyInsurContr,
  key Subject.InsurPlcyCoveragePackageID,
  key Subject.InsurPlcyCoverageID,
  key Subject.InsurPlcyInsuredObjectID,
      Subject.InsurPlcyJrnlNmbr,
      Subject.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Subject.InsurPlcyProductPackageID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Subject.InsurPlcyInsrdObjectTemplate,
      @ObjectModel.foreignKey.association: '_InsurInsrdObjectCategory'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyInsuredObjectCategory'
      Subject.InsurPlcyInsuredObjectCategory,
      @ObjectModel.foreignKey.association: '_InsurInsrdObjSubCategory'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyInsrdObjSubCategory'
      Subject.InsurPlcyInsrdObjSubCategory,
      @ObjectModel.foreignKey.association: '_InsurInsurableObject'
      Subject.InsurPlcyInsrdObjUnqID,
      Subject.InsurInsrblObjJrnlNmbr,
      @Semantics.systemDateTime.lastChangedAt: true
      Subject.LastChangeDateTime,

      /* Associations */
      _InsurancePolicyCoverage,
      _InsurPlcyCvrgInsrdObjClause,
      _InsurPlcyCvrgInsrdObjDcbl,
      _InsurPlcyCvrgObjSurchrgDisc,
      _InsurPolicyInsuredVehicle,
      _InsurPolicyInsrdObjNmdDrvr,
      _InsurPolicyInsrdObjSpclEquip,
      _InsurPlcyCvrgPckgCvrgBldng,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurInsrdObjectCategory,
      @Consumption.hidden: true
      _InsurInsrdObjSubCategory,
      _InsurInsurableObject

}
where
      Subject.InsurPlcyJrnlEndNmbr       =  2147483647
  and Subject.InsurPlcyBusinessObject    =  'P'
  and Subject.InsurPlcyCoveragePackageID <> 0
  and Subject.InsurPlcyCoverageID        <> 0