I_InspSampleCharcTP

@AbapCatalog.sqlViewName: 'IINSPSMPLCHARCTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Inspection Characteristic for Inspection Point'
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API  // Shall be set for #TRANSACTIONAL views

}

@ObjectModel: {
//    representativeKey: 'InspectionCharacteristic',

    semanticKey: ['InspectionLot','InspPlanOperationInternalID','InspectionCharacteristic','InspectionSubsetInternalID'],
    compositionRoot: false,
    createEnabled: false,
    updateEnabled: 'EXTERNAL_CALCULATION',   //true,

    deleteEnabled: false,                    // Assume: Inspection Results shall never be deleted!?

    transactionalProcessingEnabled: true,
//    draftEnabled: true,                    // No draft, only 'active persistence'

//    writeDraftPersistence: '..',           // Not necessary so far

    writeActivePersistence: 'VQASV_ACTIV',
    entityChangeStateId: 'ChangedDateTime',
    lifecycle.enqueue: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT15M'                   // Default 'PT15M'

      //  notificationBeforeExpiryInterval: 'PT1M'   // Default 'PT5M'

    },
    lifecycle.processing: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT30M'                        // Default 'PT30M'

      //  notificationBeforeExpiryInterval: 'PT3M'       // Default 'PT10M'

    },
    
    usageType: { dataClass: #TRANSACTIONAL, sizeCategory: #L, serviceQuality: #C }
}

define view I_InspSampleCharcTP as select from I_InspSubsetCharacteristic as _InspSubsetChar
    inner join I_InspectionLot       as _InspLot                 on  _InspSubsetChar.InspectionLot                = _InspLot.InspectionLot
    inner join I_InspectionOperation as _InspOper                on  _InspSubsetChar.InspectionLot                = _InspOper.InspectionLot 
                                                                 and _InspSubsetChar.InspPlanOperationInternalID  = _InspOper.InspPlanOperationInternalID

    association [1..1] to I_InspCharacteristicTP as _InspCharc      on  $projection.InspectionLot                    = _InspCharc.InspectionLot
                                                                    and $projection.InspPlanOperationInternalID      = _InspCharc.InspPlanOperationInternalID
                                                                    and $projection.InspectionCharacteristic         = _InspCharc.InspectionCharacteristic
{
  key _InspSubsetChar.InspectionLot, 
  key _InspSubsetChar.InspPlanOperationInternalID, 
  key _InspSubsetChar.InspectionCharacteristic, 
  key _InspSubsetChar.InspectionSubsetInternalID, 
      _InspSubsetChar.InspectionCharacteristicStatus, 
      _InspSubsetChar.QualityControlChart, 
      _InspSubsetChar.InspSampleAcceptanceNumber, 
      _InspSubsetChar.InspSampleRejectionNumber, 
      _InspSubsetChar.InspSampleValuationRule, 
      _InspSubsetChar.InspectionSampleSize, 
      _InspSubsetChar.InspLotDynRuleStage, 
      _InspSubsetChar.InspectionSeverity, 
      _InspSubsetChar.InspSubsetCharcCreationDate, 
      
      //eTag - taken from Inspection Lot (Hint: Using the association seems not possible -> got errors from BO generation!!)

      @ObjectModel.readOnly: true
      _InspLot.ChangedDateTime,
     
     // for Auth Check only

      @Consumption.hidden: true
      _InspLot.Plant,
      @Consumption.hidden: true      
      _InspLot.InspectionLotType,     
      @Consumption.hidden: true
      _InspLot.MatlQualityAuthorizationGroup,
      @Consumption.hidden: true
      _InspLot.InspectionSubsetType,
      @Consumption.hidden: true
      _InspLot.IsBusinessPurposeCompleted,
      @Consumption.hidden: true
      _InspOper._WorkCenter.WorkCenter,

   /* Object model relations */
    @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
    _InspCharc

    
}