I_INSPSUBSETCHARACTERISTIC

@AbapCatalog.sqlViewName: 'IINSPSUBSETCHAR'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Inspection Charc for an Inspection Point'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #B
    },
    representativeKey: 'InspectionSubsetInternalID'
}
@Metadata.ignorePropagatedAnnotations: true

define view I_InspSubsetCharacteristic
  as select from qasv
  association [1..1] to I_InspectionLot            as _InspectionLot            on  $projection.InspectionLot = _InspectionLot.InspectionLot
  association [1..1] to I_InspectionOperation      as _InspectionOperation      on  $projection.InspectionLot               = _InspectionOperation.InspectionLot
                                                                                and $projection.InspPlanOperationInternalID = _InspectionOperation.InspPlanOperationInternalID
  association [1..1] to I_InspectionSubset         as _InspectionSubset         on  $projection.InspectionLot               = _InspectionSubset.InspectionLot
                                                                                and $projection.InspPlanOperationInternalID = _InspectionSubset.InspPlanOperationInternalID
                                                                                and $projection.InspectionSubsetInternalID  = _InspectionSubset.InspectionSubsetInternalID
  association [1..1] to I_InspectionCharacteristic as _InspectionCharacteristic on  $projection.InspectionLot               = _InspectionCharacteristic.InspectionLot
                                                                                and $projection.InspPlanOperationInternalID = _InspectionCharacteristic.InspPlanOperationInternalID
                                                                                and $projection.InspectionCharacteristic    = _InspectionCharacteristic.InspectionCharacteristic
  association [0..1] to I_InspSubsetResult         as _InspSubsetResult         on  $projection.InspectionLot               = _InspSubsetResult.InspectionLot
                                                                                and $projection.InspPlanOperationInternalID = _InspSubsetResult.InspPlanOperationInternalID
                                                                                and $projection.InspectionSubsetInternalID  = _InspSubsetResult.InspectionSubsetInternalID
                                                                                and $projection.InspectionCharacteristic    = _InspSubsetResult.InspectionCharacteristic
  association [0..*] to I_InspectionResultValue    as _InspectionResultValue    on  $projection.InspectionLot               = _InspectionResultValue.InspectionLot
                                                                                and $projection.InspPlanOperationInternalID = _InspectionResultValue.InspPlanOperationInternalID
                                                                                and $projection.InspectionSubsetInternalID  = _InspectionResultValue.InspectionSubsetInternalID
                                                                                and $projection.InspectionCharacteristic    = _InspectionResultValue.InspectionCharacteristic
  association [0..1] to I_InspectionResultStatus   as _InspCharacteristicStatus on  $projection.InspectionCharacteristicStatus = _InspCharacteristicStatus.InspectionResultStatus
  association [0..1] to I_InspectionSeverity       as _InspectionSeverity       on  $projection.InspectionSeverity = _InspectionSeverity.InspectionSeverity
  association [0..1] to I_UnitOfMeasure            as _InspCharcSampleUnit      on  $projection.InspCharacteristicSampleUnit = _InspCharcSampleUnit.UnitOfMeasure
  //Extension

  association [1..1] to E_InspSubsetCharacteristic as _Extension                on  $projection.InspectionLot               = _Extension.InspectionLot
                                                                                and $projection.InspPlanOperationInternalID = _Extension.InspPlanOperationInternalID
                                                                                and $projection.InspectionCharacteristic    = _Extension.InspectionCharacteristic
                                                                                and $projection.InspectionSubsetInternalID  = _Extension.InspectionSubsetInternalID
{
      @ObjectModel.foreignKey.association: '_InspectionLot'
  key prueflos        as InspectionLot,
      @ObjectModel.foreignKey.association: '_InspectionOperation'
  key vorglfnr        as InspPlanOperationInternalID,
      @ObjectModel.foreignKey.association: '_InspectionCharacteristic'
  key merknr          as InspectionCharacteristic,
  key probenr         as InspectionSubsetInternalID,
      qasv.satzstatus as InspectionCharacteristicStatus,
      qasv.qrknr      as QualityControlChart,
      qasv.annahmez   as InspSampleAcceptanceNumber,
      qasv.rueckwez   as InspSampleRejectionNumber,
      @Semantics.booleanIndicator
      qasv.kfaktorni  as InspSampleHasAcceptanceFactor,
      qasv.kfaktor    as InspSampleAcceptanceFactor,
      qasv.antverf    as DefectFractionEstimationProced,
      qasv.bewregel   as InspSampleValuationRule,
      qasv.fakplanme  as BOOCharcMatlToSampleUnitRate,
      qasv.fakprobme  as BOOCharcSampleToMatlUnitRate,
      qasv.stiproumf  as InspectionSampleSize,
      @ObjectModel.foreignKey.association: '_InspCharcSampleUnit'
      @Semantics.unitOfMeasure: true
      qasv.probemgeh  as InspCharacteristicSampleUnit,
      qasv.probmgfak  as InspSpecSampleQuantityFactor,
      @Semantics.quantity.unitOfMeasure: 'InspCharacteristicSampleUnit'      
      qasv.pruefumf   as InspectionSampleQuantity,
      @Semantics.unitOfMeasure: true
      qasv.mengeneinh as InspectionLotSampleUnit,
      qasv.prstufe    as InspLotDynRuleStage,
      qasv.prschaerfe as InspectionSeverity,
      @Semantics.systemDate.createdAt: true
      qasv.erstelldat as InspSubsetCharcCreationDate,

      // Associations

      _InspectionLot,
      _InspectionOperation,
      _InspectionSubset,
      _InspectionCharacteristic,
      _InspSubsetResult,
      _InspectionResultValue,
      _InspCharacteristicStatus,
      _InspCharcSampleUnit,
      _InspectionSeverity
}