I_FixedAssetWorklist

@AbapCatalog: {sqlViewName: 'IFASSETLIST', preserveKey: true}
@Analytics: { dataCategory: #DIMENSION }
@EndUserText.label: 'Interface View for Fixed Asset Worklist'
@VDM.viewType: #COMPOSITE     //needs to be a BASIC view though it´s a COMPOSITE. Reason: Extension Include I_FixedAssetWorklist...

@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { representativeKey: 'FixedAsset',
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #MIXED }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: {ignorePropagatedAnnotations: true, allowExtensions: true}

define view I_FixedAssetWorklist

  as select from I_FixedAsset       as an
    inner join   I_FixedAssetAssgmt as az on  an.CompanyCode      = az.CompanyCode
                                          and an.MasterFixedAsset = az.MasterFixedAsset
                                          and an.FixedAsset       = az.FixedAsset
  //left outer join I_Supplier         as supplier on an.Supplier = supplier.Supplier



  // Association for additional descriptions of ID Elements

  association [0..1] to I_FixedAssetFinDataCmpltns as _FixedAssetFinDataCmpltns     on  an.FixedAssetFinDataCmpltns = _FixedAssetFinDataCmpltns.FixedAssetFinDataCmpltns
  association [0..1] to I_FixedAssetStatus         as _FixedAssetStatus             on  $projection.Status = _FixedAssetStatus.Status
  association [0..1] to I_TaxJurisCalcProcedure    as _TaxJurisdictionCalcProcedure on  $projection.taxcalculationprocedure = _TaxJurisdictionCalcProcedure.TaxJurisdictionCalcProcedure
  association [0..1] to I_TaxJurisdiction          as _TaxJurisdiction              on  $projection.TaxJurisdiction         = _TaxJurisdiction.TaxJurisdiction
                                                                                    and $projection.taxcalculationprocedure = _TaxJurisdiction.TaxJurisdictionCalcProcedure
{

      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
  key an.MasterFixedAsset,
  key an.FixedAsset,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key an.CompanyCode,
      @Semantics.businessDate.to: true
  key az.ValidityEndDate,

      @Semantics.businessDate.at: true
      LastChangeDate,
      case when AssetCapitalizationDate <> '00000000' and AssetDeactivationDate = '00000000'
           then cast('1' as domvalue_l)
           else cast('0' as domvalue_l)
           end                  as IsCapitalized, // technical field for counting capitalizied assets

      @ObjectModel.foreignKey.association: '_FixedAssetStatus'
      case when AssetDeactivationDate <> '00000000' then cast('3' as domvalue_l) //3-Retired

           when AssetCapitalizationDate <> '00000000' and FixedAssetFinDataCmpltns = '0' then cast('2' as domvalue_l)  //2-Capitalized

           when AssetCapitalizationDate = '00000000' and FixedAssetFinDataCmpltns = '0' then cast('0' as domvalue_l) //0-In Process

           when AssetCapitalizationDate <> '00000000' and FixedAssetFinDataCmpltns <> '0' then cast('4' as domvalue_l) //4-Incomplete Capitalized

           when AssetCapitalizationDate = '00000000' and FixedAssetFinDataCmpltns <> '0' then cast('1' as domvalue_l) //1-Incomplete In Process

           else cast('1' as domvalue_l) //1-Incomplete In Process

        end                     as Status,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      az.ControllingArea,
      an.FixedAssetExternalID,
      FixedAssetDescription,
      @Semantics.text
      cast(an.AssetAdditionalDescription as fis_txa50_more) as AssetAdditionalDescription,
      @ObjectModel.foreignKey.association: '_FixedAssetFinDataCmpltns'
      an.FixedAssetFinDataCmpltns,
      InventoryNote,
      @ObjectModel.foreignKey.association: '_InvestmentReason'
      InvestmentReason,
      AccountIsMarkedForDeletion,
      an.AccountIsBlockedForPosting,
      AcquisitionValueDate,
      OriginalFixedAssetValueDate,
      InvestmentProjectWBSElement,
      OriginalAcquisitionFiscalYear,
      AssetUnderConstIsInvmtMsr,
      LastRetirementValueDate,
      LastChangedByUser,
      OriginalMasterFixedAsset,
      OriginalFixedAsset,
      AssetCapitalizationDate,
      @ObjectModel.foreignKey.association: '_AssetClass'
      an.AssetClass,
      FixedAssetGroup,
      FixedAssetOrderDate,
      AssetDeactivationDate,
      InvestmentOrder,
      NoticeOfAssessmentTaxID,
      LastAssessmentNoticeDate,
      @ObjectModel.foreignKey.association: '_FixedAssetPropertyType'
      FixedAssetPropertyType,
      @Semantics.businessDate.at: true
      an.CreationDate,
      an.CreatedByUser,
      AreaSizeUnit,
      @ObjectModel.foreignKey.association: '_Group5AssetEvaluationKey'
      Group5AssetEvaluationKey,
      PlannedRetirementDate,
      @ObjectModel.foreignKey.association: '_ManualDepreciationReason'
      ManualDepreciationReason,
      AssetManufacturerName,
      InventoryIsCounted,
      Inventory,
      LastInventoryDate,
      @ObjectModel.foreignKey.association: '_AssetAccountDetermination'
      AssetAccountDetermination,
      AssetCountryOfOrigin,
      LastReorganizationDate,
      LegacyDataTransferDate,
      //      case an.Supplier

      //        when ''

      //          then an.AssetSupplierName

      //        else supplier.SupplierName

      //      end                                          as  AssetSupplierName,

      an.AssetSupplierName      as AssetSupplierName,
      an.Supplier,
      BaseUnit,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      Quantity,
      @ObjectModel.foreignKey.association: '_Group1AssetEvaluationKey'
      Group1AssetEvaluationKey,
      @ObjectModel.foreignKey.association: '_Group2AssetEvaluationKey'
      Group2AssetEvaluationKey,
      @ObjectModel.foreignKey.association: '_Group3AssetEvaluationKey'
      Group3AssetEvaluationKey,
      @ObjectModel.foreignKey.association: '_Group4AssetEvaluationKey'
      Group4AssetEvaluationKey,
      AssetSerialNumber,
      AssetTypeName,
      @ObjectModel.foreignKey.association: '_EnvrnmtlInvestmentReason'
      EnvrnmtlInvestmentReason,
      PartnerCompany,
      IsGroupAsset,
      IsLineItemSettled,
      FirstAcquisitionFiscalYear,
      FirstAcquisitionFiscalPeriod,

      az.GrantID,
      az.Room,
      az.BudgetPeriod,
      @Semantics.businessDate.from: true
      az.ValidityStartDate,
      @ObjectModel.foreignKey.association: '_InternalOrder'
      az.InternalOrder,
      az.FundsCenter,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      az.FunctionalArea,
      az.Fund,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      az.BusinessArea,
      @ObjectModel.foreignKey.association: '_MaintenanceOrder'
      az.MaintenanceOrder,
      az.REInternalFinNumber    as RealEstateObject,
      az.WBSElementInternalID_2 as WBSElementInternalID,
      az.VehicleLicensePlateNumber,
      @ObjectModel.foreignKey.association: '_CostCenter'
      az.CostCenter,
      az.ResponsibleCostCenter,
      az.CostCtrActivityType,
      az.PersonnelNumber,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      az.ProfitCenter,
      @ObjectModel.foreignKey.association: '_Segment'
      az.Segment,
      az.AssetLocation,
      @ObjectModel.foreignKey.association: '_FunctionalLocation'
      az.FunctionalLocation,
      @ObjectModel.foreignKey.association: '_TaxJurisdiction'
      az.TaxJurisdiction,
      @ObjectModel.foreignKey.association: '_TaxJurisdictionCalcProcedure'
      an._CompanyCode._Country.TaxCalculationProcedure,
      @ObjectModel.foreignKey.association: '_Plant'
      az.Plant,
      az.IsShutDown,
      az.ShiftOperationFactor,

      an._CompanyCode,
      _ControllingArea,
      an._MasterFixedAsset,
      an._AssetClass,


      //Associations

      _FunctionalLocation,
      _CostCenter,
      _ProfitCenter,
      _AssetAccountDetermination,
      _TaxJurisdiction,
      _TaxJurisdictionCalcProcedure,
      _Plant,
      _BusinessArea,
      _InternalOrder,
      _MaintenanceOrder,
      _Segment,
      _FunctionalArea,
      _FixedAssetPropertyType,
      _ManualDepreciationReason,
      _Group1AssetEvaluationKey,
      _Group2AssetEvaluationKey,
      _Group3AssetEvaluationKey,
      _Group4AssetEvaluationKey,
      _Group5AssetEvaluationKey,
      _InvestmentReason,
      _EnvrnmtlInvestmentReason,
      _FixedAssetFinDataCmpltns,
      _FixedAssetStatus,
      _Supplier,
      _AssetLocation



}