I_FIXEDASSET

@Analytics: {
      technicalName: 'IFIXASSET',
      dataCategory: #DIMENSION,
      dataExtraction: {
        enabled: true,
        delta.changeDataCapture: {
          mapping:
            [
              {
                table: 'FAAT_MD',
                role: #MAIN,
                viewElement: ['CompanyCode', 'MasterFixedAsset', 'FixedAsset'],
                tableElement: ['comp_code', 'asset_no', 'asset_subno']
              }
            ]
         }
      }
    }
@EndUserText.label: 'Fixed Asset'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { representativeKey: 'FixedAsset',
                compositionRoot:true,
                usageType.serviceQuality: #A,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #MASTER,
                modelingPattern: #ANALYTICAL_DIMENSION,
                supportedCapabilities: [#ANALYTICAL_DIMENSION]
              }
@Metadata: {ignorePropagatedAnnotations: true, allowExtensions:true}

define view entity I_FixedAsset
  as select from P_FixedAsset
  // Association to children

  association [0..*] to I_FixedAssetAssgmt             as _FixedAssetAssgmt             on  $projection.CompanyCode      = _FixedAssetAssgmt.CompanyCode
                                                                                        and $projection.MasterFixedAsset = _FixedAssetAssgmt.MasterFixedAsset
                                                                                        and $projection.FixedAsset       = _FixedAssetAssgmt.FixedAsset
  association [0..*] to I_FixedAssetDeprArea           as _FixedAssetDeprArea           on  $projection.CompanyCode      = _FixedAssetDeprArea.CompanyCode
                                                                                        and $projection.MasterFixedAsset = _FixedAssetDeprArea.MasterFixedAsset
                                                                                        and $projection.FixedAsset       = _FixedAssetDeprArea.FixedAsset
  association [0..*] to I_AssetValuationForLedger      as _AssetValuationForLedger      on  $projection.CompanyCode      = _AssetValuationForLedger.CompanyCode
                                                                                        and $projection.MasterFixedAsset = _AssetValuationForLedger.MasterFixedAsset
                                                                                        and $projection.FixedAsset       = _AssetValuationForLedger.FixedAsset
  association [0..*] to I_FixedAssetForLedger          as _FixedAssetForLedger          on  $projection.CompanyCode      = _FixedAssetForLedger.CompanyCode
                                                                                        and $projection.MasterFixedAsset = _FixedAssetForLedger.MasterFixedAsset
                                                                                        and $projection.FixedAsset       = _FixedAssetForLedger.FixedAsset
  //Associations to Object Core Views

  association [0..1] to I_CompanyCode                  as _CompanyCode                  on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_MasterFixedAsset             as _MasterFixedAsset             on  $projection.CompanyCode      = _MasterFixedAsset.CompanyCode
                                                                                        and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
  association [0..1] to I_AssetClass                   as _AssetClass                   on  $projection.AssetClass = _AssetClass.AssetClass
  association [0..1] to I_Currency                     as _Currency                     on  $projection.Currency = _Currency.Currency
  association [0..1] to I_Globalcompany                as _PartnerCompany               on  $projection.PartnerCompany = _PartnerCompany.Company
  association [0..1] to I_AssetAcctDetermination       as _AssetAccountDetermination    on  $projection.AssetAccountDetermination = _AssetAccountDetermination.AssetAccountDetermination
  association [0..1] to I_Supplier                     as _Supplier                     on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_Country                      as _AssetCountryOfOrigin         on  $projection.AssetCountryOfOrigin = _AssetCountryOfOrigin.Country
  association [0..1] to I_UnitOfMeasure                as _UnitOfMeasure                on  $projection.BaseUnit = _UnitOfMeasure.UnitOfMeasure

  association [0..1] to I_Group1AssetEvaluationKey     as _Group1AssetEvaluationKey     on  $projection.Group1AssetEvaluationKey = _Group1AssetEvaluationKey.Group1AssetEvaluationKey
  association [0..1] to I_Group2AssetEvaluationKey     as _Group2AssetEvaluationKey     on  $projection.Group2AssetEvaluationKey = _Group2AssetEvaluationKey.Group2AssetEvaluationKey
  association [0..1] to I_Group3AssetEvaluationKey     as _Group3AssetEvaluationKey     on  $projection.Group3AssetEvaluationKey = _Group3AssetEvaluationKey.Group3AssetEvaluationKey
  association [0..1] to I_Group4AssetEvaluationKey     as _Group4AssetEvaluationKey     on  $projection.Group4AssetEvaluationKey = _Group4AssetEvaluationKey.Group4AssetEvaluationKey
  association [0..1] to I_Group5AssetEvaluationKey     as _Group5AssetEvaluationKey     on  $projection.Group5AssetEvaluationKey = _Group5AssetEvaluationKey.Group5AssetEvaluationKey
  association [0..1] to I_InvestmentReason             as _InvestmentReason             on  $projection.InvestmentReason = _InvestmentReason.InvestmentReason
  association [0..1] to I_EnvrnmtlInvestmentReason     as _EnvrnmtlInvestmentReason     on  $projection.EnvrnmtlInvestmentReason = _EnvrnmtlInvestmentReason.EnvrnmtlInvestmentReason
  association [0..1] to I_FixedAssetFinDataCmpltns     as _FixedAssetFinDataCmpltns     on  $projection.FixedAssetFinDataCmpltns = _FixedAssetFinDataCmpltns.FixedAssetFinDataCmpltns
  association [0..1] to I_FixedAssetPropertyType       as _FixedAssetPropertyType       on  $projection.FixedAssetPropertyType = _FixedAssetPropertyType.FixedAssetPropertyType
  association [0..1] to I_ManualDepreciationReason     as _ManualDepreciationReason     on  $projection.ManualDepreciationReason = _ManualDepreciationReason.ManualDepreciationReason
  association [0..1] to I_FixedAssetGroup              as _FixedAssetGroup              on  $projection.FixedAssetGroup = _FixedAssetGroup.FixedAssetGroup
  association [0..1] to I_InternalOrder                as _InvestmentOrder              on  $projection.InvestmentOrder = _InvestmentOrder.InternalOrder
  association [0..1] to I_WBSElementBasicData          as _InvestmentWBSElement         on  $projection.InvestmentProjectWBSElement_2 = _InvestmentWBSElement.WBSElementInternalID
  association [0..1] to I_AssetLifecycleStatus         as _AssetLifecycleStatus         on  $projection.AssetLifecycleStatus = _AssetLifecycleStatus.AssetLifecycleStatus
  association [0..1] to I_AssetCompletenessStatus      as _AssetCompletenessStatus      on  $projection.AssetCompletenessStatus = _AssetCompletenessStatus.AssetCompletenessStatus
  association [0..1] to I_AssetUnderConstructionStatus as _AssetUnderConstructionStatus on  $projection.AssetUnderConstructionStatus = _AssetUnderConstructionStatus.AssetUnderConstructionStatus
  association [0..1] to I_AssetStatusAtPurchase        as _AssetStatusAtPurchase        on  $projection.AssetStatusAtPurchase = _AssetStatusAtPurchase.AssetStatusAtPurchase
  association [0..1] to I_FixedAssetCountryData        as _FixedAssetCountryData        on  $projection.CompanyCode      = _FixedAssetCountryData.CompanyCode
                                                                                        and $projection.MasterFixedAsset = _FixedAssetCountryData.MasterFixedAsset
                                                                                        and $projection.FixedAsset       = _FixedAssetCountryData.FixedAsset
  association [0..*] to I_GlobAssetAssignment          as _GlobAssetAssignment          on  $projection.CompanyCode      = _GlobAssetAssignment.CompanyCode
                                                                                        and $projection.MasterFixedAsset = _GlobAssetAssignment.MasterFixedAsset
                                                                                        and $projection.FixedAsset       = _GlobAssetAssignment.FixedAsset
  association [0..1] to I_Currency                     as _OriginalAcquisitionCurrency  on  $projection.OriginalAcquisitionCurrency = _OriginalAcquisitionCurrency.Currency

  // Association to Extension View

  association [1..1] to E_FixedAsset                   as _Extension                    on  $projection.MasterFixedAsset = _Extension.MasterFixedAsset
                                                                                        and $projection.FixedAsset       = _Extension.FixedAsset
                                                                                        and $projection.CompanyCode      = _Extension.CompanyCode
{
      //Key fields

      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,
      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
  key MasterFixedAsset,
      @ObjectModel.text.element: ['FixedAssetDescription']
  key FixedAsset,

      //Relevant Fields

      case when FixedAsset = '0000' then cast(concat(ltrim(MasterFixedAsset, '0'), '-0') as fis_fixedasset_ext_id)
           when FixedAsset <> '0000' then cast(concat(concat( ltrim(MasterFixedAsset, '0') , '-'), ltrim(FixedAsset, '0' )) as fis_fixedasset_ext_id)
      end as FixedAssetExternalID,

      @ObjectModel.foreignKey.association: '_AssetClass'
      AssetClass,
      AssetSerialNumber,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @VDM.lifecycle: {status: #DEPRECATED}
      Quantity, //Works in OP only, hence deprecated in cloud with CE1911

      @ObjectModel: { foreignKey.association: '_UnitOfMeasure' }
      BaseUnit,
      Inventory,
      @Semantics.text:true
      FixedAssetDescription,
      @Semantics.text:true
      AssetAdditionalDescription,
      @ObjectModel: { foreignKey.association: '_Currency' }
      Currency, //CompanyCodeCurrency!

      @Semantics.amount.currencyCode: 'Currency'
      @VDM.lifecycle: {status: #DEPRECATED}
      OriglAcqnAmtInCoCodeCrcy, //Works in OP only, hence deprecated in cloud with CE1911. Now OriginalAcquisitionAmount (in Transaction Currency) is provided

      @ObjectModel.foreignKey.association: '_PartnerCompany'
      PartnerCompany,
      AssetManufacturerName,
      InHouseProdnPercent,
      @VDM.lifecycle: {status: #DEPRECATED}
      AssetSupplierName,
      InventoryNote,
      @ObjectModel.foreignKey.association: '_Group1AssetEvaluationKey'
      @VDM.lifecycle: {status: #DEPRECATED}
      Group1AssetEvaluationKey,
      @ObjectModel.foreignKey.association: '_Group2AssetEvaluationKey'
      @VDM.lifecycle: {status: #DEPRECATED}
      Group2AssetEvaluationKey,
      @ObjectModel.foreignKey.association: '_Group3AssetEvaluationKey'
      @VDM.lifecycle: {status: #DEPRECATED}
      Group3AssetEvaluationKey,
      @ObjectModel.foreignKey.association: '_Group4AssetEvaluationKey'
      @VDM.lifecycle: {status: #DEPRECATED}
      Group4AssetEvaluationKey,
      @ObjectModel.foreignKey.association: '_Group5AssetEvaluationKey'
      @VDM.lifecycle: {status: #DEPRECATED}
      Group5AssetEvaluationKey,
      @ObjectModel.foreignKey.association: '_AssetAccountDetermination'
      AssetAccountDetermination,
      HasHistory,
      @VDM.lifecycle: {status: #DEPRECATED}
      AssetCapitalizationDate, //Works in OP only, hence deprecated in cloud with CE1911, use I_FixedAssetForLedger.AssetCapitalizationDate instead

      @Semantics.fiscal.year: true
      @VDM.lifecycle: {status: #DEPRECATED}
      FirstAcquisitionFiscalYear, //Works in OP only, hence deprecated in cloud with CE1911, use I_FixedAssetForLedger.FirstAcquisitionFiscalYear instead

      @Semantics.fiscal.period: true
      @VDM.lifecycle: {status: #DEPRECATED}
      FirstAcquisitionFiscalPeriod, //Works in OP only, hence deprecated in cloud with CE1911, use I_FixedAssetForLedger.FirstAcquisitionFiscalPeriod instead

      @VDM.lifecycle: {status: #DEPRECATED}
      AssetDeactivationDate, //Works in OP only, hence deprecated in cloud with CE1911, use I_FixedAssetForLedger.AssetDeactivationDate instead

      @VDM.lifecycle: {status: #DEPRECATED}
      PlannedRetirementDate,
      FixedAssetOrderDate,
      OriginalMasterFixedAsset,
      @ObjectModel.foreignKey.association: '_FixedAssetGroup'
      FixedAssetGroup,
      @ObjectModel.foreignKey.association: '_InvestmentReason'
      InvestmentReason,
      AssetIsRealEstate,
      AreaSizeUnit,
      @ObjectModel.foreignKey.association: '_InvestmentOrder'
      InvestmentOrder,
      @ObjectModel.foreignKey.association: '_InvestmentWBSElement'
      InvestmentProjectWBSElement_2,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'InvestmentProjectWBSElement_2'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'InvestmentProjectWBSElement_2'
      InvestmentProjectWBSElement,
      InventoryIsCounted,
      LastInventoryDate,
      @VDM.lifecycle: {status: #DEPRECATED}
      AssetSynchronizationRule,
      @Semantics.fiscal.year: true
      OriginalAcquisitionFiscalYear,
      AssetTypeName,
      @ObjectModel.foreignKey.association: '_Supplier'
      Supplier,
      @ObjectModel.foreignKey.association: '_AssetCountryOfOrigin'
      AssetCountryOfOrigin,
      NoticeOfAssessmentTaxID,
      LastAssessmentNoticeDate,
      @ObjectModel.foreignKey.association: '_EnvrnmtlInvestmentReason'
      EnvrnmtlInvestmentReason,
      @Semantics.businessDate.at: true
      LastChangeDate,

      @ObjectModel.foreignKey.association: '_FixedAssetFinDataCmpltns'
      FixedAssetFinDataCmpltns,
      AccountIsMarkedForDeletion,
      AccountIsBlockedForPosting,
      @VDM.lifecycle: {status: #DEPRECATED}
      AcquisitionValueDate, //Works in OP only, hence deprecated in cloud with CE1911, use I_FixedAssetForLedger.AcquisitionValueDate instead

      OriginalFixedAssetValueDate,
      AssetUnderConstIsInvmtMsr,
      @VDM.lifecycle: {status: #DEPRECATED}
      LastRetirementValueDate, //Works in OP only, hence deprecated in cloud with CE1911, use I_AssetValuationForLedger.LastRetirementValueDate

      LastChangedByUser,
      @ObjectModel.foreignKey.association: '_FixedAssetPropertyType'
      FixedAssetPropertyType,
      @Semantics.businessDate.at: true
      CreationDate,
      CreatedByUser,
      @ObjectModel.foreignKey.association: '_ManualDepreciationReason'
      @VDM.lifecycle: {status: #DEPRECATED}
      ManualDepreciationReason, //Works in OP only, hence deprecated in cloud with CE1911

      LastReorganizationDate,
      LegacyDataTransferDate,
      @VDM.lifecycle: {status: #DEPRECATED}
      IsGroupAsset, //Works in OP only, hence deprecated in cloud with CE1911

      IsLineItemSettled,
      OriginalFixedAsset,
      MasterFixedAssetSearchTerm,
      @VDM.lifecycle: {status: #DEPRECATED, successor: 'AssetIsAcquiredUsed'}
      @ObjectModel: {foreignKey.association: '_AssetStatusAtPurchase'}
      case when P_FixedAsset.AssetStatusAtPurchase = 'X' then cast('X' as fis_asset_purchased_new_or_usd)
           when P_FixedAsset.AssetStatusAtPurchase = 'Y' then cast('Y' as fis_asset_purchased_new_or_usd)
           when not(P_FixedAsset.AssetStatusAtPurchase = 'X' or P_FixedAsset.AssetStatusAtPurchase = 'Y') then cast('N' as fis_asset_purchased_new_or_usd)
      end as AssetStatusAtPurchase,
      AssetIsAcquiredUsed,

      /* Added at CE1905 */
      IsMainAsset,
      @ObjectModel.foreignKey.association: '_AssetLifeCycleStatus'
      AssetLifecycleStatus,
      @ObjectModel.foreignKey.association: '_AssetCompletenessStatus'
      AssetCompletenessStatus,
      @ObjectModel.foreignKey.association: '_AssetUnderConstructionStatus'
      AssetUnderConstructionStatus,
      AssetCreationValidityDate,
      CreationDateTime,
      LastChangeDateTime,
      AssetScreenLayout,
      @Semantics.amount.currencyCode: 'OriginalAcquisitionCurrency'
      OriginalAcquisitionAmount,
      @ObjectModel: { foreignKey.association: '_OriginalAcquisitionCurrency' }
      OriginalAcquisitionCurrency,
      PropertyClass,
      LocalTaxOffice,
      Municipality,
      LandRegisterDate,
      LandRegisterEntrySequence,
      LandRegisterEntryDate,
      LandRegisterVolume,
      LandRegisterPage,
      LandRegisterMap,
      LandPlot,
      ConveyanceDate,
      @Semantics.quantity.unitOfMeasure: 'AreaSizeUnit'
      AreaSize,
      LeaseSupplier,
      LeaseAgreement,
      LeaseAgreementDate,
      LeaseTermEndDate,
      LeaseTermStartDate,
      LeaseDurationInFiscalYears,
      LeaseDurationInFiscalPeriods,
      LeaseType,
      LeasedAssetNote,
      @VDM.lifecycle: {status: #DEPRECATED, successor: 'LegacyMasterFixedAsset'}
      LegacyAsset,
      LegacyFixedAssetCompanyCode,
      LegacyMasterFixedAsset,
      LegacyFixedAsset,
      LegacyDataTransferSequence,
      AssetIsForPostCapitalization,
      @Consumption.hidden: true
      AssetAuthorizationContext, //Needed for DCL

      @Consumption.hidden: true
      ObjectInternalID,

      /* Associations */
      _FixedAssetAssgmt,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_AssetValuationForLedger'
      _FixedAssetDeprArea,
      _AssetValuationForLedger,
      _FixedAssetForLedger,

      _CompanyCode,
      _MasterFixedAsset,
      _AssetClass,
      _Currency,
      _UnitOfMeasure,
      _PartnerCompany,
      _Group1AssetEvaluationKey,
      _Group2AssetEvaluationKey,
      _Group3AssetEvaluationKey,
      _Group4AssetEvaluationKey,
      _Group5AssetEvaluationKey,
      _AssetAccountDetermination,
      _Supplier,
      _AssetCountryOfOrigin,
      _InvestmentReason,
      _EnvrnmtlInvestmentReason,
      _FixedAssetFinDataCmpltns,
      _FixedAssetPropertyType,
      _ManualDepreciationReason,
      _FixedAssetGroup,
      _InvestmentOrder,
      _InvestmentWBSElement,
      _AssetLifecycleStatus,
      _AssetCompletenessStatus,
      _AssetUnderConstructionStatus,
      _AssetStatusAtPurchase,
      _FixedAssetCountryData,
      _GlobAssetAssignment,
      _OriginalAcquisitionCurrency
}