I_EngmntProjServiceOrgDetails

@AbapCatalog: {
  sqlViewName: 'IEPSERORGD',
  compiler.compareFilter: true,
  preserveKey: true
  }
@VDM: {
  lifecycle.contract.type: #PUBLIC_LOCAL_API,
  viewType:#COMPOSITE
  }
@ObjectModel.representativeKey: 'EngagementProjectServiceOrg'
@EndUserText.label: 'Engagement Project Service Org Details'
@AccessControl.authorizationCheck:#CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: {
  allowExtensions:true,
  ignorePropagatedAnnotations:true
  }
@ObjectModel: {
  usageType.serviceQuality: #B,
  usageType.sizeCategory: #S,
  usageType.dataClass: #CUSTOMIZING,
  supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                          #CDS_MODELING_DATA_SOURCE,
                          #SQL_DATA_SOURCE]
}
define view I_EngmntProjServiceOrgDetails
  as select from P_EngmntProjServiceOrg as A
  association [0..1] to I_EngagementProjectSrvcOrgText as _Text  
                     on _Text.EngagementProjectServiceOrg = $projection.EngagementProjectServiceOrg
                     and _Text.Language = $session.system_language 
  association [0..1] to I_CompanyCode as _CompanyCode 
                     on $projection.EngmntProjectCompanyCode       = _CompanyCode.CompanyCode  
  association [0..1] to I_ControllingArea as _ControllingArea  
                     on $projection.EngagementProjectCtrlgArea     = _ControllingArea.ControllingArea
  association [0..1] to I_SalesOrganization as _SalesOrganization 
                     on $projection.EngagementProjectSalesOrg      = _SalesOrganization.SalesOrganization     
  association [0..1] to I_DistributionChannel as _DistributionChannel      
                     on $projection.EngagementProjectDistrChnl     = _DistributionChannel.DistributionChannel  
  association [0..1] to I_Division as _Division
                     on $projection.EngagementProjectDivision      = _Division.Division
  association [0..1] to I_PurchasingOrganization as _PurchasingOrganization
                     on $projection.EngagementProjectPurchasingOrg = _PurchasingOrganization.PurchasingOrganization 
  association [0..1] to I_Plant as _Plant 
                     on $projection.EngagementProjectPlant         = _Plant.Plant 
  association [0..*] to I_CostCenter as _CostCenter    
                     on $projection.ServiceOrgDefaultCostCenter    = _CostCenter.CostCenter                                                                                                                            
{
       @ObjectModel.text.association: '_Text'
  key  A.EngagementProjectServiceOrg,

       @Semantics.booleanIndicator:true
       A.EngmtProjServiceOrgIsSales,

       @Semantics.booleanIndicator:true
       A.EngmtProjServiceOrgIsDelivery,

       A.RestrictedTimePosting,
      
       @EndUserText.label: 'Company Code'
       A.EngmntProjectCompanyCode,

       @EndUserText.label: 'Controlling Area'
       A.EngagementProjectCtrlgArea,

       @EndUserText.label: 'Sales Organization'
       A.EngagementProjectSalesOrg,
  
       @EndUserText.label: 'Distribution Channel'
       A.EngagementProjectDistrChnl,
      
       @EndUserText.label: 'Division'
       A.EngagementProjectDivision,

       @EndUserText.label: 'Purchasing Organization'
       A.EngagementProjectPurchasingOrg,

       @EndUserText.label: 'Plant'
       A.EngagementProjectPlant,
      
       @EndUserText.label: 'Cost Center'
       A.ServiceOrgDefaultCostCenter,

      _Text,
      _CompanyCode,
      _ControllingArea,
      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _PurchasingOrganization,
      _Plant,
      _CostCenter       
}