I_EngagementProjectPlanData

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IEPROJPLANDATA'
@EndUserText.label: 'Engagement Project Plan Data'
@VDM.viewType: #BASIC
@Analytics:{dataCategory:#FACT}
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.personalData.blocking: #NOT_REQUIRED
define view I_EngagementProjectPlanData

  as select from P_Engageprojplandata as EngagementProjectPlanData

  association [0..1] to I_EngagementProject           as _EngagementProject           on  $projection.EngagementProjectUUID = _EngagementProject.EngagementProjectUUID

  association [0..1] to I_EngagementProjFinancialPlan as _EngagementProjFinancialPlan on  $projection.EngagementProjFinPlanUUID = _EngagementProjFinancialPlan.EngagementProjFinPlanUUID

  association [1..1] to I_WorkPackage                 as _WorkPackage                 on  $projection.WorkPackage = _WorkPackage.WorkPackage

  association [0..1] to I_EngmntProjResourceType      as _EngmntProjResourceType      on  $projection.EngagementProjectResourceType = _EngmntProjResourceType.EngagementProjectResourceType

  association [0..1] to I_EngagementProjectResource   as _EngagementProjectResource   on  $projection.EngagementProjectResource = _EngagementProjectResource.EngagementProjectResource
                                                                                      and $projection.EngagementProjectResourceType = _EngagementProjectResource.EngagementProjectResourceType

  association [0..1] to I_WorkPackageWorkItem         as _WorkItem                    on  $projection.WorkItem    = _WorkItem.WorkItem
                                                                                      and $projection.WorkPackage = _WorkItem.WorkPackage

  association [0..1] to I_Currency                    as _Currency                    on  $projection.Currency = _Currency.Currency

  association [0..1] to I_UnitOfMeasure               as _UnitOfMeasure               on  $projection.UnitOfMeasure = _UnitOfMeasure.UnitOfMeasure

  association [0..*] to I_PersnWrkAgreementDet        as _PersnWrkAgreementDet        on  $projection.EmploymentInternalID = _PersnWrkAgreementDet.PersonWorkAgreement
  //                                                                                      and _Employment.StartDate            <= $projection.WorkPackageEndDate

  //                                                                                      and _Employment.EndDate              >= $projection.WorkPackageStartDate


  association [0..1] to I_EngagementProjectSrvcOrg    as _EngagementProjectServiceOrg on  $projection.EngagementProjectServiceOrg = _EngagementProjectServiceOrg.EngagementProjectServiceOrg

  //association [0..1] to I_PlanSkillTags    as _PlanSkillTags on  $projection.ResourceDemandUUID = _PlanSkillTags.ResourceDemandUUID


{

  key    cast(EngagementProjectPlanData.fp_key  as /cpd/eng_pfp_db_key preserving type )             as EngagementProjFinPlanUUID,

  key    cast(EngagementProjectPlanData.wp_key as /cpd/wp_db_key preserving type )                   as WorkPackageUUID,

  key    EngagementProjectPlanData.version                                                           as EngmtProjFinPlanVersion,

         @ObjectModel.foreignKey.association: '_EngmntProjResourceType'
  key    EngagementProjectPlanData.res_type                                                          as EngagementProjectResourceType,

      //--[ GENERATED:012:GlBfhyJl7jY4oBIOE}WCZW

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_WorkPackageWorkItemStdVH',
                     element: 'WorkItem' },
          additionalBinding: [{ localElement: 'WorkPackage',
                                element: 'WorkPackage' }]
        }]
      // ]--GENERATED

         @ObjectModel.foreignKey.association: '_WorkItem'
  key    EngagementProjectPlanData.workitem_id                                                       as WorkItem,

         @Semantics.fiscal.period: true
  key    EngagementProjectPlanData.period                                                            as FiscalPeriod,

         @Semantics.fiscal.year: true
  key    EngagementProjectPlanData.fc_year                                                           as FiscalYear,

         @ObjectModel.foreignKey.association: '_EngagementProjectResource'
  key    EngagementProjectPlanData.resource_id                                                       as EngagementProjectResource,

      //--[ GENERATED:012:GlBfhyJl7jY4oBIOE}WCZW

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_PersnWrkAgreementDetStdVH',
                     element: 'PersonWorkAgreement' }
        }]
      // ]--GENERATED

         @ObjectModel.foreignKey.association: '_PersnWrkAgreementDet'
  key    EngagementProjectPlanData.employee                                                          as EmploymentInternalID,
  key    EngagementProjectPlanData.confirmed                                                         as EngmtProjEmployeeIsStaffed,

      //--[ GENERATED:012:GlBfhyJl7jY4oBIOE}WCZW

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_EngmntProjSrvcOrgStdVH',
                     element: 'EngagementProjectServiceOrg' }
        }]
      // ]--GENERATED

         @ObjectModel.foreignKey.association:'_EngagementProjectServiceOrg'
  key    EngagementProjectPlanData.delvry_serv_org                                                   as EngagementProjectServiceOrg,
  key    EngagementProjectPlanData.demand_key                                                        as ResourceDemandUUID,
  


         cast(EngagementProjectPlanData.EngagementProjectUUID as /cpd/eng_db_key preserving type )   as EngagementProjectUUID,

         EngagementProjectPlanData.billgctrlcat                                                      as BillingControlCategory,
      //--[ GENERATED:012:GlBfhyJl7jY4oBIOE}WCZW

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_WorkPackageStdVH',
                     element: 'WorkPackage' }
        }]
      // ]--GENERATED

         @ObjectModel.foreignKey.association:'_WorkPackage'
         EngagementProjectPlanData.WorkPackage                                                       as WorkPackage,

         @Semantics.currencyCode: true
         EngagementProjectPlanData.currency                                                          as Currency,

         @Semantics.amount.currencyCode: 'Currency'
         @DefaultAggregation: #SUM
         EngagementProjectPlanData.cost                                                              as PlndCostAmt,

         @Semantics.unitOfMeasure: true
         EngagementProjectPlanData.uom                                                               as UnitOfMeasure,

         @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
         @DefaultAggregation: #SUM
         EngagementProjectPlanData.effort                                                            as PlndEffortQty,

         @Semantics.amount.currencyCode: 'Currency'
         @DefaultAggregation: #SUM
         EngagementProjectPlanData.revenue                                                           as PlndRevnAmt,

         @Semantics.amount.currencyCode: 'Currency'
         @DefaultAggregation: #SUM
         EngagementProjectPlanData.cost_deviation                                                    as ActualPlanDeviationCost,
        
         @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
         @DefaultAggregation: #SUM
         EngagementProjectPlanData.effort_deviation                                                  as ActualPlanDeviationEffort,
         
         @Semantics.amount.currencyCode: 'Currency'
         @DefaultAggregation: #SUM
         EngagementProjectPlanData.revenue_deviation                                                 as ActualPlanDeviationRevenue,

         EngagementProjectPlanData.SalesOrder                                                        as SalesOrder,

         cast(EngagementProjectPlanData.SalesOrderItem as /cpd/so_item_id preserving type )          as SalesOrderItem,

         EngagementProjectPlanData.WorkPackageStartDate                                              as WorkPackageStartDate,

         EngagementProjectPlanData.WorkPackageEndDate                                                as WorkPackageEndDate,


         _EngagementProject,
         _EngagementProjFinancialPlan,
         _WorkPackage,
         _EngmntProjResourceType,
         _WorkItem,
         _EngagementProjectResource,
         _PersnWrkAgreementDet,
         _Currency,
         _EngagementProjectServiceOrg,
         _UnitOfMeasure
         // _PlanSkillTags



}


where
  EngagementProjectPlanData.version = '1'