I_DevProjectElementType

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Development Project Element'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
     representativeKey: 'DevProjElmntType',
     resultSet.sizeCategory: #XS,
     supportedCapabilities: [ #SQL_DATA_SOURCE,
                              #CDS_MODELING_DATA_SOURCE,
                              #CDS_MODELING_ASSOCIATION_TARGET,
                              #SEARCHABLE_ENTITY ],
     modelingPattern: #NONE,
     usageType: {
        serviceQuality:  #B,
        dataClass:       #CUSTOMIZING,
        sizeCategory:    #S
    },
    sapObjectNodeType.name:'DevelopmentProjectElementType'
}
@Search.searchable: true
@VDM: {
    lifecycle.contract.type: #PUBLIC_LOCAL_API,
    viewType: #BASIC
}
define view entity I_DevProjectElementType
  as select from dpr_tsk_type as TTO
  association [0..1] to I_DevelopmentProjectObjectType as _ProjObjectType on  $projection.DevProjElmntObjectType = _ProjObjectType.DevelopmentProjectObjectType
  association [0..1] to I_DevProjectElementTypeText    as _Text           on  $projection.DevProjElmntObjectType = _Text.DevProjElmntObjectType
                                                                          and $projection.DevProjElmntType       = _Text.DevProjElmntType
{
      @EndUserText.label: 'Project Element Object Type'
      @ObjectModel.foreignKey.association: '_ProjObjectType'
  key 'TTO'        as DevProjElmntObjectType,
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @ObjectModel.text.association: '_Text'
  key TTO.tsk_type as DevProjElmntType,
      @Semantics.booleanIndicator: true
      active       as DevProjectElementTypeIsActive,

      _ProjObjectType,
      _Text
}

union all

select from dpr_tsk_type as TPO
association [0..1] to I_DevelopmentProjectObjectType as _ProjObjectType on  $projection.DevProjElmntObjectType = _ProjObjectType.DevelopmentProjectObjectType
association [0..1] to I_DevProjectElementTypeText    as _Text           on  $projection.DevProjElmntObjectType = _Text.DevProjElmntObjectType
                                                                        and $projection.DevProjElmntType       = _Text.DevProjElmntType
{
  key 'TPO'        as DevProjElmntObjectType,
  key TPO.tsk_type as DevProjElmntType,
      active       as DevProjectElementTypeIsActive,

      _ProjObjectType,
      _Text

}

union all

select from dpr_pha_type as PHA
association [0..1] to I_DevelopmentProjectObjectType as _ProjObjectType on  $projection.DevProjElmntObjectType = _ProjObjectType.DevelopmentProjectObjectType
association [0..1] to I_DevProjectElementTypeText    as _Text           on  $projection.DevProjElmntObjectType = _Text.DevProjElmntObjectType
                                                                        and $projection.DevProjElmntType       = _Text.DevProjElmntType
{
  key 'PPO'        as DevProjElmntObjectType,
  key PHA.pha_type as DevProjElmntType,
      active       as DevProjectElementTypeIsActive,

      _ProjObjectType,
      _Text

}

union all

select from dpr_clh_type as CPO
association [0..1] to I_DevelopmentProjectObjectType as _ProjObjectType on  $projection.DevProjElmntObjectType = _ProjObjectType.DevelopmentProjectObjectType
association [0..1] to I_DevProjectElementTypeText    as _Text           on  $projection.DevProjElmntObjectType = _Text.DevProjElmntObjectType
                                                                        and $projection.DevProjElmntType       = _Text.DevProjElmntType
{
  key 'CPO'        as DevProjElmntObjectType,
  key CPO.clh_type as DevProjElmntType,
      active       as DevProjectElementTypeIsActive,

      _ProjObjectType,
      _Text

}

union all

select from dpr_clh_type as CTO
association [0..1] to I_DevelopmentProjectObjectType as _ProjObjectType on  $projection.DevProjElmntObjectType = _ProjObjectType.DevelopmentProjectObjectType
association [0..1] to I_DevProjectElementTypeText    as _Text           on  $projection.DevProjElmntObjectType = _Text.DevProjElmntObjectType
                                                                        and $projection.DevProjElmntType       = _Text.DevProjElmntType
{
  key 'CTO'        as DevProjElmntObjectType,
  key CTO.clh_type as DevProjElmntType,
      active       as DevProjectElementTypeIsActive,

      _ProjObjectType,
      _Text
}