I_DevProjectElementTypeText

@EndUserText.label: 'Development Project Element Type - Text'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
    usageType:{
        serviceQuality: #B,
        sizeCategory: #S,
        dataClass: #CUSTOMIZING
    },
    supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                            #CDS_MODELING_DATA_SOURCE,
                            #LANGUAGE_DEPENDENT_TEXT,
                            #SEARCHABLE_ENTITY,
                            #SQL_DATA_SOURCE],
    dataCategory: #TEXT,
    modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
    sapObjectNodeType.name:'DevProjectElementTypeText',
    representativeKey: 'DevProjElmntType'
}
@Search.searchable: true
@VDM: {
    lifecycle.contract.type: #PUBLIC_LOCAL_API,
    viewType: #BASIC
}
define view entity I_DevProjectElementTypeText
  as select from dpr_tsk_type_t as TTOT
  association [0..1] to I_Language                     as _Language       on  $projection.Language = _Language.Language
  association [0..1] to I_DevelopmentProjectObjectType as _ProjObjectType on  $projection.DevProjElmntObjectType = _ProjObjectType.DevelopmentProjectObjectType
  association        to I_DevProjectElementType        as _ElementType    on  $projection.DevProjElmntType       = _ElementType.DevProjElmntType
                                                                          and $projection.DevProjElmntObjectType = _ElementType.DevProjElmntObjectType
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key language       as Language,
      @EndUserText.label: 'Project Element Object Type'
      @ObjectModel.foreignKey.association: '_ProjObjectType'
  key 'TTO'          as DevProjElmntObjectType,

      @ObjectModel.foreignKey.association: '_ElementType'
      @ObjectModel.text.element: ['DevProjectElementTypeText']
  key TTOT.tsk_type  as DevProjElmntType,

      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @Semantics.text: true
      TTOT.type_text as DevProjectElementTypeText,

      _Language,
      _ProjObjectType,
      _ElementType
}

union all

select from dpr_tsk_type_t as TPOT
association [0..1] to I_Language                     as _Language       on  $projection.Language = _Language.Language
association [0..1] to I_DevelopmentProjectObjectType as _ProjObjectType on  $projection.DevProjElmntObjectType = _ProjObjectType.DevelopmentProjectObjectType
association        to I_DevProjectElementType        as _ElementType    on  $projection.DevProjElmntType       = _ElementType.DevProjElmntType
                                                                        and $projection.DevProjElmntObjectType = _ElementType.DevProjElmntObjectType
{
  key language       as Language,
  key 'TPO'          as DevProjElmntObjectType,
  key TPOT.tsk_type  as DevProjElmntType,
      TPOT.type_text as DevProjectElementTypeText,

      _Language,
      _ProjObjectType,
      _ElementType
}

union all

select from dpr_pha_type_t as PHAT
association [0..1] to I_Language                     as _Language       on  $projection.Language = _Language.Language
association [0..1] to I_DevelopmentProjectObjectType as _ProjObjectType on  $projection.DevProjElmntObjectType = _ProjObjectType.DevelopmentProjectObjectType
association        to I_DevProjectElementType        as _ElementType    on  $projection.DevProjElmntType       = _ElementType.DevProjElmntType
                                                                        and $projection.DevProjElmntObjectType = _ElementType.DevProjElmntObjectType
{
  key language       as Language,
  key 'PPO'          as DevProjElmntObjectType,
  key PHAT.pha_type  as DevProjElmntType,
      PHAT.type_text as DevProjectElementTypeText,

      _Language,
      _ProjObjectType,
      _ElementType
}

union all

select from dpr_clh_type_t as CPOT
association [0..1] to I_Language                     as _Language       on  $projection.Language = _Language.Language
association [0..1] to I_DevelopmentProjectObjectType as _ProjObjectType on  $projection.DevProjElmntObjectType = _ProjObjectType.DevelopmentProjectObjectType
association        to I_DevProjectElementType        as _ElementType    on  $projection.DevProjElmntType       = _ElementType.DevProjElmntType
                                                                        and $projection.DevProjElmntObjectType = _ElementType.DevProjElmntObjectType
{
  key language       as Language,
  key 'CPO'          as DevProjElmntObjectType,
  key CPOT.clh_type  as DevProjElmntType,
      CPOT.type_text as DevProjectElementTypeText,

      _Language,
      _ProjObjectType,
      _ElementType
}


union all

select from dpr_clh_type_t as CTOT
association [0..1] to I_Language                     as _Language       on  $projection.Language = _Language.Language
association [0..1] to I_DevelopmentProjectObjectType as _ProjObjectType on  $projection.DevProjElmntObjectType = _ProjObjectType.DevelopmentProjectObjectType
association        to I_DevProjectElementType        as _ElementType    on  $projection.DevProjElmntType       = _ElementType.DevProjElmntType
                                                                        and $projection.DevProjElmntObjectType = _ElementType.DevProjElmntObjectType
{
  key language       as Language,
  key 'CTO'          as DevProjElmntObjectType,
  key CTOT.clh_type  as DevProjElmntType,
      CTOT.type_text as DevProjectElementTypeText,

      _Language,
      _ProjObjectType,
      _ElementType
}