I_DFS_MeasureAreaForUser

@AbapCatalog.sqlViewName: 'IORGMAREAUSR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Measure Area (for User)'
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.representativeKey: 'DfsMeasureAreaUUID'

@VDM.viewType: #BASIC

define view I_DFS_MeasureAreaForUser
  as select from I_CaseAttribute          as _case
    inner join   I_WorkflowTaskApplObject as _TaskApplicationObject on _case.CaseUniqueID = _TaskApplicationObject.TechnicalWrkflwObject
  association [1..1] to I_WorkflowTask as _WorkflowTask on _TaskApplicationObject.WorkflowTaskInternalID = _WorkflowTask.WorkflowTaskInternalID
{
  key CaseUniqueID as DfsMeasureAreaUUID,
      CaseType,
      CaseID,
      CaseExternalReference,
      CaseCreatedBy,
      CaseLastChangedBy,
      CaseClosedBy,
      CaseProcessor,
      CaseResponsible as DfsOrglMeasureResponsible,
      CaseTitle as DfsMeasureAreaDescription,
      CaseAuthorizationLevel,
      CaseStatus,
      CaseSystemStatus,
      CaseStatusObjectNumber,
      CaseSystemStatusName,
      CaseUserStatusName,
      CaseReason,

      cast( CaseCreatedOn as tzntstmps preserving type )        as CreationDateTime,
      cast( CaseLastChangedOn as tzntstmps preserving type )    as LastChangeDateTime,
      cast( CaseClosedTime as tzntstmps preserving type )       as CloseDateTime,

      concat('/ISDFPS/MEASURE_AREA||RMS_ID|/ISDFPS/ORG_MEASURE||GUID|', CaseUniqueID) as DfsObjectConcatenatedID,

      _TaskApplicationObject.WorkflowTaskInternalID,
      _WorkflowTask,
      _Reasons,
      _CaseSystemStatus,
      _CaseEntity,
      _CaseTypes
}
where
         CaseType                              = 'DFP2'
  and(
         CaseStatus                            = '20'
    or   CaseStatus                            = '25'
  )
  and
  (
         _WorkflowTask.WorkflowTaskCurrentUser = $session.user
    and
    (
         _WorkflowTask.WorkflowTaskStatus      = 'STARTED'
      or _WorkflowTask.WorkflowTaskStatus      = 'SELECTED'
      or _WorkflowTask.WorkflowTaskStatus      = 'COMMITTED'
    )
    and(
         _WorkflowTask.WorkflowTaskDefinition  = 'TS78907914'
      or _WorkflowTask.WorkflowTaskDefinition  = 'TS78907915'
    )
  )