I_CFinPurchasingDocument

@EndUserText.label: 'CFin Purchasing Document: Header'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
viewType:#COMPOSITE,
lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
authorizationCheck: #CHECK,
personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog:{
sqlViewName: 'ICFINPOROOT',
preserveKey: true,
compiler.compareFilter: true
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}

/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] } */
define view I_CFinPurchasingDocument
  as select from I_CFinRpldPurchasingDocument
  association [0..*] to I_CFinPurchasingDocumentItem as _CFinPurchasingDocumentItem on  $projection.SenderLogicalSystem    = _CFinPurchasingDocumentItem.SenderLogicalSystem
                                                                                    and $projection.CFinPurchasingDocument = _CFinPurchasingDocumentItem.CFinPurchasingDocument

{
  key SenderLogicalSystem,
  key cast( CFinRpldPurchasingDocument as fins_cfin_av_purchasing_doc preserving type ) as CFinPurchasingDocument,

      CompanyCode,
      PurchasingDocumentCategory,
      PurchasingDocumentType,
      PurchasingDocumentSubtype,
      PurchasingDocumentDeletionCode,
      CreationDate,
      Supplier,
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      NetPaymentDays,
      CashDiscount1Percent,
      CashDiscount2Percent,
      PurchasingOrganization,
      PurchasingGroup,
      DocumentCurrency,
      ExchangeRate,
      ExchangeRateIsFixed,
      PurchasingDocumentOrderDate,
      ValidityStartDate,
      ValidityEndDate,
      SupplyingSupplier,
      SupplyingPlant,
      PricingDocument,
      PricingProcedure,
      InvoicingParty,
      ReleaseIsNotCompleted,
      TaxReturnCountry,
      PurchasingCompletenessStatus,
      PurchasingProcessingStatus,
      CreatedByUser,
      IsEndOfPurposeBlocked,
      PurchasingDocumentIsAged,

      _CFinPurchasingDocumentItem,
      _CompanyCode,
      _PurchasingDocumentType,
      _PurchasingDocumentCategory,
      _Supplier,
      _SupplyingSupplier,
      _InvoicingParty,
      _PaymentTerms,
      _PurchasingOrganization,
      _PurchasingGroup,
      _DocumentCurrency,
      _SupplyingPlant,
      _PricingProcedure,
      _LogicalSystem // Make association public

}

union all select from I_PurchasingDocument
association [0..*] to I_CFinPurchasingDocumentItem as _CFinPurchasingDocumentItem on  $projection.SenderLogicalSystem    = _CFinPurchasingDocumentItem.SenderLogicalSystem
                                                                                  and $projection.CFinPurchasingDocument = _CFinPurchasingDocumentItem.CFinPurchasingDocument
association [0..1] to I_LogicalSystem              as _LogicalSystem              on  $projection.SenderLogicalSystem = _LogicalSystem.LogicalSystem
{
      @ObjectModel.foreignKey.association: '_LogicalSystem'
  key cast( '          ' as logsys preserving type  )                           as SenderLogicalSystem,
  key cast( PurchasingDocument as fins_cfin_av_purchasing_doc preserving type ) as CFinPurchasingDocument,
      CompanyCode,
      PurchasingDocumentCategory,
      PurchasingDocumentType,
      PurchasingDocumentSubtype,
      PurchasingDocumentDeletionCode,
      CreationDate,
      Supplier,
      PaymentTerms,
      CashDiscount1Days,
      CashDiscount2Days,
      NetPaymentDays,
      CashDiscount1Percent,
      CashDiscount2Percent,
      PurchasingOrganization,
      PurchasingGroup,
      DocumentCurrency,
      ExchangeRate,
      ExchangeRateIsFixed,
      PurchasingDocumentOrderDate,
      ValidityStartDate,
      ValidityEndDate,
      SupplyingSupplier,
      SupplyingPlant,
      PurchasingDocumentCondition                                               as PricingDocument,
      PricingProcedure,
      InvoicingParty,
      ReleaseIsNotCompleted,
      TaxReturnCountry,
      PurchasingCompletenessStatus,
      PurchasingProcessingStatus,
      CreatedByUser,
      I_PurchasingDocument.IsEndOfPurposeBlocked,
      I_PurchasingDocument.PurchasingDocumentIsAged,

      _CFinPurchasingDocumentItem,
      _CompanyCode,
      _PurchasingDocumentType,
      _PurchasingDocumentCategory,
      _Supplier,
      _SupplyingSupplier,
      _InvoicingParty,
      _PaymentTerms,
      _PurchasingOrganization,
      _PurchasingGroup,
      _DocumentCurrency,
      _SupplyingPlant,
      _PricingProcedure,
      _LogicalSystem // Make association public

}