I_CFINRPLDPURCHASINGDOCUMENT
CFin Rpld Purchasing Document: Header
I_CFINRPLDPURCHASINGDOCUMENT is a CDS View in S/4HANA. CFin Rpld Purchasing Document: Header. It contains 2 fields. 6 CDS views read from this table.
CDS Views using this table (6)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_CFinRpldPurchaseOrder | view | from | CONSUMPTION | CFin Rpld Purchase Order |
| I_CFinPurchasingDocument | view | from | COMPOSITE | CFin Purchasing Document: Header |
| I_PurOrdAccrsCFinPurgDocument | view | from | COMPOSITE | PurOrdAccrs: Purchasing Document |
| P_CFinRpldPurgDocVH | view | from | BASIC | |
| P_CO_DIANCFinPurchasingGLAcct | view_entity | inner | CONSUMPTION | |
| R_CFinRpldPurchasingDocumentTP | view_entity | from | TRANSACTIONAL | CFin Replicated Purchasing Document |
Fields (2)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | SenderLogicalSystem | SenderLogicalSystem | 1 |
| PurchasingDocumentType | PurchasingDocumentType | 1 |
@EndUserText.label: 'CFin Rpld Purchasing Document: Header'
@VDM: {
viewType: #BASIC,
lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
authorizationCheck:#CHECK,
personalData.blocking:#('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
sqlViewName: 'ICFINRPOROOT',
preserveKey: true,
compiler.compareFilter: true
}
@ObjectModel: {
usageType: {
dataClass: #TRANSACTIONAL,
serviceQuality: #C,
sizeCategory: #L
}
}
@ClientHandling.algorithm: #SESSION_VARIABLE
/*+[hideWarning] { "IDS" : [ "KEY_CHECK" ] } */
define view I_CFinRpldPurchasingDocument
as select from cfin_av_po_root
//Association
association [1..1] to I_PurchasingDocumentCategory as _PurchasingDocumentCategory on $projection.PurchasingDocumentCategory = _PurchasingDocumentCategory.PurchasingDocumentCategory
association [0..1] to I_PurchasingDocumentType as _PurchasingDocumentType on $projection.PurchasingDocumentCategory = _PurchasingDocumentType.PurchasingDocumentCategory
and $projection.PurchasingDocumentType = _PurchasingDocumentType.PurchasingDocumentType
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_User as _CreatedByUser on $projection.CreatedByUser = _CreatedByUser.UserID
association [0..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [0..1] to I_Supplier as _SupplyingSupplier on $projection.SupplyingSupplier = _SupplyingSupplier.Supplier
association [0..1] to I_Supplier as _InvoicingParty on $projection.InvoicingParty = _InvoicingParty.Supplier
association [0..1] to I_PaymentTerms as _PaymentTerms on $projection.PaymentTerms = _PaymentTerms.PaymentTerms
association [0..1] to I_PurchasingOrganization as _PurchasingOrganization on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
association [0..1] to I_PurchasingGroup as _PurchasingGroup on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
association [0..1] to I_Currency as _DocumentCurrency on $projection.DocumentCurrency = _DocumentCurrency.Currency
association [0..1] to I_Plant as _SupplyingPlant on $projection.SupplyingPlant = _SupplyingPlant.Plant
association [0..*] to I_CFinRpldPurchasingDocItem as _CFinRpldPurchasingDocItem on $projection.CFinRpldPurchasingDocument = _CFinRpldPurchasingDocItem.CFinRpldPurchasingDocument
and $projection.SenderLogicalSystem = _CFinRpldPurchasingDocItem.SenderLogicalSystem
association [0..1] to I_TaxCalculationProcedure as _PricingProcedure on $projection.PricingProcedure = _PricingProcedure.TaxCalculationProcedure
association [0..1] to I_LogicalSystem as _LogicalSystem on $projection.SenderLogicalSystem = _LogicalSystem.LogicalSystem
association [1..1] to E_CFinRpldPurchasingDocument as _Extension on $projection.CFinRpldPurchasingDocument = _Extension.CFinRpldPurchasingDocument
and $projection.SenderLogicalSystem = _Extension.SourceSystemLogicalSystem
{
@ObjectModel.foreignKey.association: '_LogicalSystem'
key cfin_av_po_root.fins_logsys as SenderLogicalSystem,
key cast( cfin_av_po_root.ebeln as fins_cfin_av_purchasing_doc preserving type ) as CFinRpldPurchasingDocument,
@ObjectModel.foreignKey.association: '_CompanyCode'
cfin_av_po_root.bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_PurchasingDocumentCategory'
cfin_av_po_root.bstyp as PurchasingDocumentCategory,
@ObjectModel.foreignKey.association: '_PurchasingDocumentType'
cfin_av_po_root.bsart as PurchasingDocumentType,
cfin_av_po_root.bsakz as PurchasingDocumentSubtype,
cfin_av_po_root.loekz as PurchasingDocumentDeletionCode,
cfin_av_po_root.aedat as CreationDate,
@ObjectModel.foreignKey.association: '_Supplier'
cast ( cfin_av_po_root.lifnr as md_supplier preserving type) as Supplier,
@ObjectModel.foreignKey.association: '_PaymentTerms'
cast( cfin_av_po_root.zterm as farp_dzterm preserving type) as PaymentTerms,
cast (cfin_av_po_root.zbd1t as dzbd1t preserving type) as CashDiscount1Days,
cast (cfin_av_po_root.zbd2t as dzbd2t preserving type) as CashDiscount2Days,
cast (cfin_av_po_root.zbd3t as dzbd3t preserving type) as NetPaymentDays,
cfin_av_po_root.zbd1p as CashDiscount1Percent,
cfin_av_po_root.zbd2p as CashDiscount2Percent,
@ObjectModel.foreignKey.association: '_PurchasingOrganization'
cfin_av_po_root.ekorg as PurchasingOrganization,
@ObjectModel.foreignKey.association: '_PurchasingGroup'
cfin_av_po_root.ekgrp as PurchasingGroup,
@Semantics.currencyCode:true
@ObjectModel.foreignKey.association: '_DocumentCurrency'
cfin_av_po_root.waers as DocumentCurrency,
cast(abs(cfin_av_po_root.wkurs) as fins_cfin_wkurs_no_conv preserving type) as ExchangeRate,
cfin_av_po_root.kufix as ExchangeRateIsFixed,
@Semantics.businessDate.at
cfin_av_po_root.bedat as PurchasingDocumentOrderDate,
cfin_av_po_root.kdatb as ValidityStartDate,
cfin_av_po_root.kdate as ValidityEndDate,
@ObjectModel.foreignKey.association: '_SupplyingSupplier'
cfin_av_po_root.llief as SupplyingSupplier,
@ObjectModel.foreignKey.association: '_SupplyingPlant'
cfin_av_po_root.reswk as SupplyingPlant,
// This field is obsolete
@UI.hidden: true
cfin_av_po_root.knumv as PricingDocument,
cfin_av_po_root.kalsm as PricingProcedure,
@ObjectModel.foreignKey.association: '_InvoicingParty'
cfin_av_po_root.lifre as InvoicingParty,
cfin_av_po_root.frgrl as ReleaseIsNotCompleted,
cfin_av_po_root.lands as TaxReturnCountry,
cfin_av_po_root.memory as PurchasingCompletenessStatus,
cfin_av_po_root.procstat as PurchasingProcessingStatus,
cfin_av_po_root.iuuc_operat_flag as CFinRpldDeleteArchiveStatus,
@Semantics.user.createdBy: true
cfin_av_po_root.ernam as CreatedByUser,
cfin_av_po_root.iseopblocked as IsEndOfPurposeBlocked,
cfin_av_po_root.isaged as PurchasingDocumentIsAged,
cfin_av_po_root.revno as PurchasingDocumentVersion,
cfin_av_po_root.bukrs_sender as SenderCompanyCode,
_CompanyCode,
_PurchasingDocumentType,
_PurchasingDocumentCategory,
_Supplier,
_SupplyingSupplier,
_InvoicingParty,
_PaymentTerms,
_PurchasingOrganization,
_PurchasingGroup,
_DocumentCurrency,
_CreatedByUser,
_SupplyingPlant,
_PricingProcedure,
_CFinRpldPurchasingDocItem,
_LogicalSystem
}