I_BusinessPartnerAddressTP_2

//@AbapCatalog.sqlViewName: 'IBUPAADDRESSTP2'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Business Partner Address'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
//@ClientHandling.algorithm : #SESSION_VARIABLE

@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity I_BusinessPartnerAddressTP_2
  as select from I_BusinessPartAddress_2  as BusinessPartnerAddress
  //I_BusinessPartnerAddress

  composition [0..*] of I_BusinessPartnerAddrUsageTP_2 as _BusinessPartnerAddressUsage
  composition [0..*] of I_BusPartTelephoneNumberTP_2   as _BusinessPartnerPhoneNumber
  association [0..1] to I_BusPartTelephoneNumberTP_2   as _StandardPhoneNumber         on 
//   _StandardPhoneNumber.BPDrftUUID        = $projection.BPDrftUUID                                                                                           

//                                                                                       and _StandardPhoneNumber.BPAddressDrftUUID = $projection.BPAddressDrftUUID   

                                                                                        _StandardPhoneNumber.BusinessPartner = $projection.BusinessPartner                                                                                     
                                                                                       and _StandardPhoneNumber.AddressNumber     = $projection.AddressNumber
                                                                                       and _StandardPhoneNumber.PhoneNumberType   = '1'
                                                                                       and _StandardPhoneNumber.IsDefaultPhoneNumber = 'X'
  association [0..1] to I_BusPartTelephoneNumberTP_2   as _StandardPhone               on  _StandardPhone.AddressNumber   = $projection.AddressNumber
                                                                                       and _StandardPhone.PhoneNumberType = '1'
                                                                                       and _StandardPhone.IsDefaultPhoneNumber = 'X'
  composition [0..*] of I_BusPartMobilePhoneNumberTP_2 as _BusPartMobileNumber
  association [0..1] to I_BusPartMobilePhoneNumberTP_2 as _StandardMobileNumber        on 
//   _StandardMobileNumber.BPDrftUUID        = $projection.BPDrftUUID

//                                                                                       and _StandardMobileNumber.BPAddressDrftUUID = $projection.BPAddressDrftUUID

                                                                                        _StandardMobileNumber.BusinessPartner = $projection.BusinessPartner 
                                                                                       and _StandardMobileNumber.AddressNumber     = $projection.AddressNumber
                                                                                       and _StandardMobileNumber.PhoneNumberType   = '3'
                                                                                       and _StandardMobileNumber.IsDefaultPhoneNumber = 'X'
  association [0..1] to I_BusPartMobilePhoneNumberTP_2 as _StandardMobile              on  _StandardMobile.AddressNumber   = $projection.AddressNumber
                                                                                       and _StandardMobile.PhoneNumberType = '3'
                                                                                       and _StandardMobile.IsDefaultPhoneNumber = 'X'
  composition [0..*] of I_BusPartFaxNumberTP_2         as _BusPartFaxNumber
  association [0..1] to I_BusPartFaxNumberTP_2         as _StandardFaxNumber           on  
//  _StandardFaxNumber.BPDrftUUID         = $projection.BPDrftUUID

//                                                                                       and _StandardFaxNumber.BPAddressDrftUUID  = $projection.BPAddressDrftUUID

                                                                                        _StandardFaxNumber.BusinessPartner = $projection.BusinessPartner 
                                                                                       and _StandardFaxNumber.AddressNumber      = $projection.AddressNumber
                                                                                       and _StandardFaxNumber.IsDefaultFaxNumber = 'X'

  association [0..1] to I_BusPartFaxNumberTP_2         as _StandardFax                 on  _StandardFax.AddressNumber      = $projection.AddressNumber
                                                                                       and _StandardFax.IsDefaultFaxNumber = 'X'
  composition [0..*] of I_BusPartEmailAddressTP_2      as _BusinessPartnerEmailAddress
  association [0..1] to I_BusPartEmailAddressTP_2      as _StandardEmailAddress        on  
//  _StandardEmailAddress.BPDrftUUID            = $projection.BPDrftUUID

//                                                                                       and _StandardEmailAddress.BPAddressDrftUUID     = $projection.BPAddressDrftUUID

                                                                                        _StandardEmailAddress.BusinessPartner = $projection.BusinessPartner 
                                                                                       and _StandardEmailAddress.AddressNumber         = $projection.AddressNumber
                                                                                       and _StandardEmailAddress.IsDefaultEmailAddress = 'X'

  association [0..1] to I_BusPartEmailAddressTP_2      as _StandardEmail               on  _StandardEmail.AddressNumber         = $projection.AddressNumber
                                                                                       and _StandardEmail.IsDefaultEmailAddress = 'X'
  composition [0..*] of I_BusPartWebsiteURLTP_2        as _BusPartWebsiteURL
  association [0..1] to I_BusPartWebsiteURLTP_2        as _StandardWebsiteURL          on  
//  _StandardWebsiteURL.BPDrftUUID          = $projection.BPDrftUUID

//                                                                                       and _StandardWebsiteURL.BPAddressDrftUUID   = $projection.BPAddressDrftUUID

                                                                                        _StandardWebsiteURL.BusinessPartner = $projection.BusinessPartner 
                                                                                       and _StandardWebsiteURL.AddressNumber       = $projection.AddressNumber
                                                                                       and _StandardWebsiteURL.IsDefaultURLAddress = 'X'
  association [0..1] to I_BusPartWebsiteURLTP_2        as _StandardWebURL              on  _StandardWebURL.AddressNumber       = $projection.AddressNumber
                                                                                       and _StandardWebURL.IsDefaultURLAddress = 'X'
  composition [0..*] of I_BusPartScriptedOrgAddressTP  as _BusPartScriptedOrgAddress
  composition [0..*] of I_BusPartScriptedPersonAddrTP  as _BusPartScriptedPersonAddress
  composition [0..*] of I_BusPartScriptedGroupAddrTP   as _BusPartScriptedGroupAddress

  association [1..1] to I_BPCurrentDefaultAddress      as _StandardAddrUsage           on  $projection.BusinessPartner = _StandardAddrUsage.BusinessPartner
  association        to parent I_BusinessPartnerTP_2          as _BusinessPartner      on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
//                                                                                       and $projection.BPDrftUUID      = _BusinessPartner.BPDrftUUID

  association [0..1] to I_Country                      as _Country                     on  $projection.Country = _Country.Country
  association [0..1] to I_CountryText                  as _CountryText                 on  $projection.Country   = _CountryText.Country
                                                                                       and _CountryText.Language = $session.system_language
  association [0..1] to I_Region                       as _Region                      on  $projection.Country = _Region.Country
                                                                                       and $projection.Region  = _Region.Region
  association [0..1] to I_LanguageText                 as _Language                    on  $projection.CorrespondenceLanguage = _Language.LanguageCode
                                                                                       and _Language.Language                 = $session.system_language
  association [0..1] to I_BusPartCommMdmTypeVH         as _CommType                    on  $projection.PrfrdCommMediumType = _CommType.CommunicationMediumType
  association [0..1] to I_TimeZone                     as _TimeZone                    on  $projection.AddressTimeZone = _TimeZone.TimeZoneID
  association [0..1] to I_Transportation_Zone_Text     as _TransportZone               on  $projection.TransportZone = _TransportZone.TransportZone
                                                                                       and $projection.Country       = _TransportZone.CountryCode
                                                                                       and _TransportZone.Language   = $session.system_language
  association [0..1] to I_Country                      as _POBoxCountry                on  $projection.POBoxDeviatingCountry = _POBoxCountry.Country
  association [0..1] to I_Region                       as _POBoxRegion                 on  $projection.POBoxDeviatingCountry = _POBoxRegion.Country
                                                                                       and $projection.POBoxDeviatingRegion  = _POBoxRegion.Region
  association [0..1] to I_BusPartDelivSrvcVH           as _DeliveryService             on  $projection.DeliveryServiceTypeCode = _DeliveryService.DeliveryServiceTypeCode
  association [0..1] to I_AddressNonDeliverableReason  as _AddressNonDeliverableReason on  $projection.AddressNonDeliverableReason = _AddressNonDeliverableReason.AddressNonDeliverableReason
  association [0..1] to I_AddressNonDeliverableReason  as _PostBoxNonDeliverableReason on  $projection.PostBoxNonDeliverableReason = _PostBoxNonDeliverableReason.AddressNonDeliverableReason
{
//  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPDrftUUID,

//  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPAddressDrftUUID,

      //   @semanticKey: true

  key BusinessPartnerAddress.BusinessPartner                             as BusinessPartner,
      //   @semanticKey: true

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key BusinessPartnerAddress.AddressNumber,
      @ObjectModel.editableFieldFor: 'AddressNumber'
      BusinessPartnerAddress.AddressNumber as AddressIDForEdit,
      BusinessPartnerAddressUUID,
      @Semantics.businessDate.from: true
      case when ValidityStartDate != 00010101000000
      then tstmp_to_dats(ValidityStartDate,'UTC',  $session.client, 'NULL')
      else cast ( '00010103' as abap.dats )
      end                                                                as ValidityStartDate,
      @Semantics.businessDate.to: true
      case when ValidityEndDate != 00010101000000
      then tstmp_to_dats(ValidityEndDate,'UTC',  $session.client, 'NULL')
      else cast ( '99991231' as abap.dats)
      end                                                                as ValidityEndDate,
      BusinessPartnerAddress.CareOfName,
      BusinessPartnerAddress.StreetPrefixName,
      BusinessPartnerAddress.AdditionalStreetPrefixName,
      BusinessPartnerAddress.HouseNumber,
      BusinessPartnerAddress.StreetName,
      BusinessPartnerAddress.HouseNumberSupplementText,
      BusinessPartnerAddress.StreetSuffixName,
      BusinessPartnerAddress.AdditionalStreetSuffixName,
      BusinessPartnerAddress.HomeCityName,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'DistrictName'
      BusinessPartnerAddress.District,
      BusinessPartnerAddress.District                                    as DistrictName,
      BusinessPartnerAddress.PostalCode,
      BusinessPartnerAddress.CityName,
      BusinessPartnerAddress.Country,
      BusinessPartnerAddress.Region,
      BusinessPartnerAddress.AddressTimeZone,
      BusinessPartnerAddress.TransportZone,
      BusinessPartnerAddress.TaxJurisdiction,
      BusinessPartnerAddress.CompanyPostalCode,
      BusinessPartnerAddress.DeliveryServiceTypeCode,
      BusinessPartnerAddress.DeliveryServiceNumber,
      BusinessPartnerAddress.POBox,
      BusinessPartnerAddress.POBoxIsWithoutNumber,
      BusinessPartnerAddress.POBoxPostalCode,
      BusinessPartnerAddress.POBoxLobbyName,
      BusinessPartnerAddress.POBoxDeviatingCityName,
      BusinessPartnerAddress.POBoxDeviatingRegion,
      BusinessPartnerAddress.POBoxDeviatingCountry,
      BusinessPartnerAddress.CorrespondenceLanguage,
      BusinessPartnerAddress.PrfrdCommMediumType,
      BusinessPartnerAddress.AddressStreetUnusable                       as AddressNonDeliverableReason,
      BusinessPartnerAddress.AddressPostBoxUnusable                      as PostBoxNonDeliverableReason,
      BusinessPartnerAddress.Building,
      BusinessPartnerAddress.Floor,
      BusinessPartnerAddress.RoomNumber,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'BPCountyText'
      BusinessPartnerAddress.County,
      BusinessPartnerAddress.County                                      as BPCountyText,
      //      BusinessPartnerAddress.CityFileTestStatus,


      concat_with_space(
        concat_with_space(
          concat_with_space(
            concat_with_space(StreetName,HouseNumber,1)
          ,PostalCode,1)
        ,CityName,1)
      ,Country,1)                                                        as AddressLine1Text,

      case
        when PrfrdCommMediumType='FAX'
          then concat('+',concat_with_space(_StandardFax._FaxCountryPrefix.TelephoneCountryPrefix,
                concat_with_space(_StandardFax.FaxNumber, _StandardFax.FaxNumberExtension,1),1))
        when PrfrdCommMediumType='INT'
          then _StandardEmail.EmailAddress
        when PrfrdCommMediumType='URI'
          then lower(_StandardWebURL.SearchURLAddress)
        when PrfrdCommMediumType='TEL'
          then case
            when _StandardPhone.IsDefaultPhoneNumber='X'
              then  concat('+',concat_with_space(_StandardPhone._TelCountryPrefix.TelephoneCountryPrefix,
                concat_with_space(_StandardPhone.PhoneNumber, _StandardPhone.PhoneNumberExtension,1),1))
            else concat('+',concat_with_space(_StandardMobile._TelCountryPrefix.TelephoneCountryPrefix,
                _StandardMobile.MobilePhoneNumber,1))
          end
        when _StandardPhone.PhoneNumber is not null
          then concat('+',concat_with_space(_StandardPhone._TelCountryPrefix.TelephoneCountryPrefix,
                concat_with_space(_StandardPhone.PhoneNumber, _StandardPhone.PhoneNumberExtension,1),1))
        else ''
      end                                                                as AddressLine2Text,

      case
        when HouseNumber=''
            and StreetName=''
            and CityName=''
            and PostalCode=''
          then HouseNumber
          else
            case
              when HouseNumber=''
                  and StreetName=''
                then concat_with_space(PostalCode,CityName,1)
                else concat_with_space(HouseNumber,concat(
                      StreetName,concat_with_space(
                        ',',concat_with_space(PostalCode,CityName,1)
                        ,1)
                      )
                     ,1)
            end
      end                                                                as FormattedAddress,

      concat_with_space(
        concat(
          concat_with_space(
            concat_with_space(
              concat_with_space(HouseNumber,StreetName,1)
              ,',',1)
            ,CityName,1)
          ,',')
        ,concat_with_space(_CountryText.CountryName,PostalCode,1)
      ,1)                                                                as CompleteAddress,
      _BPProtectedAddress.BPAddressIsProtected,

      case _StandardAddrUsage.AddressID
      when AddressNumber
      then cast('X' as boole_d)
      else
      cast(' ' as boole_d)
      end                                                                as StandardUsage,
      _BusinessPartner.AuthorizationGroup,
      _BusinessPartner.IsBusinessPurposeCompleted,
      cast( 'X' as sdraft_is_active preserving type )   as  BPHasActiveEntity,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataControllerSet              as DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController1                as DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController2                as DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController3                as DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController4                as DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController5                as DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController6                as DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController7                as DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController8                as DataController8,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController9                as DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController10               as DataController10,
      /* Associations */
      _BusinessPartnerAddressUsage,
      _BusinessPartnerPhoneNumber,
      _BusPartMobileNumber,
      _BusinessPartnerEmailAddress,
      _BusPartFaxNumber,
      _BusPartWebsiteURL,
      _BusPartScriptedOrgAddress,
      _BusPartScriptedPersonAddress,
      _BusPartScriptedGroupAddress,
      _StandardAddrUsage,
      _BusinessPartner,
      _Country,
      _CountryText,
      _Region,
      _Language,
      _CommType,
      _TimeZone,
      _TransportZone,
      _POBoxCountry,
      _POBoxRegion,
      _DeliveryService,
      _AddressNonDeliverableReason,
      _PostBoxNonDeliverableReason,
      _BPProtectedAddress,
      _StandardPhoneNumber,
      _StandardMobileNumber,
      _StandardFaxNumber,
      _StandardEmailAddress,
      _StandardWebsiteURL
//      _BPDataControllerUsage

}