I_BusPartScriptedGroupAddrTP

//@AbapCatalog.sqlViewName: 'IBPSCRPTGRPADTP'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
//@ClientHandling.algorithm : #SESSION_VARIABLE

@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Business partner scripted addresses'
define view entity I_BusPartScriptedGroupAddrTP
  as select from I_BusPartScriptedGroupAddress
  association [0..1] to I_AddressRepresentation             as _AddressRepresentation  on  $projection.AddressRepresentationCode = _AddressRepresentation.AddressRepresentationCode
  association [0..1] to I_BusinessPartnerFormOfAddress      as _FormOfAddress          on  $projection.FormOfAddress = _FormOfAddress.FormOfAddress
  association        to parent I_BusinessPartnerAddressTP_2 as _BusinessPartnerAddress on  $projection.BusinessPartner = _BusinessPartnerAddress.BusinessPartner
                                                                                       and $projection.AddressNumber   = _BusinessPartnerAddress.AddressNumber
//                                                                                       and $projection.BPDrftUUID   = _BusinessPartnerAddress.BPDrftUUID

//                                                                                       and $projection.BPAddressDrftUUID   = _BusinessPartnerAddress.BPAddressDrftUUID

  association [1..1] to I_BusinessPartnerTP_2               as _BusinessPartner        on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner      
//                                                                                       and $projection.BPDrftUUID   = _BusinessPartner.BPDrftUUID                                                                                 

{
//  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPDrftUUID,

//  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPAddressDrftUUID,

//  key cast ( hextobin('00000000000000000000000000000000') as sysuuid_x ) as BPScriptedGrpAddrDrftUUID,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key BusinessPartner,
  key AddressNumber,
      @ObjectModel.foreignKey.association: '_AddressRepresentation'
  key AddressRepresentationCode,
      AddressRepresentationCode as AddrRepCodeForEditValue,
      tstmp_to_dats(ValidityStartDateTime,'UTC',  $session.client, 'NULL') as ValidityStartDate,
      tstmp_to_dats(ValidityEndDateTime,'UTC',  $session.client, 'NULL')   as ValidityEndDate,
      BusinessPartnerAddressUUID,
      CareOfName,
      AdditionalStreetSuffixName,
      CorrespondenceLanguage,
      PrfrdCommMediumType,
      POBox,
      POBoxIsWithoutNumber,
      POBoxPostalCode,
      POBoxLobbyName,
      POBoxDeviatingCityName,
      POBoxDeviatingRegion,
      POBoxDeviatingCountry,
      DeliveryServiceTypeCode,
      DeliveryServiceNumber,
      AddressTimeZone,
      FullName,
      CityName,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'DistrictName'
      District,
      DistrictName,
      HomeCityName,
      PostalCode,
      CompanyPostalCode,
      StreetName,
      StreetPrefixName,
      AdditionalStreetPrefixName,
      StreetSuffixName,
      HouseNumber,
      HouseNumberSupplementText,
      Building,
      Floor,
      RoomNumber,
      Country,
      Region,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'BPCountyText'
      County,
      BPCountyText,
      case
        when HouseNumber=''
            and StreetName=''
            and CityName=''
            and PostalCode=''
          then HouseNumber
          else
            case
              when HouseNumber=''
                  and StreetName=''
                then concat_with_space(PostalCode,CityName,1)
                else concat_with_space(HouseNumber,concat(
                      StreetName,concat_with_space(
                        ',',concat_with_space(PostalCode,CityName,1)
                        ,1)
                      )
                     ,1)
            end
      end                                                                  as FormattedAddress,

      BusinessPartnerName1,
      BusinessPartnerName2,
      TaxJurisdiction,
      TransportZone,

      @ObjectModel.foreignKey.association: '_FormOfAddress'
      FormOfAddress,
      SearchTerm1,
      SearchTerm2,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataControllerSet              as DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController1                as DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController2                as DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController3                as DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController4                as DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController5                as DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController6                as DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController7                as DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController8                as DataController8,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController9                as DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      _BusinessPartner.DataController10               as DataController10,
      
      _AddressRepresentation,
      _FormOfAddress,
      _BusinessPartnerAddress,
      _BPProtectedAddress,
      _BusinessPartner,
      
      _BusinessPartner.AuthorizationGroup,
      _BusinessPartner.IsBusinessPurposeCompleted,
      _BPProtectedAddress.BPAddressIsProtected,
      
      _BusinessPartner._AuthorizationGroup as _AuthorizationGroup
      //_BPDataControllerUsage

}