I_BkAcctChgReqDeadlineEmail

@AbapCatalog.sqlViewName: 'IBKACCTREQDDLEML'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@AbapCatalog.preserveKey: true
@ObjectModel: {    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL
    }     }
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Deadline email'
define view I_BkAcctChgReqDeadlineEmail
  as select from           I_WorkflowTask           as WorkflowTask
    left outer to one join I_WorkflowTaskApplObject as WorkflowTaskApplObject on  WorkflowTaskApplObject.WorkflowTaskInternalID = WorkflowTask.WorkflowTaskInternalID
                                                                              and WorkflowTaskApplObject.WorkflowObjectRole     = '99'
    left outer to one join I_BankAcctChangeRequest  as ChangeRequest          on ChangeRequest.BankAccountChangeRequest = WorkflowTaskApplObject.TechnicalWrkflwObject
    left outer to one join I_User                   as User                   on WorkflowTask.WorkflowTaskCurrentUser = User.UserID
  association [1..1] to I_WorkflowTaskURL as _WorkflowTaskURL on $projection.WorkflowTaskInternalID = _WorkflowTaskURL.WorkflowTaskInternalID
  association [0..1] to I_UserContactCard as _CreatedByUser   on $projection.CreatedByUser = _CreatedByUser.ContactCardID
{
      //_WorkflowTask

  key WorkflowTask.WorkflowTaskInternalID,
      WorkflowTask.WorkflowTaskType,
      WorkflowTask.WorkflowTaskPriority,
      WorkflowTask.WorkflowTaskStatus,
      WorkflowTask.WrkflwTskCreationUTCDateTime,
      WorkflowTask.WrkflwTskCompletionUTCDateTime,
      WorkflowTask.TopLevelWorkflowTask,
      WorkflowTask.ParentWorkflowTask,
      WorkflowTask.WorkflowTaskCreatedByUser,
      WorkflowTask.WorkflowTaskCurrentUser,
      User.UserDescription,
      WorkflowTask.WorkflowTaskDefinition,
      WorkflowTask.WorkflowTaskDefinitionObjType,
      WorkflowTask.WorkflowTaskDefinitionObject,
      WorkflowTask.TopLevelWorkflowTaskDefinition,
      WorkflowTask.TopLevelWrkflwTskDefObjType,
      WorkflowTask.TopLevelWrkflwTskDefObject,
      WorkflowTask.WorkflowTaskStepType,
      WorkflowTask.WorkflowTaskProcessorRole,
      WorkflowTask.WorkflowTaskDefinitionVersion,
      WorkflowTask.WorkflowTaskDefinitionType,
      WorkflowTask.WorkflowTaskResult,
      _WorkflowTaskURL.WorkflowTaskURL,
      //Change request

      ChangeRequest.BankAccountChangeRequest,
      ChangeRequest.BankAccountAction,
      ChangeRequest.BankAccountActionText,
      ChangeRequest.BankAccountChangeRequestStatus,
      ChangeRequest.BankAccountChangeRequestStep,
      ChangeRequest.BankAccountReqStatusText,
      ChangeRequest.BankAcctChangeReqHeadingText,
      ChangeRequest.BankAcctChangeRequestDueDate,
      ChangeRequest.CreatedByUser,
      _CreatedByUser.FullName,
      ChangeRequest.CreationDate,
      ChangeRequest.LastChangedByUser,
      //_WorkflowTask Association

      WorkflowTask._TaskApplicationLeadingObject,
      WorkflowTask._TaskApplicationObject,
      WorkflowTask._TaskDefinition,
      WorkflowTask._TaskDueDate,
      WorkflowTask._TaskPriority,
      WorkflowTask._TaskRecipient,
      WorkflowTask._TaskStartEvent,
      WorkflowTask._TaskStatus,
      WorkflowTask._TaskTitle,
      WorkflowTask._TaskType,
      WorkflowTask._TopLevelTaskDefinition,
      WorkflowTask._WorkflowStepType,
      WorkflowTask._WorkflowTaskStepResult

}